How to assign EdgeWeight to a multigraph?

Question

I'm trying to make a program to illustrate the simplify process of a complex resistence network. I create a graph to represent the structure of the network and trying to use EdgeWeight to symbolize the value of resistence. but sometimes I'll need to deal with parallel resistence, so assigning EdgeWeight to them will be a problem.

In simple graphs, one can use:

gg=Graph[{1<->2,2<->3,3<->1},EdgeWeight->{1,2,3}]

to specify the weight of each edge. Then we can use PropertyValue to extract them:

PropertyValue[{gg,#},EdgeWeight]&/@EdgeList@gg

{1,2,3}

But in a non-simple graph:

gg=Graph[{1<->2,1<->2,2<->3},EdgeWeight->{1,2,3}]

It seems that EdgeWeight simply ignored the weight assignment for parallel edges and consider all parallel edges to be the same:

PropertyValue[{gg, #}, EdgeWeight] & /@ EdgeList@gg

{1,1,3}

This put a great barrier on my programming, so how to solve this problem? How to allow multiple EdgeWeight assigned to parallel edges?

Answer 1

Mathematica's can't properly handle edge properties for multigraphs. The reason is that edges are typically referred to by their end vertices. Therefore there is no way to distinguish between multiple edges connecting the same vertices.

EdgeWeight, EdgeCost, and EdgeCapacity are the only edge properties which can even be stored for a multigraph. These properties are stored as simple lists. The kth element of the list corresponds to the kth edge.

Thus you can work with weighted multigraphs, but you must take care to only set or extract weights in a particular way.

You can extract weights as a vector like this:

wg = Graph[{1 <-> 2, 1 <-> 2, 1 <-> 3}, EdgeWeight -> {3, 4, 5}]

PropertyValue[wg, EdgeWeight]
(* {3, 4, 5} *)

Once these weights were set, you cannot easily change them. SetProperty[wg, EdgeWeight -> ...] or Graph[wg, EdgeWeight -> ...] will produce incorrect results.

You can do this instead:

Graph[VertexList[wg], EdgeList[wg], EdgeWeight -> newWeights]

Whether it's worth the trouble, I do not know. The risk of bumping into bugs is quite high.