Finding the two pairs in a list of pairs that minimize and maximize a given function

Question

I need to declare a list of ordered pairs, and with it I need to declare a function of two variables, say x and y, and print the ordered pairs giving the maximum and the minimum value on the function.

For example, suppose the list is

L = {{1, 2}, {5, 3}, {9, 2}} 

and the function is

2 x + y

With {x, y} = {1, 2}, I will get 4 , with {5, 3}, 13, and with {9, 2}, 20 . Then I need to print {1, 2} and {9, 2} as the result.

Can anyone help me with it please? I don't know how to write it!

Answer 1

list = {{1, 2}, {5, 3}, {9, 2}}
func = 2*#[[1]] + #[[2]] &;

Through[{MinimalBy[func], MaximalBy[func]}[list]]

{{{1, 2}}, {{9, 2}}}

---

Some Benchmarking:

benchMarkResults = Transpose@Table[
    With[{riList = RandomInteger[{1, 9999999}, {Round[10^n], 2}], rn = Round[10^n]},
     {{rn, 
       Through[{MinimalBy[func], MaximalBy[func]}[riList]]; // AbsoluteTiming // First},
      {rn, 
       riList[[Ordering[func /@ riList][[{1, -1}]]]]; // AbsoluteTiming // First},
      {rn, SortBy[riList, func][[{1, -1}]]; // AbsoluteTiming // First},
      {rn, 
       SortBy[riList, {N[func@#] &}][[{1, -1}]]; // AbsoluteTiming // First},
      {rn, SortBy[riList, {N@*func}][[{1, -1}]]; // AbsoluteTiming // First},
      {rn, 
       Pick[riList, #, Alternatives @@ MinMax@#] &[Function[{x, y}, 2 x + y] @@@ riList]; 
        // AbsoluteTiming // First}}],
    {n, 0, 7, 0.2}];

The gray line indicates where SystemOptions["CompileOptions" -> {"MapCompileLength"}] kicks in.

Answer 2

SortBy is useful. Taking Karsten's example input:

list = {{1, 2}, {5, 3}, {9, 2}};
func = 2*#[[1]] + #[[2]] &;

SortBy[list, func][[{1, -1}]]

{{1, 2}, {9, 2}}

---

To make this method robust one should convert the output to explicit numbers⁽¹⁾⁽²⁾ with N since e.g. Sort[{1, Pi, 5, 9}] evaluates to {1, 5, 9, π}. Also it is more efficient to use the stable sort syntax^{(1)(2)(3)(4)(5)}. Therefore what I should have written:

SortBy[list, {N@*func}][[{1, -1}]]

Or as Karsten7 points out, since Composition does not compile this is much faster on packable data:

SortBy[list, {N @ func @ # &}][[{1, -1}]]