3
$\begingroup$

I only have six numbers, $\lbrace4, 48, 360, 2240, 12600, 66528\rbrace$, from the following series:

Table[1/SeriesCoefficient[ArcSin[x/2]^2, {x, 0, 2 n}], {n, 1, 6}]

I want to find a function $f(x)$ such that

$$\sum_{n=1}^{\infty}f(n)x^{2n}=\arcsin^2 \bigg(\frac{x}{2}\bigg)$$

The is a Maple code to find it

with(gfun)

s := [seq(1/coeff(series(arcsin((1/2)*x)^2, x, 25), x, 2*n), n = 1 .. 12)]

R := unapply(rsolve(op(1, listtorec(s, r(m))), r(m)), m); [seq(R(m), m = 0 .. 8)]

Maple result

How do I find it using Mathematica?

$\endgroup$
  • 1
    $\begingroup$ Assuming[n >= 1, 1/SeriesCoefficient[ArcSin[Sqrt[x]/2]^2, {x, 0, n}]] yields a rather complicated expression. $\endgroup$ – J. M.'s technical difficulties Oct 4 '16 at 13:03
  • $\begingroup$ The left side of your equation is independent of x, but the right side is not. Do you mean Sum[f[n] x^(2 n), {n, 1, Infinity}]? $\endgroup$ – bbgodfrey Oct 4 '16 at 13:08
3
$\begingroup$

The problem with the result of SeriesCoefficient[] is that the hypergeometric functions that show up in it are left unsimplified:

Assuming[n >= 0, FullSimplify[1/SeriesCoefficient[ArcSin[Sqrt[x]/2]^2/x, {x, 0, n}]]]
   (2^(3 + 2 n) (1 + 2 n) Sqrt[π] Gamma[2 + n])/
   (Gamma[1/2 + n] ((1 + 2 n) HypergeometricPFQ[{1/2, 1/2, -n}, {3/2, 1/2 - n}, 1] +
    HypergeometricPFQ[{1/2, -(1/2) - n, -n}, {1/2 - n, 1/2 - n}, 1]))

Note, however, that since n is assumed to be a positive integer, the hypergeometric functions in it are actually terminating hypergeometric series; that is, one of the Pochhammer factors in the term becomes zero past a certain index. In particular, we can make the replacements

HypergeometricPFQ[{1/2, 1/2, -n}, {3/2, 1/2 - n}, 1] ->
Sum[(Pochhammer[1/2, k]^2 (-1)^k Binomial[n, k])/
    (Pochhammer[3/2, k] Pochhammer[1/2 - n, k]), {k, 0, n}]

HypergeometricPFQ[{1/2, -1/2 - n, -n}, {1/2 - n, 1/2 - n}, 1] ->
Sum[(Pochhammer[1/2, k] Pochhammer[-1/2 - n, k] (-1)^k Binomial[n, k])/
    Pochhammer[1/2 - n, k]^2, {k, 0, n}]

which respectively evaluate to (π (n!)^2)/(2 (1/2 (-1 + 2 n))! (1/2 (1 + 2 n))!) and (π (n!)^2)/((1/2 (-1 + 2 n))!)^2; if we plug these into the original expression returned by SeriesCoefficient[], we have

FullSimplify[(2^(2 n + 3) (2 n + 1) Sqrt[π] Gamma[2 + n])/
             (Gamma[1/2 + n] ((2 n + 1) π (n!)^2/(2 ((2 n - 1)/2)! ((2 n + 1)/2)!) +
              π (n!)^2/(((2 n - 1)/2)!)^2))]
   (2^(3 + 2 n) (1 + n) Gamma[3/2 + n])/(Sqrt[π] Gamma[1 + n])

The result can of course be further simplified to 2^(2 n + 2) (n + 1) Pochhammer[3/2, n]/n!.

| improve this answer | |
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.