1
$\begingroup$

How do I get the displacement in the free end of a bar with Parabolic load (I.e. in point with length L)?

I found the information on a site, but only I found for uniform load.

Someone who understands about engineering could I describe the steps?

enter image description here

The code obtained was this for uniform load:

Clear[a, x, V, M, y, L, EI]
M = EI*D[y[x], {x, 2}]; 
V = EI*D[y[x], {x, 3}]; 
th = D[y[x], {x}]; 
q = -a; 
M1 = M /. x -> 0; 
M2 = M /. x -> L; 
V1 = V /. x -> 0; 
V2 = V /. x -> L; 
y1 = y[x] /. x -> 0; 
y2 = y[x] /. x -> L; 
th1 = th /. x -> 0; 
th2 = th /. x -> L; 
s = DSolve[{EI*Derivative[4][y][x] == 0, M2 == Mom, V2 == PP,y1 == 0, th1 == 0}, y, x]
$\endgroup$
9
$\begingroup$

First find an equation for the parabolically distributed load:

param = Thread[a*#^2 + b*# + c & /@ {0, L/3, L} == {Q, Q/2, 0}] // Solve[#, {a, b, c}] &

q[x_] := a*x^2 + b*x + c /. param[[1]]

This is the governing equation for Euler-Bernoulli beam:

eqn = EI*D[y[x], {x, 4}] == q[x]

Boundary conditions are: y[0]==0, y'[0]=0, y''[L]==0 and y'''[L]==0

soln1 = DSolve[{eqn, y[0] == 0, y'[0] == 0, y''[L] == 0, 
y'''[L] == 0}, y[x], x]

Equation for cantilever deflection is:

defln[x_] = y[x] /. soln1[[1]] // Simplify@# &

Tip deflection is given by:

defln[L]

(* (3 L^4 Q)/(160 EI) *)
$\endgroup$
  • 1
    $\begingroup$ Today again this answer is helping me. Even after more than a year ... $\endgroup$ – LCarvalho Sep 2 '17 at 3:27

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.