5
$\begingroup$

How to make the following graphics by using Mathematica?

Pascal triangle with products

What I tried:

I used J.M's answer for the Pascal triangle

pascal = With[{n = 6}, 
Graphics[Table[
Text[Style[Binomial[n - j, n - i], Large], {2 (i - j/2), 3 j/2}], {i, n}, {j, i}]]]


product = MatrixForm[{1, 1, 2, 9, 96, 2500}

then

Show[pascal, product]

GraphicsGrid[pascal, product]

but it doesn't work.

(sequence 1, 1, 2, 9.. is the product of the terms in the $nth$ row)

$\endgroup$
  • 3
    $\begingroup$ For anybody who wants to take a crack at this: (j!)^(j - 1)/BarnesG[j + 1]^2 gives the desired product. $\endgroup$ – J. M. is in limbo May 20 '16 at 19:50
9
$\begingroup$
Manipulate[

 pascal = Row[Pane[#, 50, Alignment -> Center] & /@ #] & /@ 
   Table[CoefficientList[(x + 1)^i, x], {i, 0, n - 1}];

 product = Pane @ StringPadLeft[ToString[#], 40, "."] & /@ 
   Table[(j!)^(j - 1)/BarnesG[j + 1]^2, {j, 0, n - 1}];

 Grid[{{
    Column[pascal, Center],
    Column[product, Right]
    }}, BaseStyle -> 15]
 ,
 {{n, 6}, 1, 15, 1}]

enter image description here

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.