How to save in PDF the SAME Result? The numbers and Labels in graph are erased when I save the PDF

Question

I want to save some bullet gauges in PDF, as a dashboard, but what I obtain in the PDF has the numbers erased, and the Titles/Numbers erased as you can see here

when What Mathematica10 show is

Note that Mathematica save PDF well, as is showed if you don´t rotate the gauges.

The code is

DataFile = {{"Man", "First", 215, 230, 120, 80, 65}, {"Man", "Second",
    240, 450, 180, 150, 114}, {"Woman", "First", 275, 450, 210, 190, 
   43}, {"Woman", "Second", 275, 275, 145, 134, 96}, {"Woman", 
   "Third", 200, 240, 20, 18, 12}}

NumeroPropiedades = Length[DataFile];
lonxitude = 
  Table[StringLength[DataFile[[i, 1]]], {i, 1, NumeroPropiedades}];
Max[lonxitude];

MaximoEscala = Max[Table[DataFile[[i, 4]], {i, 1, NumeroPropiedades}]];

rotate[gauge_] := 
 Rotate[gauge /. Text[l_, r__] :> Text[Rotate[l, 270 Degree], r], 
  90 Degree]
(* copied from http://ow.ly/zdSc302jZEm *)

BulletTOTAL = 
  Table[BulletGauge[{DataFile[[i, 5]], 
     DataFile[[i, 4]]*0.75}, {DataFile[[i, 3]]}, {0, DataFile[[i, 4]],
      DataFile[[i, 6]], DataFile[[i, 7]], MaximoEscala}, 
    ImageSize -> Large, 
    GaugeLabels -> 
     Placed[Style[Rotate[DataFile[[i, 1]], 3 Pi/2], "Subsection", 
       Black], Right]], {i, 1, NumeroPropiedades}];
Labeled[Row[rotate /@
   BulletTOTAL
  , Spacer[20]], 
 Row[{Style["Monthly", 39, "Subtitle", Darker[Red]]}, Spacer[30]], Top]

================== SOLUTION ======================== **

As Karsten7 said, in a comment It was a bug that was fixed between version 10.0 and 10.4.1

**

Answer 1

You can try using a direction vector for Text instead of using Rotate to rotate the labels, as demonstrated in this answer:

DataFile = {{"Man", "First", 215, 230, 120, 80, 65}, {"Man", "Second",
     240, 450, 180, 150, 114}, {"Woman", "First", 275, 450, 210, 190, 
    43}, {"Woman", "Second", 275, 275, 145, 134, 96}, {"Woman", 
    "Third", 200, 240, 20, 18, 12}};

NumeroPropiedades = Length[DataFile];
lonxitude = Table[StringLength[DataFile[[i, 1]]], {i, 1, NumeroPropiedades}];

MaximoEscala = 
  Max[Table[DataFile[[i, 4]], {i, 1, NumeroPropiedades}]];

rotate[gauge_] := 
 Rotate[gauge /. 
   Text[value_, Offset[o_, s_], d1_, {1, 0}] :> 
    Text[value, Offset[{0.5, -12.}, s], {0., 0.}, {0, -1}], 90 Degree]

BulletTOTAL = 
  Table[BulletGauge[{DataFile[[i, 5]], 
     DataFile[[i, 4]]*0.75}, {DataFile[[i, 3]]}, {0, DataFile[[i, 4]],
      DataFile[[i, 6]], DataFile[[i, 7]], MaximoEscala}, 
    ImageSize -> Large, 
    GaugeLabels -> 
     Placed[Graphics@
       Text[Column[{Style[DataFile[[i, 2]], 18], 
          Style[DataFile[[i, 1]], 25, Bold]}, Center], {0, 0}, 
        Automatic, {0, -1}], {1, 2/3}]], {i, 1, NumeroPropiedades}];
Labeled[Row[rotate /@ BulletTOTAL, Spacer[20]], 
 Row[{Style["Monthly", 39, "Subtitle", Darker[Red]]}, 
  Spacer[30]], Top]

Alternatively one can use VerticalGauge to produce fake vertical BulletGauges.

BulletTOTAL = Table[
   Show[{
     VerticalGauge[0, {0, MaximoEscala}, ScaleDivisions -> {5, 1}, 
      ScaleRanges -> ({#, {0, 0.2}} & /@ 
         Partition[
          Sort@{0, DataFile[[i, 4]], DataFile[[i, 6]], 
            DataFile[[i, 7]], MaximoEscala}, 2, 1]), 
      ScaleRangeStyle -> {GrayLevel[0.6], GrayLevel[0.7], 
        GrayLevel[0.8], GrayLevel[0.9]}, GaugeMarkers -> None, 
      ImageSize -> Large],
     VerticalGauge[{DataFile[[i, 3]]}, {0, MaximoEscala}, 
      ScaleDivisions -> {5, 1},
      ScaleRanges -> ({#, {0.06, 0.14}} & /@ 
         Partition[Sort@{0, DataFile[[i, 5]], DataFile[[i, 4]]*0.75}, 
          2, 1]), ScaleRangeStyle -> 
       Reverse[ColorData[63, "ColorList"][[;; 2]]], 
      GaugeMarkers -> 
       Graphics[{GrayLevel[0.1], Opacity[0.5], Thickness[0.07], 
         Line[{{0, 0}, {3 + 1/3, 0}}]}], 
      GaugeLabels -> 
       Placed[Column[{Style[DataFile[[i, 2]], 18], 
          Style[DataFile[[i, 1]], 25, Bold]}, Center], {0.16, 0.97}], 
      ImageSize -> Large]
     }, AspectRatio -> 7
    ], {i, 1, NumeroPropiedades}];

Labeled[Row[BulletTOTAL, Spacer[20]], 
 Row[{Style["Monthly", 39, "Subtitle", Darker[Red]]}, 
  Spacer[30]], Top]