2
$\begingroup$

I am trying to solve for $\Omega$ this nonlinear integral equation:

$$1+\dfrac{z}{k^2}-\dfrac{z^2}{K_2(z)} \dfrac{\Omega}{k^3} \displaystyle\int_{1}^{\infty} \gamma^2\, \text{ArcTanh} \left(\sqrt{\frac{\gamma ^2-1}{\gamma ^2}} \dfrac{k}{\Omega}\right)\, e^{-\text{z$\gamma $}} \, d\gamma=0$$

where $K_2(z)$ is the modified Bessel function of the second kind, $\Omega$ and $k$ are reals, $z> 0$.

The Mathematica input is:

f[Ω_?NumericQ, k_?NumericQ, z_?NumericQ] := 1 + (z/k^2) - (z^2/BesselK[2, z]) (Ω/k^3) 
    NIntegrate[γ^2 (ArcTanh[Sqrt[(γ^2 - 1)/γ^2] (k/Ω)]) Exp[-z γ], {γ, 1, Infinity}, 
    MaxRecursion -> 500]

The solutions $\Omega (k, z)$ are given by :

 W[k_,z_] := Re[Ω /. FindRoot[f[Ω, k, z], {Ω, .895}]]

I need to calculate all solutions $\Omega(k, z)$ for $k = 3$ when $0.1 <z <100$.

My problem is that I get accurate solutions for $1<z<100$ and inaccurate solutions for $0.1=<z<0.7$.

For example:

Block[{k=3},Table[{z, W[k,z]},{z,{100,10,5,1,0.5,0.1}}]]

{{100, 1.139642672363642}, {10, 1.96313715768855}, {5, 2.393983432376982}, {1, 2.905633499901334}, {0.5, 202.5621368946721}, {0.1, 104.1929384069426}}

The true values for $z=0.5$ and $0.1$ are:

W[3,0.5]= 2.98 ; W[3,0.1]= 2.99

Please, why do the computations do not converge? Is there an easy way to resolve this problem ?

(I should mention that I'm using Mathematica 10.2.0.0.)

$\endgroup$
  • $\begingroup$ When k > omega, ArcTanh[Sqrt[([Gamma]^2 - 1)/[Gamma]^2] (k/[CapitalOmega])] seems to be indeterminate when gamma goes to infinity. Is this correct? $\endgroup$ – Vito Vanin May 3 '16 at 0:53
  • $\begingroup$ @Vito Vanin Limit[ArcTanh[Sqrt[([Gamma]^2 - 1)/[Gamma]^2] (x)],Gamma->Infinity] =1/2 (-I \[Pi] - Log[-1 + x] + Log[1 + x]) when gamma goes to infinity for all x>1. $\endgroup$ – Betatron May 3 '16 at 4:17
  • $\begingroup$ I am not sure that any of the results in the Question are correct. Applying f[Last@#, 3, First@#] & to them returns {0.00299279 + 0.018689 I, 0.592512 + 0.194949 I, 0.733582 + 0.114397 I, 0.867595 + 0.0489768 I, 0.999996, 0.999997}. $\endgroup$ – bbgodfrey May 3 '16 at 5:32
  • $\begingroup$ I do not understand this! $\endgroup$ – Betatron May 3 '16 at 22:25
  • 1
    $\begingroup$ @bbgodfrey, thank you. This is the paper : dx.doi.org/10.1063/1.4821606. Please, see Fig. 3-d for $\Omega_{i}(3, 100)/\Omega_{r}(3, 100) \approx -0.0075$, value that I have not found. $\endgroup$ – Betatron May 14 '16 at 21:51
3
$\begingroup$

Difficulties encountered in solving the dispersion relation in the Question are due not so much to convergence of the integral as to the branch point in complex γ- space, which occurs where the argument of ArcTanh[] is equal to 1. Based on the related article cited in a comment above, the integration contour {γ, 1, Infinity} must pass below all non-analytic points in complex γ- space. Moreover, on both physical and mathematical grounds Im[Ω] < 0, which implies that the corresponding value of γ also has a negative imaginary part. I had hoped to take the branch point into account in the same way that I did in answering Question 113240, but this proved to be impractical, because the corresponding branch cut is not a straight line in complex γ- space.

Alternatively, the branch point, which is logarithmic, can be eliminated from the integrand

γ^2 (ArcTanh[Sqrt[(γ^2 - 1)/γ^2] (k/Ω)]) Exp[-z γ]

by means of integration by parts:

arg1 = Integrate[γ^2 Exp[-z γ], γ, Assumptions -> z > 0];
arg2 = Simplify[D[ArcTanh[Sqrt[(γ^2 - 1)/γ^2] (k/Ω)], γ], γ > 1];
arg = -arg1 arg2
(* (k*(2 + 2*z*γ + z^2*γ^2)*Ω)/(E^(z*γ)*z^3*Sqrt[γ^2 - 1]*(-(k^2*(-1 + γ^2)) + γ^2*Ω^2)) *)

Based on the discussion in the first paragraph, the dispersion relation becomes not just the first equation in the question with the new integrand, but also the Residue of the pole.

pole = Solve[Denominator[arg] == 0, γ] // Last
(* {γ -> k/Sqrt[k^2 - Ω^2]} *)
res = FullSimplify[Residue[arg, {γ, γ /. pole}]]
(* (-(k^2*(2 + z^2)*Ω) + 2*Ω^3 - 2*k*z*Ω*Sqrt[(k - Ω)*(k + Ω)])/
(2*E^((k*z)/Sqrt[k^2 - Ω^2])*z^3*((k - Ω)*(k + Ω))^(3/2)*Sqrt[Ω^2/(k^2 - Ω^2)]) *)

Inserting this term, along with the new integrand given above, into the definition of f from the Question yields the new dispersion function,

h[Ω_?NumericQ, k_?NumericQ, z_?NumericQ] := 
    1 + (z/k^2) - (z^2/BesselK[2, z]) (Ω/k^3) (NIntegrate[(E^(-z γ)
    k (2 + 2 z γ + z^2 γ^2) Ω)/(z^3 Sqrt[-1 + γ^2] (-k^2 (-1 + γ^2) + γ^2 Ω^2)), 
    {γ, 1, Infinity}] + 2 Pi I (E^(-((k z)/Sqrt[k^2 - Ω^2])) Ω (-2 k^3 z + 2 k z Ω^2 - 
    k^2 (2 + z^2) Sqrt[k^2 - Ω^2] + 2 Ω^2 Sqrt[k^2 - Ω^2]))/(2 z^3 Sqrt[Ω^2/(k^2 - Ω^2)] 
    (k^2 - Ω^2)^2))

A comment above by Betatron estimates that h[Ω, 3, 100] is satisfied by Ω such that Im[Ω]/Re[Ω] is of order -0.0075. The new dispersion relation yields,

Ω /. Last@FindRoot[h[Ω, 3, 100], {Ω, 1.1 - .1 I}]
(* 1.13917 - 0.0075706 I *)
Im[%]/Re[%]
(* -0.0066457 *)

In contrast, the original dispersion relation yielded 1.1397 + 4.04927*10^-11 I, along with error messages. A few minutes of computation are sufficient to generate the following plots.

enter image description here

enter image description here

As requested in the Question, the new dispersion relation gives credible solutions for small z, and credible values for Im[Ω] throughout.

Addendum

As requested by Betatron in a Chat Room conversation, the code used to create the two plots above is

t1 = Table[{i, Ω /. FindRoot[h[Ω, 3, i], {Ω, 3 - I/1000}]}, {i, 1/10, 1, 1/10}];
t2 = Table[{i, Ω /. FindRoot[h[Ω, 3, i], {Ω, 2.5 - .3 I}]}, {i, 1, 3, 1/10}];
t3 = Table[{i, Ω /. FindRoot[h[Ω, 3, i], {Ω, 2. - .3 I}]}, {i, 4, 20}];
ListLogLinearPlot[Union[Re[t1], Re[t2], Re[t3]], AxesLabel -> {z, "Re[Ω]"}]
ListLogLinearPlot[{First@#, Im[Last@#]/Re[Last@#]} & /@ 
    Union[t1, t2, t3], PlotRange -> All, AxesLabel -> {z, "Im[Ω]/Re[Ω]"}]
$\endgroup$
  • $\begingroup$ Thank you so much Professor, but If i try for z=0.5 :\[CapitalOmega] /. Last@FindRoot[ h[\[CapitalOmega], 3, 0.5], {\[CapitalOmega], 1 - .1 I}] I get : 3.155443621*10^-29 + 16.23354888 I and Im[%]/Re[%] give 5.144616994*10^29 ? $\endgroup$ – Betatron May 16 '16 at 5:42
  • $\begingroup$ @Betatron Try a better initial guess, for instance, Ω /. FindRoot[h[Ω, 3, 1/2], {Ω, 3 - I/1000}]. $\endgroup$ – bbgodfrey May 16 '16 at 5:46
  • $\begingroup$ Please, How did you find arg = -arg1 arg2 in the integration by part of γ^2 (ArcTanh[Sqrt[(γ^2 - 1)/γ^2] (k/Ω)]) Exp[-z γ]? $\endgroup$ – Betatron May 16 '16 at 11:29
  • $\begingroup$ @Betatron I differentiated ArcTanh[] to eliminate the branch point and, consequently, had to integrate the rest. Fortunately, the endpoints vanished. If your question is about how integration by parts itself works, see for instance Wolfram MathWorld. $\endgroup$ – bbgodfrey May 16 '16 at 12:52
  • $\begingroup$ For h[Ω,0.2,100],Re[Ω]=0.99 from the graph, value that I can't find whatever the initial guess of omega, for example I get this : Re[Ω /. FindRoot[h[Ω,0.2,100], {Ω,0.985 - I/1000}] = 0.09375544601]. Therefore, to find all solutionsRe[Ω] for k∈[0,3], I'll have to fix for each k a different initial value of Ω. Please, how to get the better initial guess of omega for full range of k? Thank's $\endgroup$ – Betatron May 16 '16 at 19:29

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.