# Flip sign of one variable in list

I have this list of x, y-pairs l={{x1, y1}, {x2, y2}, ...}. Now I need to flip the sign of the y values only before plotting. What is the easiest way to do this modification?

• {1, -1} # & /@ l or Transpose@{#[[1]], -#[[2]]} &@Transpose[l] – BlacKow May 13 '16 at 15:39
• Welcome! I suggest the following: 1) As you receive help, try to give it too, by answering questions in your area of expertise. 2) Take the tour and check the faqs! 3) When you see good questions and answers, vote them up by clicking the gray triangles, because the credibility of the system is based on the reputation gained by users sharing their knowledge. Remember to accept the answer, if any, that solves your problem, by clicking the checkmark sign! – user9660 May 13 '16 at 15:50
• Or even faster Transpose[{1, -1} # &@Transpose[l]] – BlacKow May 13 '16 at 15:50
• Or MapAt[-# &, l, {All, 2}]. Or {#1, -#2} & @@@ l. – march May 13 '16 at 15:51
• This is almost certainly a duplicate. I will see if I can find it. – march May 13 '16 at 15:55

Dot works well here.

pts = {{x1, y1}, {x2, y2}, {x3, y3}, {x4, y4}};

pts.{{1, 0}, {0, -1}}

{{x1, -y1}, {x2, -y2}, {x3, -y3}, {x4, -y4}}


In version 10.1.0 under Windows x64 this is twice as fast as BlacKow's fastest method:

l = RandomReal[{0, 1}, {1000000, 2}];

Transpose[{1, -1} Transpose[l]]   // RepeatedTiming // First

l.{{1, 0}, {0, -1}}               // RepeatedTiming // First

0.0133

0.0072

• I was so sure that you can't do this, that it will cause some dimensions mismatch, so I haven't even tried this... I'll add it to my benchmark later. Thanks! – BlacKow May 14 '16 at 3:12
• I like this. Nice to see you using dot products! :) – J. M. will be back soon May 14 '16 at 5:13
• @J.M. There is a pretty good chance you taught me this but my memory is too poor to remember. – Mr.Wizard May 14 '16 at 6:29
• @J.M. Do you feel that this is a duplicate of (38138)? I do, but not strongly, and I did not wish to act alone. – Mr.Wizard May 15 '16 at 3:38
• Somehow I recall another thread with the exact same problem of reflecting, but the link escapes me at the moment. BTW, I'm sure you know this, but for general scaling and reflection, one could use DiagonalMatrix[], or even ScalingTransform[]. – J. M. will be back soon May 15 '16 at 4:10

Little benchmark to compare suggested methods:

l = RandomReal[{0, 1}, {1000000, 2}];
b1[l_List] := {1, -1} # & /@ l;
b2[l_List] := Transpose@{#[[1]], -#[[2]]} &@Transpose[l];
b3[l_List] := Transpose[{1, -1} Transpose[l]];
m1[l_List] := MapAt[-# &, l, {All, 2}];
m2[l_List] := {#1, -#2} & @@@ l;
ch1[l_List] := l /. {a_, b_} :> {a, -b};
g1[l_List] := l ConstantArray[{1, -1}, Length@l];
w1[l_List] := l.{{1, 0}, {0, -1}};
fb1[l_List] := Thread[{l[[;; , 1]], -l[[;; , 2]]}];

#2 -> #1 & @@@ SortBy[#, #[[1]] &] &@({#1, #2} & @@@Transpose@{First@AbsoluteTiming[#[l]] & /@ #, #}&@{b1, b2, b3,m1, m2, ch1, g1,w1,fb1})


{w1 -> 0.007054, b3 -> 0.016369, b2 -> 0.020753, b1 -> 0.155566, fb1 -> 0.25016, g1 -> 0.323931, m2 -> 1.05527, m1 -> 1.13127, ch1 -> 1.32451}

• b3 is the last thing I would have used without much thinking, neat to see how much faster it is though. – N.J.Evans May 13 '16 at 16:28
• @FrankBreitling Usually you create a new list in Mathematica and not modify existing one. Your method l=Thread[{l[[1]], -l[[2]]}] doesn't yield desired result. – BlacKow May 13 '16 at 17:02
• you could write b3 as Transpose[{1, -1} Transpose@l] (+1) – kglr May 13 '16 at 17:59
• @kglr Indeed... not sure why I came up with that one lol.. Fixed – BlacKow May 13 '16 at 18:01
• @FrankBreitling I updated my answer with your method. – BlacKow May 16 '16 at 22:21