5
$\begingroup$

I have two equation for Ex(t1,t2,t) and Ey(t1,t2,t). Please,could you tell me, how I can make a plot Ex(Ey)?

Ex[t1_, t2_, t_] = ((Sin[t2] - Sin[t1])/(t1 - t2) - Cos[t])^2

Ey[t1_, t2_, t_] = (2 (Cos[t1] - Cos[t2])/(t1 - t2) - Sin[t])^2
$\endgroup$
8
$\begingroup$

What you really have is a family of parametric curves. I would go about doing this in the following way (and you can switch out t for t1 or t2 if you want; just follow the general construction).

As an example, consider:

With[{t1 = 0.5, t2 = 0},
  ParametricPlot[{Ey[t1, t2, t], Ex[t1, t2, t]}, {t, 0, 2 π}, AspectRatio -> 1]
 ]

enter image description here

If you want to see some general behavior, we can make a table over one of the other variables. For instance,

Multicolumn[
 Table[
   With[{t2 = 0}, ParametricPlot[{Ey[t1, t2, t], Ex[t1, t2, t]}, {t, 0, 2 π}, AspectRatio -> 1]],
   {t1, {0.01, 0.1, 0.5, 1, 2, 5}}],
 3]

enter image description here

animation

$\endgroup$
  • $\begingroup$ I hope you don't mind, but I added an animation. Just because I can. $\endgroup$ – wxffles Oct 11 '16 at 23:23
  • $\begingroup$ @wxffles. That's cute! $\endgroup$ – march Oct 11 '16 at 23:24
4
$\begingroup$

If you are not after a continuous solution, then this is straightforward:

min = 0.;
max = 2.;
step = 0.1;

ListPlot[
  Transpose@{Flatten@
     Quiet@Table[
       Ey[x, y, z], {x, min, max, step}, {y, min, max, step}, {z, min,
         max, step}], 
    Flatten@Quiet@
      Table[Ex[x, y, z], {x, min, max, step}, {y, min, max, step}, {z,
         min, max, step}]}, Frame -> True, AspectRatio -> 1, 
  FrameLabel -> {"Ey", "Ex"}]

enter image description here

Explanation: for a set {x,y,z} the functions Ex[x,y,z] and Ey[x,y,z] take some values, say, E1 and E2, respectively. So for sure when the function Ex takes the value E1, then function Ey takes the value E2. So one needs to make a list of such pairs {E2, E1}. Quiet is because when the denominator (t1-t2 in the definitions) is zero, then both functions are Indeterminate, and I didn't want to play around with discarding such values as they don't influence the plot.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.