1
$\begingroup$

I have a ContourPlot3D that plots three planes:

planes = {-4 x + 5 y + 5 z == 10, -2 x - 3 y - 2 z == -5, -5 x + 5 y + 2 z == 7};

ContourPlot3D[planes, {x, -10, 10}, {y, -10, 10}, {z, -10, 10}, 
              AxesLabel -> {x, y, z}, Mesh -> None, ImageSize -> Medium, 
              SphericalRegion -> True]

In my application, I would like to restrict the user from being able to scale the size of the plot or be able to move it by clicking the orange border around it without restricting their ability to rotate the plot.

Putting it in a Row with Selectable -> False restricts the ability to rotate. Any help is greatly appreciated.

Also, if my request isn't feasible, its not the end of the world.

$\endgroup$
2
$\begingroup$

You can use Dynamic to lock the image size:

planes = {-4 x + 5 y + 5 z == 
    10, -2 x - 3 y - 2 z == -5, -5 x + 5 y + 2 z == 7};

DynamicModule[{size = Medium}, 
 ContourPlot3D[
  Evaluate@planes, {x, -10, 10}, {y, -10, 10}, {z, -10, 10}, 
  AxesLabel -> {x, y, z}, Mesh -> None, 
  ImageSize -> Dynamic[size, (size = Medium) &], 
  SphericalRegion -> True]]

You can still rotate, but when you try to resize, it just gets reset to Medium and nothing happens.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.