How to retouch (smart fill) photo image?

Question

Can the program proposed by Alexei Boulbitch at the post of Custom arrow shaft be adapted to retouch an image in setting a mask arround the part one desires to disapear? This is only a suggestion, there may be a more straightforward way to do it.

In the famous following picture

Nicolas Yehzov has been edited out. The original picture was the following

I was wondering if It could be done in Mathematica, in the same way one can extract a part of an image. The reason for which I refer to the Custom arrow shaft post is that I think the mechanism must be similar.

Added this afternoon

Sorry not to have been enough precise. Here is how i can operate under LaTeX + PsTricks

I can construct a mask by hand, point to point --- which is particularly borying --- and erase one of the mass killers. It's there that I was thinking of Alexei's Code. After that either I can mask the part under the clipping path or I can add negatively for the rest of the image. The whith the help of the various graphic commands I can reconstruct the missing part. For instance it should not been too difficult to rebuild the wall and the water.

Perhaps with today technology can we do a better job than the one of the past where you see the effect of pencil drawing. Of course, here is not my intension but I give always to my students some pictures to anchor them in reality.

In all the case I am particularly gratefull to all your answer even if the questions are not always clear. I am particularly impress by your skills and by this incredible tool I have had for nearly 30 years without realizing how it could be such a great tool.

Answer 1

Here's a google drive link to the Notebook.

1. Use "Mask tool" to select area to inpaint, copy as image, store somewhere.
2. Do the same to select the area which should be used to probe texture from.
3. Repeat for all environments.
4. Fold Inpaint.

A GIF animation of the masks (included here in order to make the post self-contained):

img = Import["https://i.sstatic.net/d3AXT.jpg"];

{waterMask, waterSource, headMask, headSource, shadowMask, shadowSource, edgeMask, 
  edgeSource, coatMask, coatSource} = Import["https://i.sstatic.net/x4v6b.gif"];

Fold[
 Inpaint[#, First@#2, 
   Method -> {"TextureSynthesis", Masking -> Last@#2}] &,
 img,
 {
  {waterMask, waterSource},
  {headMask, headSource},
  {shadowMask, shadowSource},
  {edgeMask, edgeSource},
  {coatMask, coatSource}
  }
 ]

I have to polish a handrail but looks quite good.

Answer 2

Here is a way to do it, but it needs a lot 'artistic' touch.

First Import the image.

img = Import["https://i.sstatic.net/d3AXT.jpg"];

Then create the Mask using interface (thanks Kuba).

From orange Copy choose Mask as ...

mask = (*Ctrl+v*)

Finally

Inpaint[img, mask] 

I guess you have to do some fine tuning by hand. Try hard and you can make him completely disappear. I don't have that much talent or courage to mess with history.

---

If you want to do it with numbers then find the location of right person.

{x1, x2} = {545, 800};
{y1, y2} = {10, 500};
{l, h} = ImageDimensions[img];
i1 = ImageTake[img, {h - y2, h - y1}, {x1, x2}]

i2 = Graphics[{Inset[i1, {x1, y1}, {0, 0}, {x2 - x1, y2 - y1}]}, 
     PlotRange -> {{1, l}, {1, h}}, ImageSize -> {l, h}];
mask = DeleteSmallComponents@FillingTransform@ChanVeseBinarize[i2, 
     "TargetColor" -> Darker[Gray]]