Reduce a complex inequality

Question

Reduce[Abs[1/(1 + I/Sqrt[α])] < 0.5, {α}]

It is taking long time to run. Can any one help me to get the reduced condition in terms of $\alpha$ or its modulus. Note that $\alpha$ is a complex number.

Answer 1

First of all you shouldn't (if possible) use approximate numbers working with symbolic functionality like a very sophisticated function Reduce.
Before seeking the set of your interest try to envisage the region:

RegionPlot[ Abs[1/(1 + I/Sqrt[x + I y])] < 1/2, 
                  {x, -1.1, 0.5}, {y, -0.6, 1.0}]

Now we can see what we are to find, i.e. dependence of the boundary of this set, i.e. we should find a few functions yielding y as a function of x on the boundary. We can do it with Reduce if α will be rewritten as x+ I y:

Reduce[ Abs[1/(1 + I/Sqrt[x + I y])] == 1/2 && x ∈ Reals && y ∈ Reals, {x, y}]

(x == -1 && y == 0)                                                ||
(-1 < x < -(1/9) && y == Root[1 + 4 x - 42 x^2 + 36 x^3 + 
             81 x^4 + (-46 + 36 x + 162 x^2) #1^2 + 81 #1^4 &, 2]) || 
(x == -(1/9) && y == 4/(3 Sqrt[3]))                                || 
(-(1/9) < x <= 1/3  && ( y == Root[1 + 4 x - 42 x^2 + 36 x^3 + 
             81 x^4 + (-46 + 36 x + 162 x^2) #1^2 + 81 #1^4 &, 2]  || 
                         y == Root[1 + 4 x - 42 x^2 + 36 x^3 + 
             81 x^4 + (-46 + 36 x + 162 x^2) #1^2 + 81 #1^4 &, 4]))||
(1/3 < x < 7/18 &&   (   y == Root[1 + 4 x - 42 x^2 + 36 x^3 + 
             81 x^4 + (-46 + 36 x + 162 x^2) #1^2 + 81 #1^4 &, 3]  || 
                         y == Root[1 + 4 x - 42 x^2 + 36 x^3 + 
             81 x^4 + (-46 + 36 x + 162 x^2) #1^2 + 81 #1^4 &,4])) || 
(x == 7/18 && y == Sqrt[5/3]/6)

To figure out why the solution looks slightly involved see e.g.

Plot[ ReIm /@ Table[ Root[ 1 + 4 x - 42 x^2 + 36 x^3 + 
        81 x^4 + (-46 + 36 x + 162 x^2) #1^2 + 81 #1^4 &, k],
                     {k, {2, 3, 4}}] // Flatten,
      {x, -1, 1}, Evaluated -> True, Exclusions -> {-(1/9)}, 
      AspectRatio -> Automatic, PlotStyle -> Thick]

There are three roots involved to describe the boundary, this also clarifies why it was difficult to find this set directly using α as a complex unknown.
If we plot all the roots of the underlying polynomial then the curves will form more symmetric pattern:

Plot[ ReIm /@ Table[ Root[ 1 + 4 x - 42 x^2 + 36 x^3 + 81 x^4 
      + (-46 + 36 x + 162 x^2) #1^2 + 81 #1^4 &, k], {k, 4}] // Flatten,
     {x, -1, 1}, Evaluated -> True, Exclusions -> {-(1/9)}, 
     AspectRatio -> Automatic, PlotStyle -> Thick]

There were interesting posts discussing how roots of polynomials are numbered.