I spent some time manually editing a post replacing Mathematica ASCII \[Alpha] with Unicode α. I did this by laboriously choosing Copy as LaTeX, pasting into the edit box, and then copying the Unicode symbol from the preview below. This made me realize I am lacking a "Copy as Unicode string" function in Mathematica.

How can I most easily copy an expression such as:

Mathematica graphics

In Unicode:

αβ + Mod[δΨ, 2 ⁢ρ^2]

10 Answers 10


Since a native method is not forthcoming, I shall post my file based circumvention, for Windows.

You will need to have this utility in the command path (it apparently is stock with Windows 7).

copyUnicode[expr_] := Run["clip <",
   Export["$Clipboard.temp", ToString[expr, InputForm],
          "Text", CharacterEncoding -> "Unicode"] ];


expr = \[Alpha]\[Beta] + Mod[\[Delta]\[CapitalPsi], 2\[InvisibleTimes]\[Rho]^2];


This leaves the following text in the Windows Clipboard:

αβ + Mod[δΨ, 2*ρ^2]

Here is a version of the function that holds (does not evaluate) the expression:

SetAttributes[copyUnicode, HoldFirst]

copyUnicode[expr_, form_: InputForm] := 
  Run["clip <", 
   Export["$Clipboard.temp", ToString[Unevaluated@expr, form], "Text", 
    CharacterEncoding -> "Unicode"]];


Plot[\[Alpha], {\[Alpha], 0, 10}] // copyUnicode

Puts in the Windows Clipboard:

Plot[α, {α, 0, 10}]
  • 3
    $\begingroup$ I think clip is native in at least win-7. Perhaps you should note that this places the output in the system clipboard. The output of your copyUnicode function is just a 0 (at least, on my PC). You have to do a ctrl-v paste afterwards. A MMA Paste doesn't seem to work. $\endgroup$ Feb 2 '12 at 21:10
  • 1
    $\begingroup$ Very useful function! Why not make it available for any code sample? (Now it works only for single expression…) $\endgroup$
    – xzczd
    Nov 23 '12 at 14:09
  • $\begingroup$ @xzczd I'll see if I can improve it. $\endgroup$
    – Mr.Wizard
    Nov 23 '12 at 23:56
  • $\begingroup$ There's a built-in CopyToClipboard function, but it doesn't seem to work, at least on Linux. $\endgroup$ May 21 '13 at 1:46
  • $\begingroup$ Does it possible to convert string to Plot[\[Alpha], {\[Alpha], 0, 10}] or Cell[BoxData["\<\"Plot[\\\\[Alpha], {\\\\[Alpha], 0, 10}]\"\>"], "Output"}] to Unicode Form? Because I use one function something like InputCell2SE@cellExpression//CopyToClipboard copy InputCell to SE which turns out Plot[\[Alpha], {\[Alpha], 0, 10}], and I used FrontEnd..."InputText" $\endgroup$ Jun 19 '13 at 15:08


This method for Windows is based on the .NET code from Todd Gayley's this wonderful answer. My .NET knowledge is absolutely ZERO, all credit goes to Todd.


The main idea is to extract the "Input"-style code string, convert it to the UTF-16 little endian form, which is the standard byte order in Windows, feed the bytes to system clipboard by using .NET API.

The main functions are placed in a package:


mmaUnicodeToUTF16LE::usage = 
        ToString[Row[{Style["mmaUnicodeToUTF16LE[_Integer]", Bold], " convert integer list obtained from ", Style[Row[{"ToCharacterCode[", Style["string", Italic], ", \"Unicode\"]"}], Bold], " to integer list consistent with the UTF‐16 Little Endian standard."}], StandardForm];
stringToUTF16LE::usage = 
        ToString[Row[{Style["stringToUTF16LE[_String]", Bold], " convert ", Style["string", Italic], " to integer list consistent with the UTF‐16 Little Endian standard."}], StandardForm];
WriteToClipboardUnicode::usage = 
        ToString[Row[{Style["WriteToClipboardUnicode[_String]", Bold], " write ", Style["string", Italic], " to Windows clipboard using the UTF‐16 Little Endian encoding."}], StandardForm];


mmaUnicodeToUTF16LE[bytecode_Integer] := 
                    PadRight[#, 2 Ceiling[Length@#/2]] &@
                     Join[Most[#] - Rest[# 2^8], #[[{-1}]]] &@
        DeleteCases[FixedPointList[BitShiftRight[#, 8] &, bytecode], 0]

stringToUTF16LE[str_String] := 
                    mmaUnicodeToUTF16LE /@ ToCharacterCode[str, "Unicode"] // 
            Flatten // Join[#, {0, 0}] &

WriteToClipboardUnicode[str_String] :=
       Module[{bytecode, strm, dataObject},
          bytecode = stringToUTF16LE[str];
                           strm = NETLink`NETNew["System.IO.MemoryStream", bytecode];
                           dataObject = NETLink`NETNew["System.Windows.Forms.DataObject"];
                           dataObject@NETLink`SetData["Text", strm];


Then execute the following code, which will generate a palette with a UniCode Copy button:

Button["UniCode Copy",
        timestamp = {};
        FrontEndExecute[FrontEndToken["CopySpecial", "InputText"]];
        codestr = 
            NotebookGet[ClipboardNotebook[]][[1, 1, 1]] // 
                StringReplace[#, {"\\\n" -> "", 
                            "\n" ~~ space : " " ... :> 
                                StringJoin["\n", ConstantArray[space, 4]]}] &;
    Method -> "Queued"

SelectionMove[EvaluationNotebook[], Previous, Cell];

To use it, select the Cells you want to copy as input text code, then press the button. The package can be put in a file and be auto-loaded when MMA start, the palette can be installed to system menu.


Unicode expressions in Mathematica Notebook:

test unicode expressions

Text generated directly by the above code:


α β + Mod[δΨ, 2 ρ^2]

  • $\begingroup$ Very nice. Thanks! $\endgroup$
    – Mr.Wizard
    Apr 1 '14 at 22:10
  • $\begingroup$ @Mr.Wizard It's my honour :) Needed this tool myself for a loong time. And there are still problems, such as some characters from private area get copied, e.g. a. Maybe a whitelist is needed. $\endgroup$
    – Silvia
    Apr 1 '14 at 22:16
  • $\begingroup$ Arguably copy of characters such as \[Transpose] as  is acceptable as they can still be pasted into a Notebook, although it would be nice to also have the option to copy the expanded FullForm of such private letters. $\endgroup$
    – Mr.Wizard
    Apr 2 '14 at 2:23
  • 1
    $\begingroup$ @LCFactorization I think the \[Rule] symbol in MMA, whose Unicode is U+F522, is in the Basic Multilingual Plane (U+E000–U+F8FF), one of the Private Use Area in Unicode standard, thus may not be printable in 3rd party software. $\endgroup$
    – Silvia
    Feb 14 '16 at 16:03
  • 1
    $\begingroup$ @LCFactorization xzczd's web service looks very nice, thanks for sharing! Regarding the PDE, if you have any examples, please feel free to ping me in chat or email me :) $\endgroup$
    – Silvia
    Feb 18 '16 at 14:20

Edit 2: A new version of the Mac solution with button is listed below

Fixed problem with pasting into textarea

In some applications on Mac, copying as Unicode from Mathematica already works without having to do any postprocessing. However, it doesn't work in textarea fields in web browsers.

Nevertheless, if you're willing to do a few additional mouse clicks, the Unicode forms can be brought into the browser by taking the detour through one of those applications that do support Mathematica's characters. One convenient choice is to open a new window in TextEdit and paste your original Mathematica code into it first. In the default RichText mode, TextEdit displays the special characters as Unicode glyphs. Then you can simply copy whatever you just pasted back from TextEdit and paste it into the browser. It seems that as soon as TextEdit is recognized as the provider of the Unicode text on the pasteboard, there is no conversion back to the Mathematica representation, so you get the correct appearance in the browser.

In the following, I use the same idea in order to automate the conversion. Instead of TextEdit, I go through a temporary file in RichText (RTF) format on the provider side. The Mac pasteboard does support RTF as a format for data on the pasteboard, but this isn't accepted by the browsers I've recently tried when attempting to paste into textarea.

Therefore, I have to add one additional step: using the textutil tool which is built into OS X, I convert the RTF file to a regular text file with Unicode characters first. Then I read the text file back in and put it on the pasteboard.

Of course, this means it's only going to work on Mac OS X because it uses Cocoa bindings in the built-in Python interpreter:

copyAsUnicode[t_] := 
 Module[{out = 
      "MathematicaOutput" <> StringJoin[Map[ToString, DateList[]]]}]},
   Export[out <> ".rtf", t];
  Run["textutil -convert txt " <> out <> ".rtf -output " <> out <> 
  Run["printf \"from AppKit import *\n\
content=NSData.dataWithContentsOfFile_('" <> out <> 
    ".txt')\nboard.declareTypes_owner_([NSStringPboardType], None)\n\
board.setData_forType_(content, NSStringPboardType)\n\
\" | /usr/bin/python"];
  DeleteFile[{out <> ".txt", out <> ".rtf"}]]

The idea is to export to RTF and read the result to the clipboard outside of Mathematica. The function is invoked for example as copyAsUnicode["αβ+Mod[δΨ+ρ2]"]. This example itself was copied that way, too, i.e., I typed copyAsUnicode["copyAsUnicode[\"αβ+Mod[δΨ+ρ2]\"]"], which I again copied the same way... OK, I think you get the idea.

Of course the next step would be to make this into a Palette that acts on the NotebookSelection, but the above is the main step. Maybe someone else knows how to do something like this in other operating systems (I don't).

Installing this function as a button:

Responding to the comment, here I'm just listing the same function as above, but wrapped in Silvia's code to make it into a button. It requires no package loading because I inlined everything into the button code:

Button["UniCode Copy", Module[{codestr},
FrontEndExecute[FrontEndToken["CopySpecial", "InputText"]];
codestr = NotebookGet[ClipboardNotebook[]][[1, 1, 1]];
 Module[{out = 
      "MathematicaOutput" <> StringJoin[Map[ToString, DateList[]]]}]},
   Export[out <> ".rtf", codestr];
  Run["textutil -convert txt " <> out <> ".rtf -output " <> out <> 
  Run["printf \"from AppKit import *\n\
content=NSData.dataWithContentsOfFile_('" <> out <> 
    ".txt')\nboard.declareTypes_owner_([NSStringPboardType], None)\n\
board.setData_forType_(content, NSStringPboardType)\n\
\" | /usr/bin/python"];
  DeleteFile[{out <> ".txt", out <> ".rtf"}]]],
Method -> "Queued"]
SelectionMove[EvaluationNotebook[], Previous, Cell];

Now you can also install this permanently by going to Palettes > Install Palette and selecting a name for the palette.

  • $\begingroup$ This looks good, but since I cannot test it on Windows I will leave it to Mac users to upvote. Thank you for your answer. $\endgroup$
    – Mr.Wizard
    Feb 2 '12 at 4:27
  • $\begingroup$ Hi, I posted one question with little difference from directly copy Input Expression to SE and need your attention. mathematica.stackexchange.com/questions/27289/… $\endgroup$ Jun 20 '13 at 1:47
  • $\begingroup$ @Jens, this is a nice workaround (and it still works). Any idea if there are plans for this to be integrated into a Palette as you suggested? $\endgroup$ May 13 '14 at 18:30
  • $\begingroup$ @RicoPicone Thanks, I added the button code, hopefully that should put it on equal footing with the windows solution (except for potential shortcomings of the Mac Unicode handling, which I have no control over...). $\endgroup$
    – Jens
    May 13 '14 at 19:33
  • $\begingroup$ @Jens, thanks for your work on this. I can't get it to work. I get the message (copy from clipboard option) that the clipboard contents are invalid. I'll try to save it as a file, next. $\endgroup$ May 14 '14 at 14:32

Here's how to add a permanent menu item and keyboard shortcut for Silvia's solution. (This can be easily adapted to Jens' solution for Mac OS.)

enter image description here

1. Add Package

Copy Silvia's first code block that starts with Needs["NETLink`"] to a file and save it as UniCodeCopy.m in one of the directories included in $Path.

2. Initialize the Front End

Save the following to the file $UserBaseDirectory/Autoload/FrontEnd/init.m (create it if needed):


CopySelectionAsUnicode[] :=
    Module[{selection, code},
           FrontEndExecute[FrontEndToken["CopySpecial", "InputText"]];
           selection = NotebookGet[ClipboardNotebook[]][[1, 1, 1]];
           code = StringReplace[selection, {"\\\n" -> "",
                                            "\n" ~~ space : " " ... :> StringJoin["\n", ConstantArray[space, 4]]}];

                             {MenuItem["Copy as Unicode",
                                       (* Alt + U *)
                                       MenuKey["u", Modifiers -> {"Command"}],
                                       System`MenuEvaluator -> Automatic,
                                       Method -> "Queued"]}]]

For key bindings, the possible modifiers are "Shift", "Control", "Command" (Alt) and "Option" (Alt).

(It took me a few hours to figure this out. I hope this proves useful for other struggling novices.)

  • 2
    $\begingroup$ Very nice! Thanks for sharing :) $\endgroup$
    – Silvia
    Aug 10 '14 at 6:46
  • 1
    $\begingroup$ Are you saying that $UserBaseDirectory/Autoload/FrontEnd/init.m should be created, because there is no such file on my Windows 8.1 computer? There is, however, the file $UserBaseDirectory/FrontEnd/init.m on my computer, but appending your code to the end of that file caused Mathematica to crash during initialization. Thanks in advance for your assistance. $\endgroup$
    – bbgodfrey
    Mar 8 '15 at 22:40
  • $\begingroup$ Yes, just create it. I've added that to my post. $\endgroup$
    – ens
    Mar 8 '15 at 22:53
  • $\begingroup$ It works well. Thank you. $\endgroup$
    – tanghe2014
    Jun 1 '20 at 1:08

I use a small web application for when there are too many to convert by hand.

  • $\begingroup$ Very handy. Now if we could just get this as a button in the editor. $\endgroup$
    – Mr.Wizard
    Jun 19 '13 at 16:09
  • $\begingroup$ On Mac, I can get the same result by simply pasting the Mathematica code into the TextEdit application and immediately copying the same passage from there. So there's no need to go to the web. $\endgroup$
    – Jens
    Jun 19 '13 at 17:15
  • $\begingroup$ @Jens very true. One day everyone will use Macs... :) (typed on a iPad) $\endgroup$
    – cormullion
    Jun 19 '13 at 17:27
  • $\begingroup$ @Jens Hmm.. did not work for me - MacBook Pro OSX - all standard things. Copied from notebook - pasted into TextEdit - had all the \[Alpha] etc. Some special settings? $\endgroup$ Apr 3 '14 at 4:48
  • $\begingroup$ @VitaliyKaurov Works for me. Did you set the document format to Plain Text perhaps? Then it won't work of course. $\endgroup$
    – Jens
    Apr 3 '14 at 5:37

Here's a version that doesn't require a temporary file.

Linux (needs xclip)

SetAttributes[copyUnicode, HoldAll];
copyUnicode[expr_] := With[{
      stream = OpenWrite["!xclip -in -selection clipboard", CharacterEncoding -> "UTF-8"]
   WriteString[stream, ToString[Unevaluated@expr, InputForm]];

Example: executing the cell

 RowBox[{"copyUnicode", "[", 
     SuperscriptBox["x", "2"], "\[SmallCircle]", 
       RowBox[{"\[LeftFloor]", "\[Alpha]", "\[RightFloor]"}], ",", 
       "\"\<\[LeftFloor]\[Alpha]\[RightFloor]\>\""}], "}"}]}], 
     SqrtBox["5"], "\[CirclePlus]", "\[HappySmiley]"}]}], 
\[Element]\>\""}], "]"}]], "Input"]

gives x^2 ∘ {Floor[α], "⌊α⌋"} ± Sqrt[5] ⊕ ☺ <= "∫∂→⋃∑∞∈".


Not tested, but it should work if you use "!clip"instead of"!xclip -in -selection clipboard"`. You might have to change the encoding to UTF-16.


  • Note that certain characters get ASCIIfied anyway in InputForm when not inside a string.
  • Mathematica uses non-standard private-use code points for some characters like U+211D , even when a standard code point exists, so the output will be wrong if the input contains such characters.
  • $\begingroup$ Your caveats also apply to Mac OS X, so there's more work to be done before it becomes 100% reliable... (+1) $\endgroup$
    – Jens
    Jun 19 '13 at 20:21
  • $\begingroup$ Another caveat to add: some special characters, such as \[UpEquilibrium], get converted incorrectly or not at all, no matter what I try. So I don't think it's possible to get a perfect translation to Unicode in general. $\endgroup$
    – Jens
    Jun 19 '13 at 20:46

Here is a function that copies a Unicode string to the clipboard using JLink:

LoadJavaClass["java.awt.Toolkit", AllowShortContext -> False];

uniclip[s_String] :=
    java`awt`Toolkit`getDefaultToolkit[]@getSystemClipboard[]@setContents[#, #]& @
      JavaNew["java.awt.datatransfer.StringSelection", s]

Example usage:

expr = \[Alpha]\[Beta] + Mod[\[Delta]\[CapitalPsi], 2\[InvisibleTimes]\[Rho]^2];

uniclip @ ToString[expr, InputForm]

After evaluating these expressions, the clipboard contains αβ + Mod[δΨ, 2*ρ^2].


In the comments, a request was made to include code to invoke this functionality from a context menu. I was unable to fulfill this request. If someone wants to take up the work, here is a packaged form of the function which will save them the trouble of dealing with the finicky auto-load requirements of anything that uses JLink`:

BeginPackage["Uniclip`", {"JLink`"}];

CopyUnicodeToClipboard::usage =
  "CopyUnicodeToClipboard[s] copies s to the clipboard using Unicode characters";

CopySelectionAsUnicode::usage =
  "CopySelectionAsUnicode[] copies the currently selected text to the clipboard using Unicode characters";


retry:_CopyUnicodeToClipboard :=
  ( InstallJava[]
  ; LoadJavaClass["java.awt.Toolkit", AllowShortContext -> False]
  ; CopyUnicodeToClipboard[s_String] :=
        java`awt`Toolkit`getDefaultToolkit[] @
           setContents[#, #]& @
           JavaNew["java.awt.datatransfer.StringSelection", s]
  ; retry

CopySelectionAsUnicode[] :=
  , FrontEndExecute[FrontEndToken["CopySpecial", "InputText"]]
  ; text = NotebookGet[ClipboardNotebook[]][[1, 1, 1]]
  ; CopyUnicodeToClipboard @ text



WARNING The function CopySelectionAsUnicode functions erratically when called from a menu item. It involves a re-entrant call to the front-end which introduces a lengthy delay.

The auto-load declaration to go into the kernel's init.m looks like this:

DeclarePackage["Uniclip`", {"CopyUnicodeToClipboard", "CopySelectionAsUnicode"}];

The package code must go into a file named Uniclip.m somewhere in the $Path.

The context menu declaration (for ContextMenus.tr) looks like this:

    MenuEvaluator -> Automatic],

I had added it under all of the Copy As menu items for the Text, Input, Output, Plugin, CellBracket styles.

  • 1
    $\begingroup$ This is great! I suppose it should work on all platforms? $\endgroup$
    – Silvia
    Sep 7 '14 at 20:43
  • $\begingroup$ Great - I see no problems on Mac OS X 10.7.5 with Mathematica 10. $\endgroup$
    – Jens
    Sep 7 '14 at 21:33
  • $\begingroup$ @Silvia I can only vouch for it working on Windows, but by rights it should work on all platforms. $\endgroup$
    – WReach
    Sep 7 '14 at 22:20
  • 3
    $\begingroup$ I believe this is the first multiplatform solution. Provide complete self-contained package code to add this as a menu item and shortcut key (in the context menu if you can manage it), and I'll Accept it so long as no failures appear. Thanks! $\endgroup$
    – Mr.Wizard
    Sep 8 '14 at 6:55
  • 2
    $\begingroup$ @Mr.Wizard I spent a couple of hours today trying to fulfill the request, but failed. I kept hitting race conditions in re-entrant front-end calls while trying to hook up the context menu. This is because the only way I know how recover the text selection involves a front-end call, and the menu item invocation is already a front-end call. I can't really spend more time on it right now, so if anyone wants to incorporate uniclip into another answer that adds menu items and shortcut keys, feel free. $\endgroup$
    – WReach
    Sep 20 '14 at 18:33

Here's a method that's really no different from the standard ones except it's generalized for copying cells and, theoretically, for Windows and Unix.

We'll use RunProcess because this exists now, and tweak the ProcessEnvironment to make it work for Mac:

   enc : _String | Automatic : Automatic,
   lang : _String | Automatic : Automatic
   ] :=
    encoding = Replace[enc, Automatic :> $CharacterEncoding],
    language = Replace[lang, Automatic :> $Language]
   If[#["ExitCode"] =!= 0,
      FrontEnd`unicodeCopy::copyerr = "error in copy process:\n ``";
      Message[FrontEnd`unicodeCopy::copyerr, #["StandardError"]];,
      ] &@
      {"xsel", "-b"}
      CharacterEncoding -> encoding
     ProcessEnvironment -> <|
       "LANG" ->
          "english" -> "en_US"
          ] <> "." <>
         Replace[encoding, {
           "UTF8" -> "UTF-8",
           "Unicode" -> "UTF-16"
       "PATH" -> Environment["PATH"]

(I'm using FrontEnd` for when I dump to "MenuSetup.tr", just so it looks consistent)

Now we'll define a bunch of junk to generalize to make it work across an NB:

$unicodeTR =
    "PrivatePathsTextResources"] // FrontEndExecute;
$unicodeReplacements = #[[2]] -> 
      "\"" <> StringReplace[#[[1]], {"x" -> ":", 
         StartOfString ~~ "0" -> "\\"}] <> "\""] & /@
    StringSplit@StringSplit[Import[$unicodeTR, "String"], "\n"]

FrontEnd`UnicodeCopy[c : {__Cell}] :=
    ExportPacket[Cell[CellGroupData[c]], "InputText"]
    ], {
    {s_String, __} :>
FrontEnd`UnicodeCopy[c_Cell] :=
    ExportPacket[c, "InputText"]
    ], {
    {s_String, __} :>
FrontEnd`UnicodeCopy[b_BoxData | _TextData] :=

FrontEnd`UnicodeCopy[b_RowBox] :=

   nb : _NotebookObject | _FrontEnd`NotebookObject | \
_FrontEnd`SelectedNotebook | _FrontEnd`InputNotebook | \
_FrontEnd`ButtonNotebook | _FrontEnd`EvaluationNotebook | \
_FrontEnd`MessagesNotebook | _FrontEnd`HelpBrowserNotebook | \
   ] :=
   nb : _InputNotebook | _EvaluationNotebook | _ClipboardNotebook | \
_ButtonNotebook | _MessagesNotebook | _HelpBrowserNotebook] :=

FrontEnd`UnicodeCopy[Optional[Automatic, Automatic]] :=

FrontEnd`UnicodeCopy[s_String] :=
FrontEnd`UnicodeCopy[e_] :=

  FrontEnd`UnicodeCopy[Evaluate@ToString[Unevaluated[e], InputForm]];

Then I'll add this to my MenuSetup using the framework I wrote up here and whose up-to-date implementation lives here

 {"Edit", "Copy As", 5},
 "Unicode" -> KernelExecute[ToExpression["FrontEnd`UnicodeCopy[]"]],
 MenuEvaluator -> Automatic,
 System`MenuKey["C", System`Modifiers -> {"Control"}]

This now lives under the "Copy As" menu:

copy as

And it can be used by function:





Or by Control-C:


(fixed, now, by doing a more selective replacement from UnicodeCharacters.tr)

One issue here is that I was a bit over zealous with some replacements when copying from cells and boxes (has to do with what comes out of the ExportPacket):

(Command-C): "asdasd\\[Alpha]\\[Beta]\\[Gamma]" 
(Control-C): "asdasd\α\β\γ" 

And just to include the original example:

\[Alpha]\[Beta] + 
 Mod[\[Delta]\[CapitalPsi], 2\[InvisibleTimes]\[Rho]^2]


αβ + 
 Mod[δΨ, 2⁢ρ^2]

(note how, unfortunately, the added spacing from the cell copy is preserved)

  • $\begingroup$ That looks like a lot of work! Thank you. The spacing thing may even be useful. :-) $\endgroup$
    – Mr.Wizard
    Jun 17 '17 at 14:08

Edit: Updated code

As a generalization to the excellent answer by ens, Silvia's solution also can be added as a palette to the menu as follows. First, create and save the UniCodeCopy.m package, as described by ens. Then create as a separate notebook, perhaps named Unicode Copy Source.nb,

    Notebook[{Cell[BoxData[ButtonBox["\"UniCode Copy\"", Appearance -> Automatic,
        ButtonFunction :> Module[{codestr},                  
        AppendTo[$Path, FileNameJoin[{$UserDocumentsDirectory, 
        FrontEndExecute[FrontEndToken["CopySpecial", "InputText"]]; 
        codestr = (StringReplace[#1, {"\\\n" -> "", "\n" ~~ space : " " ... :> 
            StringJoin["\n", ConstantArray[space, 4]]}] & )
            [NotebookGet[ClipboardNotebook[]][[1, 1, 1]]]; 
            Evaluator -> Automatic, ImageSize -> 200, Method -> "Queued"]], 
            NotebookDefault]}, WindowSize -> {Fit, Fit}, 
            WindowMargins -> {{Automatic, 522}, {Automatic, 41}}, 
            WindowFrame -> "Palette", WindowElements -> {}, 
            StyleDefinitions -> "Palette.nb"], WindowTitle -> "UniCodeCopy"];
NotebookSave[%, FileNameJoin[{$UserDocumentsDirectory, 

Note that the third and fourth lines of code add the location of UniCodeCopy.m (in this case, my Mathematica/MyPackages directory) to $Path, if the location is not already there. (If it is there, these two lines of code can be omitted.) Executing Unicode Copy Source.nb creates the small palette, UnicodeCopy.nb, saved in Mathematica/MyPackages. Finally, use the Install Palette ... command in the Palette menu to register UnicodeCopy.nb as a palette. After Mathematica is restarted, it will display UnicodeCopy in the Palette menu.


Under windows with Nircmd available, one can add the code below (a modification of https://mathematica.meta.stackexchange.com/a/155/9754) to an initialization cell of
$UserBaseDirectory <> "\\Autoload\\FrontEnd\\init.m" to get Alt Gr+p as a shortcut for copying as unicode and having 4 spaces added at the beginning of each line.

FrontEndExecute[FrontEnd`AddMenuCommands["Copy", {MenuItem["Copy for MSE",
      FrontEndExecute[Module[{opts, content},
            If[MatchQ[NotebookRead[SelectedNotebook[]], {} | $Failed | NotebookRead[$Failed]], Beep[],

                opts = AbsoluteOptions[$FrontEndSession, "ExportTypesetOptions"];
                SetOptions[$FrontEndSession, "ExportTypesetOptions" -> {"PageWidth" -> 800, "CellBreaks" -> "\nCeLlBrEaK\n"}];
                FrontEndTokenExecute[SelectedNotebook[], "CopySpecial", "InputText"];
                content = NotebookGet[ClipboardNotebook[]];
                SetOptions[$FrontEndSession, opts];

                RunProcess[{"C:\\nircmd\\nircmdc.exe", "clipboard", "readfile", "\"" <> 
                          Export["C:\\nircmd\\mathCopy.txt", #, CharacterEncoding -> "Unicode"] <> "\""}] &[

                   Fold[StringReplace, StringJoin[{"    ", Cases[content, Cell[c_String, ___] :> c, All]}],
                      {{"" | "" -> "I", "" -> "E", "" | "" -> "<->", "\n" -> "\n    "},
                        {"    In[" ~~ NumberString ~~ "]:= " -> "    ",
                          "    CeLlBrEaK\n" | StartOfString ~~ "    Out[" ~~ NumberString ~~
                              "]= " ~~ e : Shortest[__] ~~ f : "\n    CeLlBrEaK" | EndOfString :>
                            "    (* " <> StringReplace[e, "\n    " -> "\n       "] <> " *)" <> StringTake[f, UpTo[5]],
                          "CeLlBrEaK" -> ""}}]]]]],
       MenuKey["p", Modifiers -> {"Control", "Command"}], System`MenuEvaluator -> Automatic, Method -> "Queued"]}]]

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.