3
$\begingroup$

I'm trying to evaluate the integral $$ \int W_{0,a}(x)\,W_{1,b}(x)\,\frac{dx}{x}, $$ where $W$ denotes the Whittaker $W$ function, and $a,b\in[0,1/2]$. Using the Whittaker differential equations that $W_{0,a}(x)$ and $W_{1,b}(x)$ solve by definition, the integral in question can be shown to effectively reduce to the following one $$ \int W_{0,a}(x)\,W_{1,b}(x)\,\frac{dx}{x^2}\;\text{or}\; \int W_{0,a}(1/x)\,W_{1,b}(1/x)\,dx $$ which I'm also not sure how to find. Any suggestions?

$\endgroup$
8
$\begingroup$

Identities from MathematicalFunctionData can be useful when Mathematica can't seem to rewrite things in a form we want.

whit[k_, m_, z_] = Activate[MathematicalFunctionData[
   WhittakerW, "AlternativeRepresentations"][[4]][k, m, z][[1, 2]]]

enter image description here

int = FullSimplify[whit[0, a, x] whit[1, b, x]]

enter image description here

Integrate[int/x, x]
(* large output of HypergeometricPFQs *)
$\endgroup$
1
  • $\begingroup$ What a find. Many thanks. (+1) $\endgroup$ – bbgodfrey May 6 '16 at 0:13
4
$\begingroup$

Mathematica can't this integral to solve,but we can convert WhittakerW function to BesselI function.I'm use Maple to convert.

$$W_{0,a}(x)=\frac{1}{2} \sqrt{\pi } \sqrt{x} \csc (\pi (a+1)) \left(I_a\left(\frac{x}{2}\right)-I_{-a}\left(\frac{x}{2}\right)\right)$$ $$W_{1,b}(x)=\frac{1}{2} \sqrt{\pi } \sqrt{x} \csc (\pi b) \left(-\frac{1}{2} x I_{1-b}\left(\frac{x}{2}\right)+\left(b+\frac{x}{2}-\frac{1}{2}\right) I_{-b}\left(\frac{x}{2}\right)+\left(b-\frac{x}{2}+\frac{1}{2}\right) I_b\left(\frac{x}{2}\right)+\frac{1}{2} x I_{b+1}\left(\frac{x}{2}\right)\right)$$

whit1 = 1/2*Sqrt[Pi*x]/Sin[Pi*(1 + a)]*(BesselI[a, x/2] - BesselI[-a, x/2]);
whit2 = 1/2*Sqrt[Pi*x]/Sin[Pi*b]*(-BesselI[1 - b, x/2]*x/2 + BesselI[-b, x/2]*(b + x/2 - 1/2) + BesselI[1 + b, x/2]*x/2 + BesselI[b, x/2]*(b - x/2 + 1/2));
int = FullSimplify[whit1*whit2/x]

(* 1/4 (-x BesselI[1 - b, x/2] + (-1 + 2 b + x) BesselI[-b, x/2] + (1 + 2 b - x) BesselI[b, x/2] + x BesselI[1 + b, x/2]) BesselK[a, x/2] Csc[b \[Pi]] *)

integral = Integrate[int, x, Assumptions -> {a, b} \[Element] Reals]

 (* 1/4 Csc[b \[Pi]] (-(1/2) \[Pi] Csc[
 a \[Pi]] ((2^(-1 + 2 a + 2 b) x^(1 - a - b)
      HypergeometricPFQ[{1/2 - a/2 - b/2, 1/2 - a/2 - b/2, 
       1 - a/2 - b/2}, {1 - a, 1 - b, 1 - a - b, 3/2 - a/2 - b/2},
       x^2/4])/((1/2 - a/2 - b/2) Gamma[1 - a] Gamma[
      1 - b]) - (2^(-1 - 2 a + 2 b) x^(1 + a - b)
      HypergeometricPFQ[{1/2 + a/2 - b/2, 1/2 + a/2 - b/2, 
       1 + a/2 - b/2}, {1 + a, 1 - b, 1 + a - b, 3/2 + a/2 - b/2},
       x^2/4])/((1/2 + a/2 - b/2) Gamma[1 + a] Gamma[1 - b])) + 
  b \[Pi] Csc[
  a \[Pi]] ((2^(-1 + 2 a + 2 b) x^(1 - a - b)
      HypergeometricPFQ[{1/2 - a/2 - b/2, 1/2 - a/2 - b/2, 
       1 - a/2 - b/2}, {1 - a, 1 - b, 1 - a - b, 3/2 - a/2 - b/2},
       x^2/4])/((1/2 - a/2 - b/2) Gamma[1 - a] Gamma[
      1 - b]) - (2^(-1 - 2 a + 2 b) x^(1 + a - b)
      HypergeometricPFQ[{1/2 + a/2 - b/2, 1/2 + a/2 - b/2, 
       1 + a/2 - b/2}, {1 + a, 1 - b, 1 + a - b, 3/2 + a/2 - b/2},
       x^2/4])/((1/2 + a/2 - b/2) Gamma[1 + a] Gamma[1 - b])) + 
  1/2 \[Pi] Csc[
  a \[Pi]] ((2^(-1 + 2 a + 2 b) x^(2 - a - b)
      HypergeometricPFQ[{1/2 - a/2 - b/2, 1 - a/2 - b/2, 
       1 - a/2 - b/2}, {1 - a, 1 - b, 1 - a - b, 2 - a/2 - b/2}, 
      x^2/4])/((1 - a/2 - b/2) Gamma[1 - a] Gamma[
      1 - b]) - (2^(-1 - 2 a + 2 b) x^(2 + a - b)
      HypergeometricPFQ[{1/2 + a/2 - b/2, 1 + a/2 - b/2, 
       1 + a/2 - b/2}, {1 + a, 1 - b, 1 + a - b, 2 + a/2 - b/2}, 
      x^2/4])/((1 + a/2 - b/2) Gamma[1 + a] Gamma[1 - b])) - 
  1/2 \[Pi] Csc[
  a \[Pi]] ((2^(-3 + 2 a + 2 b) x^(3 - a - b)
      HypergeometricPFQ[{1 - a/2 - b/2, 3/2 - a/2 - b/2, 
       3/2 - a/2 - b/2}, {1 - a, 2 - b, 2 - a - b, 
       5/2 - a/2 - b/2}, x^2/4])/((3/2 - a/2 - b/2) Gamma[
      1 - a] Gamma[2 - b]) - (2^(-3 - 2 a + 2 b) x^(3 + a - b)
      HypergeometricPFQ[{1 + a/2 - b/2, 3/2 + a/2 - b/2, 
       3/2 + a/2 - b/2}, {1 + a, 2 - b, 2 + a - b, 
       5/2 + a/2 - b/2}, x^2/4])/((3/2 + a/2 - b/2) Gamma[
      1 + a] Gamma[2 - b])) + 
  1/2 \[Pi] Csc[
  a \[Pi]] ((2^(-1 + 2 a - 2 b) x^(1 - a + b)
      HypergeometricPFQ[{1/2 - a/2 + b/2, 1/2 - a/2 + b/2, 
       1 - a/2 + b/2}, {1 - a, 3/2 - a/2 + b/2, 1 + b, 1 - a + b},
       x^2/4])/((1/2 - a/2 + b/2) Gamma[1 - a] Gamma[
      1 + b]) - (2^(-1 - 2 a - 2 b) x^(1 + a + b)
      HypergeometricPFQ[{1/2 + a/2 + b/2, 1/2 + a/2 + b/2, 
       1 + a/2 + b/2}, {1 + a, 3/2 + a/2 + b/2, 1 + b, 1 + a + b},
       x^2/4])/((1/2 + a/2 + b/2) Gamma[1 + a] Gamma[1 + b])) + 
  b \[Pi] Csc[
  a \[Pi]] ((2^(-1 + 2 a - 2 b) x^(1 - a + b)
      HypergeometricPFQ[{1/2 - a/2 + b/2, 1/2 - a/2 + b/2, 
       1 - a/2 + b/2}, {1 - a, 3/2 - a/2 + b/2, 1 + b, 1 - a + b},
       x^2/4])/((1/2 - a/2 + b/2) Gamma[1 - a] Gamma[
      1 + b]) - (2^(-1 - 2 a - 2 b) x^(1 + a + b)
      HypergeometricPFQ[{1/2 + a/2 + b/2, 1/2 + a/2 + b/2, 
       1 + a/2 + b/2}, {1 + a, 3/2 + a/2 + b/2, 1 + b, 1 + a + b},
       x^2/4])/((1/2 + a/2 + b/2) Gamma[1 + a] Gamma[1 + b])) - 
  1/2 \[Pi] Csc[
  a \[Pi]] ((2^(-1 + 2 a - 2 b) x^(2 - a + b)
      HypergeometricPFQ[{1/2 - a/2 + b/2, 1 - a/2 + b/2, 
       1 - a/2 + b/2}, {1 - a, 2 - a/2 + b/2, 1 + b, 1 - a + b}, 
      x^2/4])/((1 - a/2 + b/2) Gamma[1 - a] Gamma[
      1 + b]) - (2^(-1 - 2 a - 2 b) x^(2 + a + b)
      HypergeometricPFQ[{1/2 + a/2 + b/2, 1 + a/2 + b/2, 
       1 + a/2 + b/2}, {1 + a, 2 + a/2 + b/2, 1 + b, 1 + a + b}, 
      x^2/4])/((1 + a/2 + b/2) Gamma[1 + a] Gamma[1 + b])) + 
  1/2 \[Pi] Csc[
  a \[Pi]] ((2^(-3 + 2 a - 2 b) x^(3 - a + b)
      HypergeometricPFQ[{1 - a/2 + b/2, 3/2 - a/2 + b/2, 
       3/2 - a/2 + b/2}, {1 - a, 5/2 - a/2 + b/2, 2 + b, 
       2 - a + b}, x^2/4])/((3/2 - a/2 + b/2) Gamma[1 - a] Gamma[
      2 + b]) - (2^(-3 - 2 a - 2 b) x^(3 + a + b)
      HypergeometricPFQ[{1 + a/2 + b/2, 3/2 + a/2 + b/2, 
       3/2 + a/2 + b/2}, {1 + a, 5/2 + a/2 + b/2, 2 + b, 
       2 + a + b}, x^2/4])/((3/2 + a/2 + b/2) Gamma[1 + a] Gamma[
      2 + b]))) *)

Now we check numerical:

a = 0;
b = 1/2;
Integrate[WhittakerW[0, a, x]*WhittakerW[1, b, x]/x, x]
MeijerG[{{1}, {2}}, {{3/2, 3/2}, {0}}, x] /. x -> 1 // N

$0.452954$

Needs["NumericalCalculus`"]
NLimit[integral /. x -> 1 /. b -> 1/2, a -> 0, Method -> SequenceLimit] // Quiet 

$0.452954$

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.