1
$\begingroup$

I have two circles that intersect at point A, as shown in the image:

enter image description here

The first figure shows the circle center greater (${125,0}$) in its initial position.

The second figure shows the circle center greater (${-109.827,59.6919}$) in its final position.

We can observe that the point $A$ moves across the circles.

In its final position the circles are tangent.

The center of the larger circle follows the path given by the equation:

ParametricPlot[{125 Cos[25 t + 20 t^2], 125 Sin[25 t + 20 t^2]}, {t, 
  0, 0.0980576}]

Below my demonstration of the situation (Please excuse me. I am not able to insert the code with CRTL+V):

enter image description here

My question is as follows: How can I get the list that describes the coordinates of point A relative to {0,0} as a function of time?

Note: If there are any grammatical errors, please forgive me, therefore The English language is not my native language.

$\endgroup$
  • $\begingroup$ Here's one way to find the general solution for the intersection of two circles: Solve[{(x - x1)^2 + (y - y1)^2 == r1, (x - x2)^2 + (y - y2)^2 == r2}, {x, y}] $\endgroup$ – bill s Jun 9 '16 at 23:45
4
$\begingroup$

I post this with the following interpretation. There are 2 unequal size circles: one fixed and one rolling without slipping (cycloid). The circles initially intersected and the desire is to animate their intersection (I have made the approximate 'kissing of the circle continue on). I have made convenient choices for origins etc. If this is close to the desired it can be adapted as required. If not close apologies.

cycloid[t_, t0_] := {t - Sin[t - t0], 1 - Cos[t - t0]}
theta[t_] := t + 2 t^2;
cint[p_] := Module[{
   cf = (u + 1)^2 + (v - 1/2)^2 == 1/4,
   cm = (u - p)^2 + (v - 1)^2 == 1, pi},
  pi = Quiet[Solve[{cm, cf}, {u, v}, Reals]];
  If[Length[pi] > 0, Point[{u, v} /. pi], Sequence[]]
  ]
kiss = t /. 
   First@NSolve[{Norm[{theta[t], 1} - {-1, 1/2}] == 3/2, t > 0}, t, 
     Reals];
kp = cint[theta[0.99 kiss]][[1, 1]];
angle = ArcTan[#2/#1 & @@ ((cint[0][[1, 1]]) - {0, 1})];
tab = Table[With[{pos = theta[t], cnt = {-1, 1/2}},
    Show[
     Graphics[{Circle[cnt, 1/2], Circle[{pos, 1}, 1], PointSize[0.01],
        Point[cycloid[pos, 0
         ]],
       Orange, Point[cnt], Point[{pos, 1}],
       Red, cint[pos], 
       If[t < kiss, {Opacity[0], Point[kp]}, {Red, 
         Point[cycloid[pos, angle - Pi/2]]}],
       Purple, Thick,
       InfiniteLine[{0, 0}, {1, 0}]
       }, PlotRange -> {{-2, 20}, {-0.1, 2}}], 
     ParametricPlot[cycloid[u, 0], {u, 0, 6 Pi}, PlotStyle -> Dashed],
      ImageSize -> {800, 400}]],
   {t, 0, 2.8, 0.1}];
anim = Join[tab, Reverse@tab];

enter image description here

The gif was just an export of anim.

$\endgroup$
  • $\begingroup$ @LeandroMacieldeCarvalho look up Export and gif. Also there is an excellent set of answers on MSE on this topic. So search this site. I am not near computer and likely in different Timezone. Apologies for delay :) $\endgroup$ – ubpdqn Jun 11 '16 at 4:02

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.