How to express the function $a(t)$ knowing a parametrization $a(\eta)$ and $t(\eta)$?

Question

I have this function : \begin{equation}\tag{1} a(\eta) = \sqrt{\sin{2 \eta}}, \end{equation} and this time variable : \begin{equation}\tag{2} t(\eta) = \int_0^\eta a(\eta') \, d\eta'. \end{equation} This integral is very difficult to express in an analytical way, because of the square-root.

I would like to know the function $a$ parametrized as a power series of $t$. How can I achieve this ?

When $\eta$ is very small, I could get \begin{equation}\tag{3} a( \, \eta(t) \, ) \approx (3 \, t)^{\frac{1}{3}}. \end{equation} When $\eta$ isn't so small, I'm expecting something like this (but I could be wrong) : \begin{equation}\tag{4} a(\, \eta(t) \,) = (3 \, t)^{\frac{1}{3}} f(t), \end{equation} where $f(t)$ could be Taylor expanded (?). How to find this function using Mathematica ?

---

EDIT : To clarify a few things : I don't know the function $f(t)$ defined above. This is what I'm looking for, as a Taylor series of $t$.

I can integrate the function (1) to get $t(\eta)$ using Mathematica, as a power expansion :

FullSimplify[
    Series[
        Integrate[Sqrt[Abs[Sin[2 x]]], {x, 0, eta}, Assumptions -> 0 < eta < Pi/2],
    {eta, 0, 6}]
]

I then get this : \begin{equation}\tag{5} t(\eta) \approx \sqrt{2} \; \eta^{\frac{3}{2}} \big( \frac{2}{3} - \frac{2}{21} \; \eta^2 + \frac{1}{495} \; \eta^4 - \frac{1}{2835} \; \eta^6 \big). \end{equation} Then I need to invert this, to get $a(t) \equiv a( \, \eta(t) \, )$, as a power expansion in $t$ (or maybe $t^{1/3}$ ?). It should be pretty basic. As I said above, I'm expecting something like \begin{equation}\tag{6} a( \, \eta(t) \, ) = (3 \, t)^{\frac{1}{3}} f(t), \end{equation} with $f(t)$ an unknown Taylor series.

Answer 1

Use InverseSeries:

tserieseta=FullSimplify[Series[Integrate[Sqrt[Abs[Sin[2 x]]],{x,0,eta},Assumptions->0<eta<Pi/2],{eta,0,8}]]+O[eta]^10

$\frac{2}{3} \sqrt{2} \text{eta}^{3/2}-\frac{2}{21} \sqrt{2} \text{eta}^{7/2}+\frac{1}{495} \sqrt{2} \text{eta}^{11/2}-\frac{\sqrt{2} \text{eta}^{15/2}}{2835}-\frac{67 \text{eta}^{19/2}}{538650 \sqrt{2}}+O\left(\text{eta}^{10}\right)$

etaseriest = InverseSeries[tserieseta] /. eta -> t

$\frac{1}{2} 3^{2/3} t^{2/3}+\frac{3 t^2}{28}+\frac{999 \sqrt[3]{3} t^{10/3}}{43120}+\frac{837\ 3^{2/3} t^{14/3}}{120736}+\frac{1469583 t^6}{201870592}+O\left(t^{19/3}\right)$

Series[Sqrt[Sin[2*etaseriest]], {t, 0, 8}]

$\sqrt[3]{3} \sqrt[3]{t}-\frac{3}{14} 3^{2/3} t^{5/3}-\frac{405 t^3}{4312}-\frac{1647 \sqrt[3]{3} t^{13/3}}{60368}-\frac{6911325\ 3^{2/3} t^{17/3}}{706547072}+O\left(t^6\right)$

f[t] = %/(3 t)^(1/3)

$1-\frac{3}{14} \sqrt[3]{3} t^{4/3}-\frac{135\ 3^{2/3} t^{8/3}}{4312}-\frac{1647 t^4}{60368}-\frac{6911325 \sqrt[3]{3} t^{16/3}}{706547072}+O\left(t^{17/3}\right)$

Answer 2

Why not just expand s in a Taylor series and Integrate it?

a[s_] = Sqrt[Sin[2 s]];
tApprox[h_, order_] := Integrate[Series[a[s], {s, 0, order}], {s, 0, h}]
tExact[h_?NumericQ] := NIntegrate[a[s], {s, 0, h}]

Then:

tApprox[h, 1]
tApprox[h, 3]
(* 2/3 Sqrt[2] h^(3/2) *)
(* -(2/21) Sqrt[2] h^(3/2) (-7 + h^2) *)

and

p1 = Plot[tExact[h], {h, 0, π/2}];
Show[p1, Plot[Evaluate[tApprox[h, 1]], {h, 0, π/2}, PlotStyle -> Red]]
Show[p1, Plot[Evaluate[tApprox[h, 3]], {h, 0, π/2}, PlotStyle -> Red]]

Answer 3

This code works, except that it doesn't give the full answer. A part is missing :

time[eta_] := FullSimplify[
    Series[
        Integrate[Sqrt[Abs[Sin[2 x]]], {x, 0, eta}, Assumptions -> 0 < eta < Pi/2],
    {eta, 0, 6}]]

Eta[t_] := (3 t/(2 Sqrt[2]))^(2/3)  (* This isn't the final function! *)

a[t] := Series[Sqrt[Sin[2 Eta[t]]], {t, 0, 6}]

time[eta]

a[t]

This code need a fix : the function Eta[t] should be the inversion of time[eta]. How to do this ?