8
$\begingroup$

According to the manual:

"HoldAll is an attribute which specifies that all arguments to a function are to be maintained in an unevaluated form."

The following code yields, as expected, g[2,3] in Mathematica v9.01.

SetAttributes[f, HoldAll]; f[x_] := g @@ Unevaluated[x]; f[2 3]

When the function given the HoldAll attribute is defined as a pure function, the argument is evaluated despite the HoldAll attribute.

SetAttributes[h, HoldAll]; h = g @@ Unevaluated[#] &; h[2 3]

The above code returns 6 because the 2 3 multiplication is evaluated before being fed to h (use Trace to confirm the order).

1) Is the above behavior a bug or should it be considered a "documented feature"?

2) Is the above behavior consistent across Mathematica versions?

$\endgroup$
  • $\begingroup$ Try this: h = Function[Null, g @@ Unevaluated[#], HoldAll]. $\endgroup$ – J. M. will be back soon Aug 1 '16 at 18:33
  • $\begingroup$ The right way is what JM said. And if you think about it, you'll realize that this is actually a very weird and unique situation in Mathematica. It is a case of x being held in an expression of the form f[y][x]. This is only possible when f is Function and likely needs to be treated as a special case by the evaluator. $\endgroup$ – Szabolcs Aug 1 '16 at 18:36
  • 1
    $\begingroup$ @J.M.: I understand that there are workarounds. I am wondering whether I am misinterpreting the manual. $\endgroup$ – Hector Aug 1 '16 at 18:39
  • 1
    $\begingroup$ @Hector There is no bug. You are confused by how the manual uses the word "function". It is important to understand that Mathematica has no functions, only expressions and transformation rules. I wrote an answer. $\endgroup$ – Szabolcs Aug 1 '16 at 18:52
  • 2
    $\begingroup$ I think this question exposes one of the most common misconceptions about the language. $\endgroup$ – rcollyer Aug 1 '16 at 20:00
16
$\begingroup$

A response to this comment:

I understand that there are workarounds. I am wondering whether I am misinterpreting the manual.

Yes. The use of the word "function" in the manual may be confusing here. It is symbols that have attributes, not "functions". Attributes have an effect only at certain specific steps of the evaluation sequence, and only when the relevant symbol is the head of the expression that is being evaluated.

Here's the description of the evaluation sequence:

Given an expression h[e1, e2, ...],

  1. If the expression is a raw object (e.g., Integer, String, etc.), leave it unchanged.

  2. Evaluate the head h of the expression.

  3. Evaluate each element $e_i$ of the expression in turn. If h is a symbol with attributes HoldFirst, HoldRest, HoldAll, or HoldAllComplete, then skip evaluation of certain elements.

  4. (... several steps we don't care about now ...)

  5. Use any built-in transformation rules for h[e1, e2, ...] or for h[...][...].

What happens to your expression h[2*3] is this:

First, h gets evaluated to Function[g @@ Unevaluated[#]]. Now Function[...] would get evaluated further if it had any applicable transformation rules, but it doesn't. Next the system looks at transformation rules for Function[...][...] instead (notice the second set of brackets). There are rules for this, so the evaluation proceeds.

Notice that we never reached step 2. which would check any attributes of h! h already got replaced at step 1. Thus the attributes of h do not matter.


Another way to put it is that attributes do not belong to "functions". They belong to symbols, in your case to the symbol h.

Mathematica doesn't even have functions in the traditional sense. It has transformation rules.

The symbol h has an associated transformation rule which causes it to be replaced before any of its attributes could come into play.


Finally I'll just repeat J.M.'s comment. Use this:

h = Function[Null, g @@ Unevaluated[#], HoldAll]

I'll also note that Function is a very special symbol that has very special evaluation rules: the evaluator will hold y in an expression of the form f[x][y] only when f is Function (and in no other situation). In particular, it is not possible to bestow a custom symbol with this property.

$\endgroup$
  • $\begingroup$ Let me see if I understand. When I use SetAttributes[h, HoldAll], the symbol h acquires the attribute. When we use Function[Null, g @@ Unevaluated[#], HoldAll], the value of the symbol h gets the attribute. I think I got it. $\endgroup$ – Hector Aug 1 '16 at 22:36
  • $\begingroup$ I think you might have gotten your numbering mixed up. There are references to step 2 and step 1 that look like they were meant to refer to step 3 and step 2. $\endgroup$ – user2357112 Aug 1 '16 at 23:41
  • $\begingroup$ Congratulations on reaching 100k! That is a lot of hours of your life invested in this site. $\endgroup$ – Mr.Wizard Aug 2 '16 at 7:10
  • $\begingroup$ @Hector Yes, something like that. Except that the use of these attributes inside of Function is a very special case that doesn't follow from the general principles of the Wolfram Language. $\endgroup$ – Szabolcs Aug 2 '16 at 8:55

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.