Creating Average Grid data from Co-ordinate and value data

Question

Consider a list:

ZXV = {{z1, x1, v1}, {z2, x2, v2},........................} 

where $z$ is Z co-ordinate, $x$ is X co-ordinate, $v$ is the value at the point $i$.

I want to create a grid based on squares 100 units wide. I then want to calculate the average value within the grid.

I then want to create a list of averages, with the centre point of each square - {{cz1, cx1, av1}, {cz2, cx2, av2}, .......} where $cz$ is centre for $z$, $cx$ is centre for $x$, and $av$ is average value for the square unit.

I was looking at something like

Split[mylist, Chop[#2 - #1 - 1] == 0 &]

but I need to setup recursive loop [2#-#1], [#3- #1], [#4 - #1] until the rule [#Number - #1] > 100 is reached

How could I accomplish this?

Answer 1

mylist = Transpose[{RandomReal[100, 1000], RandomReal[100, 1000], RandomReal[1, 1000]}];

binned = GatherBy[#, Floor[#[[2]]] &] & /@ GatherBy[mylist, Floor[#[[1]]] &];

means = Join @@ Map[Mean, binned, {2}];

BubbleChart[Tooltip /@ means, GridLines -> {Range@100, Range@100}, 
            BubbleSizes -> {0.005, .005}]

Answer 2

I think you can use Partition to form the group of four points, and then calculate the mean value in each group.

For example here are some data on a 100 by 100 grids

data = N@Table[Cos[x^2 + y^2], {x, π/100, π, π/100}, {y, π/100, π, π/100}];

To form a group of four point

data1 = Partition[data, {2, 2}, 1];

then the mean value is

data2= Map[Mean[Mean[#]] &, data1, {2}];

If your data has the form of {{x1,y1,z1},..} shape, then you can apply this to each dimension

dataXYZ = 
 N@Table[{x, y, Cos[x^2 + y^2]}, {x, π/100, π, π/100}, {y, π/100, π, π/100}];

Transpose[Map[Mean[Mean[#]] &, Partition[#, {2, 2}, 1], {2}] & /@ 
  Transpose[dataXYZ, {2, 3, 1}], {3, 1, 2}]

Here is an example shows what it does, where the black dots are the original grid and the red dots are the center of each square.

grid1 = Table[{i, j}, {i, 10}, {j, 10}];
grid2 = Transpose[Map[Mean[Mean[#]] &, Partition[#, {2, 2}, 1], {2}] & /@ 
   Transpose[grid1, {2, 3, 1}], {3, 1, 2}]
Graphics[{PointSize[Large], Point[Flatten[grid1, 1]], Red, 
  Point[Flatten[grid2, 1]]}]

Answer 3

Let's say you have this data, just using a random set here for completeness,

SeedRandom[55];
(* A set of random 2D coordinates *)
list = RandomReal[100, {1000, 2}];
(* attach a set of less-random values as the third coordinate *)

list = {#1, #2, #1 + #2 + RandomReal[{-50, 50}]} & @@@ list;

You can view the data using a ListDensityPlot or ListPlot,

ListDensityPlot[list, ColorFunction -> "Rainbow"]
ListPlot[Style[{#1, #2}, ColorData["Rainbow"][#3/100]] & @@@ list, 
 AspectRatio -> 1, 
 GridLines -> {Range[0, 100, 20], Range[0, 100, 20]}]

You can see that the values generally get larger as x and z get larger, but that density plot is horrible.

To get a list of the values in a particular rectangular region, use Select:

Last/@Select[list, 0 <= #[[1]] <= 20 && 0 <= #[[2]] <= 20 &]

(*  {37.5551, 1.32275, 16.2364, 66.5277, 18.6801,......, 15.8541, 25.897, 33.8019, 19.1619} *)

And you can just use Mean to get the mean value in that region (or Total to get the total value).

Use Table to collect all the mean values over, for example, a 5 by 5 grid,

{dx, dz} = {20, 20};
gridmean = Table[
   Mean[
    Last /@ 
     Select[list, x <= #[[1]] <= x + dx && z <= #[[2]] <= z + dz &]
    ]
   , {x, 0, 80, dx}, {z, 0, 80, dz}];

And then use ListDenistyPlot to show the mean values,

ListDensityPlot[gridmean, ColorFunction -> "Rainbow", 
 InterpolationOrder -> 0, DataRange -> {{0, 100}, {0, 100}}]

Alternatively, you could create a list of Rectangle objects and use RegionMember to select the points,

regions = 
  Table[Rectangle[{x, z}, {x + dx, z + dz}], {x, 0, 80, dx}, {z, 0, 
    80, dz}];
gridmean = Table[
  Mean[
   Last /@ Select[list, RegionMember[regions[[n, m]], #[[;; 2]]] &]
   ], {n, 5}, {m, 5}]

But this is a bit slower