3
$\begingroup$

I need to plot this with Mathematica:

Use a triple integral to determine the volume of the region below $z = 4 - x\,y$ and above the region in the xy-plane defined by $0 \leq x \leq2,\ 0 \leq y \leq 1$

I want to learn how to plot such regions in Mathematica; it would help me a lot in studying triple integrals.

$\endgroup$
11
$\begingroup$
region = ImplicitRegion[
   0 < z < 4 - x*y && 0 <= x <= 2 && 0 <= y <= 1,
   {x, y, z}];

RegionPlot3D[region,
 BoxRatios -> {1, 1, 1},
 Axes -> True]

enter image description here

Volume[region]

(*  7  *)

RegionMeasure[region]

(*  7  *)

Integrate[1, {x, 0, 2}, {y, 0, 1}, {z, 0, 4 - x*y}]

(*  7  *)

Integrate[1, Element[{x, y, z}, region]]

(*  7  *)

However, this can be done with just a double integral

Integrate[4 - x*y, {x, 0, 2}, {y, 0, 1}]

(*  7  *)
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.