0
$\begingroup$

I want to find the numerical value of alpha in function

(-E^-x α + E^-x x α)^2/(2 (1 - E^-x x α)^2)

above which the function is unity for some positive values of x.

Answer is approximately 2.4095.

$\endgroup$
  • $\begingroup$ Welcome to Mathematica.SE! I suggest the following: 1) As you receive help, try to give it too, by answering questions in your area of expertise. 2) Take the tour! 3) When you see good questions and answers, vote them up by clicking the gray triangles, because the credibility of the system is based on the reputation gained by users sharing their knowledge. Also, please remember to accept the answer, if any, that solves your problem, by clicking the checkmark sign! $\endgroup$ – Michael E2 Jul 28 '16 at 11:49
  • $\begingroup$ Why not discuss how you found your approximate answer? We might be able to adapt this to Mathematica. $\endgroup$ – J. M.'s technical difficulties Jul 28 '16 at 11:55
  • $\begingroup$ I can see how you got the value 2.4095 from the image i.stack.imgur.com/CpjQO.png, but it also appears not to be the optimal answer to the problem as currently stated. $\endgroup$ – Michael E2 Jul 28 '16 at 12:06
1
$\begingroup$
expr = (-E^-x α + E^-x x α)^2/(2 (1 - E^-x x α)^2);

ContourPlot[expr == 1, {x, 0, 3}, {α, 0, 4}, FrameLabel -> Automatic]

enter image description here

The global minimum is at the boundary

min1 = NMinimize[{α, expr == 1, x > 0, α > 0}, {α, x}]

(*  {1.41421, {α -> 1.41421, x -> 2.40504*10^-8}}  *)

expr /. {α -> Sqrt[2], x -> 0}

(*  1  *)

The local minimum for x > 1

min2 = NMinimize[{α, expr == 1, x > 1, α > 1}, {α, x}, 
  WorkingPrecision -> 15]

(*  {2.40948624835748, {α -> 2.40948624835748, x -> 1.41421356285863}}  *)

The value returned for x is approximately Sqrt[2]

min3 = MinValue[{α, (expr /. x -> Sqrt[2]) == 1, α > 
     0}, α] // FullSimplify

(*  -(-2 + Sqrt[2]) E^Sqrt[2]  *)

min3 // N[#, 15] &

(*  2.40948628645477  *)

expr /. {x -> Sqrt[2], α -> min3} // Simplify

(*  1  *)
|improve this answer|||||
$\endgroup$
  • $\begingroup$ +1. ContourPlot was used to get the initial idea about the minima. How to proceed initially if one needs to minimize two parameters for positive x, for example in (8 x^(2/3) [Alpha]^2 (-1 + x^(4/3) [Beta])^2)/(9 (E^( x^(4/3) [Beta]) - x^(4/3) [Alpha])^2) $\endgroup$ – Sluth Jul 29 '16 at 15:43
  • $\begingroup$ @Sluth - If you want to minimize two parameters you have to state how you want this done, i.e., define a function of the two parameters to be minimized, e.g., minimize a^2 + b^2. Also you state that x is positive but what are the constraints on the two parameters? Is the expression given in the comment also supposed to equal unity? All of these questions should be included in a new question rather than asking a question in a comment. Note that ContourPlot3D can show contours in {x, a, b} space. $\endgroup$ – Bob Hanlon Jul 30 '16 at 3:04

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.