13
$\begingroup$

The default value of Lighting in 3D graphics typically uses "Standard", with several coloured lights, or "Neutral", depending on the type of plot.

What is the explicit lighting specification for "Standard" and "Neutral", in terms of actual light positions, directions, colours and types?

$\endgroup$
  • 5
    $\begingroup$ How about the second answer here: mathematica.stackexchange.com/questions/27616/… $\endgroup$ – Feyre Jul 1 '16 at 12:02
  • $\begingroup$ @Feyre Yes, that's the answer. Thank you. I would rather you post it as an answer here because that question seems to ask something different (by the title) and I really couldn't find the answer after searching both here and the documentation ... $\endgroup$ – Szabolcs Jul 1 '16 at 12:09
  • $\begingroup$ I'm surprised you didn't find an answer in the docs. I searched on "lighting default" and found the answer in the third hit. $\endgroup$ – m_goldberg Jul 1 '16 at 12:17
  • 3
    $\begingroup$ For your perusal: System`PlotThemeDump`resolvePlotTheme["DefaultLights", Graphics3D] and System`PlotThemeDump`resolvePlotTheme["ClassicLights", Graphics3D]. $\endgroup$ – J. M.'s technical difficulties Jul 1 '16 at 12:26
  • $\begingroup$ @m_goldberg Well, I didn't search for those specific words as I was concentrating on figuring out what "Standard" is. Of course that seems silly now that I chose those words for the title of the post ... Also, the relevant page doesn't contain the word "Standard". $\endgroup$ – Szabolcs Jul 1 '16 at 12:55
11
$\begingroup$

The answer can be found here: Change The Lighting Of Plots in the official How Tos.

For "Standard"/Automatic:

Graphics3D[Sphere[], 
           Lighting -> {{"Ambient", RGBColor[0.4, 0.2, 0.2]},
                        {"Directional", RGBColor[0, 0.18, 0.5], ImageScaled[{2, 0, 2}]},
                        {"Directional", RGBColor[0.18, 0.5, 0.18], ImageScaled[{2, 2, 3}]},
                        {"Directional", RGBColor[0.5, 0.18, 0], ImageScaled[{0, 2, 2}]},
                        {"Directional", RGBColor[0, 0, 0.18], ImageScaled[{0, 0, 2}]}}]

For "Classic":

Graphics3D[Sphere[], 
           Lighting -> {{"Ambient", RGBColor[0.312, 0.188, 0.4]},
                        {"Directional", RGBColor[0.8, 0., 0.], ImageScaled[{2, 0, 2}]},
                        {"Directional", RGBColor[0., 0.8, 0.], ImageScaled[{2, 2, 2}]},
                        {"Directional", RGBColor[0., 0., 0.8], ImageScaled[{0, 2, 2}]}}]

For "Neutral":

Graphics3D[Sphere[], 
           Lighting -> {{"Ambient", RGBColor[0.35, 0.35, 0.35]},
                        {"Directional", RGBColor[0.37, 0.37, 0.37], ImageScaled[{2, 0, 2}]},
                        {"Directional", RGBColor[0.37, 0.37, 0.37], ImageScaled[{2, 2, 2}]},
                        {"Directional", RGBColor[0.37, 0.37, 0.37], ImageScaled[{0, 2, 2}]}}]
|improve this answer|||||
$\endgroup$
  • $\begingroup$ I added the one for Neutral too, hope you don't mind :-) Thanks! Also, I just learned about ImageScaled. $\endgroup$ – Szabolcs Jul 1 '16 at 12:13
  • $\begingroup$ No, I should have immediately added it, you did ask about both. $\endgroup$ – Feyre Jul 1 '16 at 12:17

Not the answer you're looking for? Browse other questions tagged or ask your own question.