# Make two parametric plots just touch (single intersection point)

topc[u_] := {(1099 E^(-1077 u/4000) (1077 Cos[u] - 4000 Sin[u]))/
89750, (12448145 + 4396 E^(-1077 u/4000) (4000 Cos[u] + 1077 Sin[u]))/359000}

botc[t_, aa_, bb_] :=
{-(aa/Sqrt[1 + bb^2]) + aa E^(bb t) Cos[t + ArcTan[bb]],
-((aa bb)/Sqrt[1 + bb^2]) + aa E^(bb t) Sin[t + ArcTan[bb]]}

targetp = {-(71171/1000), -(17884/1000)}

Manipulate[
Show[
ParametricPlot[topc[u], {u, 0, 4*Pi},
Frame -> True, AspectRatio -> Automatic, PlotRange -> All, AxesOrigin -> {0, 0}],
ParametricPlot[botc[t, aa, bb], {t, 0, cc}],
Graphics[Point[targetp]]
],
{aa, 6, 10}, {bb, .5, .9}, {cc, 2.5, 4}]


I apologize for poor the formatting.

I have one "fixed" parametric topc and I want to adjust the parameters of a second parametric botc so they intersect at a single point. They are logarithmic spirals, if that helps. I'd like to generally know how to solve this for what combination of aa and bb (cc can just be big), but in this particular case, I would also like the second parametric to terminate at target point targetp. I believe it is achievable because with Manipulate I can get close (e.g., 7.81, .804, 2.66), but I would like to know how to get the exact solution.

• Welcome! I suggest the following: 1) As you receive help, try to give it too, by answering questions in your area of expertise. 2) Take the tour and check the faqs! 3) When you see good questions and answers, vote them up by clicking the gray triangles, because the credibility of the system is based on the reputation gained by users sharing their knowledge. Remember to accept the answer, if any, that solves your problem, by clicking the checkmark sign! – user9660 Jun 30 '16 at 19:14
• You might be interested in (55039), (33947), and (84566). – MarcoB Jun 30 '16 at 19:37
• Thank you for the welcome. I had actually spent a good amount of time reviewing your 2nd and 3rd references, and the great answers are what encouraged me to sign up and post this question. The thing that is different in my case is that I'm actually wanting to change the parametric curve to cause an intersection, rather than just finding the intersections, and then also this concept of a single intersection point, instead of two (although I believe this could be iterated to through some process). The target point is a separate constraint, but disambiguating. – Roverone Jul 1 '16 at 2:30

Needing to explain a problem to someone else always helps to frame the possible answers.

I think this did it for me:

NMinimize[{
EuclideanDistance[topc[u], botc[t, aa, bb]] +
EuclideanDistance[botc[t2, aa, bb], targetp],
u > 1, t > 1, t2 > 2.5, t2 < 2.7, aa > 7, aa < 8, bb > .75, bb < .9},
{u, t, t2, aa, bb},
Method -> "DifferentialEvolution", AccuracyGoal -> 20,
PrecisionGoal -> 18, WorkingPrecision -> 40
]

(* Out:
{1.465088839383683150383175135295538390948*10^-18,
{u -> 2.743229589247772339496766690216749822960,
t -> 1.299658067345949266094374009407513665953,
t2 -> 2.663270615045027047071529010580577232557,
aa -> 7.860795524809032465215910875839111415513,
bb -> 0.8007220938880252978547788832651505336813}}
*)

• I'm glad you were able to solve your problem! Thanks for summarizing your solution. (+1) – MarcoB Jul 1 '16 at 4:52