3
$\begingroup$

Firstly: I am completely new to Mathematica, but I need to be able to create a 3D Scatter Graph with the following points:

{0.000824, 15.8, 39.0}, {0.000507, 20.5, 39.6}, {0.000444, 20.5, 39.8}, {0.000380, 20.4, 40.8}, {0.000317, 22.0, 40.9}

I also want the axes labelled: {"Oxygen Concentration","Temperature","Salinity"}

The things that I also want are each of the points labelled from P1 to P5 respictively. I would also like the different colours for each point as well as the axis gridlines.

It would be a great help if someone could do this. What I have done so far is:

ListPointPlot3D[{{0.000824, 15.8, 39.0}, {0.000507, 20.5, 39.6}, {0.000444, 20.5, 39.8}, {0.000380, 20.4, 40.8}, {0.000317, 22.0, 40.9}}, Axes -> True, AxesLabel -> {"Oxygen Concentration", "Salinity", "Temperature"}, Boxed -> False, ColorFunction -> "Rainbow"]

$\endgroup$
3
$\begingroup$
data = {{0.000824, 15.8, 39.0}, {0.000507, 20.5, 39.6}, {0.000444, 20.5, 39.8}, 
        {0.000380, 20.4, 40.8}, {0.000317, 22.0, 40.9}};
bcdata = {##, 1} & @@@ data;
labels = Style["P" <> #, 16, Bold] & /@ CharacterRange["1", "5"];

BubbleChart3D[bcdata, Boxed -> False, Axes -> True, FaceGrids -> All, 
 AxesLabel -> {"Oxygen Concentration", "Salinity", "Temperature"}, 
 ColorFunction -> (ColorData["Rainbow"][#3] &), ChartLabels -> labels]

Mathematica graphics

$\endgroup$
  • $\begingroup$ Wonderful effect. :) $\endgroup$ – yode Jun 11 '16 at 16:10
0
$\begingroup$
point = {{0.000824, 15.8, 39.0}, {0.000507, 20.5, 39.6}, {0.000444, 
    20.5, 39.8}, {0.000380, 20.4, 40.8}, {0.000317, 22.0, 40.9}};
Graphics3D[{{Red, 
   MapIndexed[Text["P" <> ToString[First[#2]], #1 + {0, .2, 0}] &, 
    point]}, PointSize[.01], Point[point]}, Boxed -> True, 
 PlotRange -> CoordinateBounds[point, {2, .5, .5}], Axes -> True, 
 LabelStyle -> Directive[Bold, Medium], 
 AxesLabel -> {"Oxygen Concentration", "Salinity", "Temperature"}]

Maybe this can help.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.