5
$\begingroup$

Recently I need to compute the summation like the following form:

Sum[t^Abs[n - m], {n, -∞, ∞}, Assumptions -> m ∈ Integers]

But Mathematica cannot figure it out:

enter image description here

Although it would be simple to compute without m:

enter image description here

I wonder why and how could I solve it?

$\endgroup$
1
  • $\begingroup$ Note that the second result is not correct without additional assumptions. $\endgroup$
    – Michael E2
    Jul 11, 2016 at 21:19

2 Answers 2

5
$\begingroup$

This sum is indeed possible to compute as it is using the FourierSequenceTransform. Some algorithms of MA are obviously more advanced than others:

s = FourierSequenceTransform[t^Abs[n - m], n, w, Assumptions -> m \[Element] Integers]
(*(E^(-I (-1 + m) w) (-1 + t^2))/((E^(I w) - t) (-1 + E^(I w) t))*)

Now we recall that for $w\rightarrow 0$ the desired sum is obtained

Cancel[s/. w -> 0]
(*(1 + t)/(1 - t)*)

And, as @Michael E2 noticed, one should pay attention to the radius of convergence of the sum.

$\endgroup$
2
  • $\begingroup$ Thank you! But how about a even complex summation, like this one: Sum[t^(1/2 (Abs[n - m1] + Abs[n - m2]) + 3/2 (Abs[m1] + Abs[m2]) + m2 - m1), {n, -\[Infinity], \[Infinity]}, {m2, -\[Infinity], \ \[Infinity]}, {m1, m2, \[Infinity]}] This summation should have a simple result, as I have computed it manually. But mathematica can't solve this summation using above method $\endgroup$
    – user27490
    Jul 11, 2016 at 22:44
  • $\begingroup$ @user27490 How have you reformulated your sum m1to run in infinite limits? Only then it will be suitable for Fourier methods. $\endgroup$
    – yarchik
    Jul 12, 2016 at 13:47
3
$\begingroup$

It seems to help to explicitly expand Abs, which by default is a function over the complexes, for a real/integer argument:

Assuming[
 {k, m} ∈ Integers,
 Sum[t^Abs[k - m] // PiecewiseExpand, {k, -∞, ∞}, 
  Assumptions -> m ∈ Integers && Abs[t] < 1]
 ]
(*  (-1 - t)/(-1 + t)  *)

Follow-up to comment:

Maybe deconstruct the pieces semi-manually? (I assume Sum does something like this above, but gives up here.)

summand = Assuming[{k, m1, m2} ∈ Integers, 
   t^(1/2 (Abs[k - m1] + Abs[k - m2]) + 3/2 (Abs[m1] + Abs[m2]) + m2 - m1) //
     PiecewiseExpand[#, Method -> {"ConditionSimplifier" -> Simplify}] &
   ];
Simplify@ Total@ Assuming[{k, m1, m2} ∈ Integers,
   Sum[Piecewise[{#}, 0],
      {k, -∞, ∞}, {m2, -∞, ∞}, {m1, m2, ∞}, 
      Assumptions -> k ∈ Integers && m1 ∈ Integers && m2 ∈ Integers && Abs[t] < 1] & /@ 
    Append[First@summand, {Last@summand, Or @@ summand[[1, All, 2]] // Not // Reduce}]
   ]
(*  -((1 + 4 t + 4 t^2 + 5 t^3 + 4 t^4) / ((-1 + t)^3 (1 + t + t^2)))  *)
$\endgroup$
2
  • $\begingroup$ Thank you! But how about a even complex summation, like this one: Assuming[{n, m1, m2} \[Element] Integers, Sum[t^(1/2 (Abs[n - m1] + Abs[n - m2]) + 3/2 (Abs[m1] + Abs[m2]) + m2 - m1) // PiecewiseExpand, {n, -\[Infinity], \[Infinity]}, {m2, \ -\[Infinity], \[Infinity]}, {m1, m2, \[Infinity]}, Assumptions -> n \[Element] Integers && m1 \[Element] Integers && m2 \[Element] Integers && Abs[t] < 1]] This summation should have a simple result, as I have computed it manually. But mathematica can't solve this summation using above method. $\endgroup$
    – user27490
    Jul 11, 2016 at 22:42
  • $\begingroup$ @user27490 : Instead of adding essentially the same comment to every answer, could you instead update your question so that it is actually the question you want answered? $\endgroup$ Jul 12, 2016 at 5:36

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.