Reducing the number of plotmarkers in listlineplot

Question

Here is my code:

ListLinePlot[{Transpose[{Flatten[falset1alphav1], 
Flatten[detectiont1alphav1]}], 
Transpose[{Flatten[falset1huberv1], Flatten[detectiont1huberv1]}], 
Transpose[{Flatten[falset1alphav15], Flatten[detectiont1alphav15]}],
Transpose[{Flatten[falset1huberv15], 
Flatten[detectiont1huberv15]}], 
Transpose[{Flatten[falset1alphav2], Flatten[detectiont1alphav2]}], 
Transpose[{Flatten[falset1huberv2], Flatten[detectiont1huberv2]}], 
Transpose[{Flatten[falset08alphav1], Flatten[detectiont08alphav1]}],
Transpose[{Flatten[falset08huberv1], 
Flatten[detectiont08huberv1]}], 
Transpose[{Flatten[falset08alphav15], 
Flatten[detectiont08alphav15]}], 
Transpose[{Flatten[falset08huberv15], 
Flatten[detectiont08huberv15]}], 
Transpose[{Flatten[falset08huberv2], Flatten[detectiont08huberv2]}],
Transpose[{Flatten[falset08huberv2], 
Flatten[detectiont08huberv2]}], 
Transpose[{Flatten[falset1likelihoodv1], 
Flatten[detectiont1likelihoodv1]}], 
Transpose[{Flatten[falset1energyv1], 
Flatten[detectiont1energyv1]}]}, PerformanceGoal -> "Quality", 
PlotMarkers -> {
"", "", "", "", "", 
"", {"+", 18}, {"+", 18}, {"+", 18}, {"+", 18}, {"+", 18}, {"+", 
18}}, PlotStyle -> {{Blue, Thick}, Directive[Orange, Thick], 
Directive[Red, Thick], Directive[Green, Thick], 
Directive[Black, Thick], Directive[Purple, Thick], {Blue, Thick}, 
Directive[Orange, Thick], Directive[Red, Thick], 
Directive[Green, Thick], Directive[Black, Thick], 
Directive[Purple, Thick], Directive[Cyan, Thick, Dashed], 
Directive[Magenta, Thick, Dashed]}, BaseStyle -> 22, 
AspectRatio -> .7, PlotRange -> Automatic, 
AxesStyle -> Arrowheads[0.03], 
AxesLabel -> {Style[\!\(\*SubscriptBox[\(P\), \(F\)]\), 
FontSize -> 21], 
Style[\!\(\*SubscriptBox[\(P\), \("D"\)]\), Italic, 
FontSize -> 21]}, 
PlotLegends -> 
Placed[LineLegend[{{Blue, Thick}, Directive[Orange, Thick], 
Directive[Red, Thick], Directive[Green, Thick], 
Directive[Black, Thick], Directive[Purple, Thick], {Blue, Thick},
Directive[Orange, Thick], Directive[Red, Thick], 
Directive[Green, Thick], Directive[Black, Thick], 
Directive[Purple, Thick], Directive[Cyan, Thick, Dashed], 
Directive[Magenta, Thick, 
  Dashed]}, {"\[Alpha]-div(\[Theta]=1,\!\(\*SubscriptBox[\(\
\[ScriptCapitalU]\), \(1\)]\))", 
 "Huber(\[Theta]=1,\!\(\*SubscriptBox[\(\[ScriptCapitalU]\), \
\(1\)]\))", 
 "\[Alpha]-div(\[Theta]=1,\!\(\*SubscriptBox[\(\[ScriptCapitalU]\)\
, \(2\)]\))", 
 "Huber(\[Theta]=1,\!\(\*SubscriptBox[\(\[ScriptCapitalU]\), \
\(2\)]\))", 
 "\[Alpha]-div(\[Theta]=1,\!\(\*SubscriptBox[\(\[ScriptCapitalU]\)\
, \(3\)]\))", 
 "Huber(\[Theta]=1,\!\(\*SubscriptBox[\(\[ScriptCapitalU]\), \
\(3\)]\))", 
 "\[Alpha]-div(\[Theta]=0.8,\!\(\*SubscriptBox[\(\[ScriptCapitalU]\
\), \(1\)]\))", 
 "Huber(\[Theta]=0.8,\!\(\*SubscriptBox[\(\[ScriptCapitalU]\), \
\(1\)]\))", 
 "\[Alpha]-div(\[Theta]=0.8,\!\(\*SubscriptBox[\(\[ScriptCapitalU]\
\), \(2\)]\))", 
 "Huber(\[Theta]=0.8,\!\(\*SubscriptBox[\(\[ScriptCapitalU]\), \
\(2\)]\))", 
 "\[Alpha]-div(\[Theta]=0.8,\!\(\*SubscriptBox[\(\[ScriptCapitalU]\
\), \(3\)]\))", 
 "Huber(\[Theta]=0.8,\!\(\*SubscriptBox[\(\[ScriptCapitalU]\), \
\(3\)]\))", "Likelihood", "Energy Det."}, 
LegendLayout -> {"Column", 2}, LabelStyle -> 21, 
LegendFunction -> (Framed[#, RoundingRadius -> 2, 
    FrameStyle -> LightGray] &)], {Right, Bottom}], 
GridLines -> Automatic, GridLinesStyle -> LightGray, Joined -> True]

As you can see I have many curves in one listlineplot and I need to use markers for some of them only. The problem is that every curve which needs plotmarkers have many data points inside, lets say 200 or more. Therefore, there are too many plot markers and it seems really so ugly. I need lets say around 20 markers per curve. How can I do this? I checked other questions here but I couldnt solve my problem.

Answer 1

You can post-process to Downsample the set of Insets as in the following example (assuming that all Insets are plot markers):

ClearAll[foo]
foo[n_Integer] = # /. {dir___, insets : Repeated[Inset[___], {1, Infinity}]} :> 
   {dir, (Downsample[{insets}, n])} &;

Example:

lp = ListLinePlot[{Range[20], Range[20] + 2, Range[20] + 4}, 
         PlotMarkers -> {Automatic, 14}, ImageSize -> 300];
lp2 = MapAt[foo[3], lp, {1}];
Row[{lp, lp2}, Spacer[5]]

Row[{#, MapAt[foo[3], #, {1}]}, Spacer[5]] &@
 ListLinePlot[{Range[20], Range[20] + 2, Range[20] + 4}, 
  PlotMarkers -> {"", {"+", 18}, {"+", 18}}, ImageSize -> 300, 
  AxesStyle -> Arrowheads[0.03], 
  AxesLabel -> {Style[Subscript[P, F], FontSize -> 21], Style[
\!\(\*SubscriptBox[\(P\), \("\<D\>"\)]\), Italic, FontSize -> 21]}]

Answer 2

Here is what I would call the canonical approach to your problem which should work starting from version 6, where Span (;;) was introduced:

data = Table[Table[{x, f}, {x, 0, 2 Pi, 0.03}], {f, {Sin[x], Sin[2 x], Sin[3 x]}}];

pl1 = Show[ListLinePlot[data], 
  (* taking every 15th data point from every dataset *)
  ListPlot[data[[;; , ;; ;; 15]], PlotMarkers -> {Automatic, 14}], 
  ImageSize -> 300, PlotRange -> All]

The same is achievable with the new in version 9 Downsample:

pl2 = Show[ListLinePlot[data], 
  ListPlot[Downsample[data, {1, 15, 1}], PlotMarkers -> {Automatic, 14}], 
  ImageSize -> 300, PlotRange -> All];

pl2 == pl1

True