How to use Select with lists

Question

I am trying to do:

Select[minimus[[6]], #1[[2]] < (min[[6]] + emin[[6]]) &]

applied to all elements of minimus, min and emin. They all have the same Length, but minimus is a list of pair coordinates {{x1, y1}, {x2, y2}, ..., {xN, yN}} while both min and emin are lists of values.

I thought something like this would work:

Map[Select[minimus[[#2]], #1[[2]] < (min[[#2]] + emin[[#2]])&]&, Range[Length[minimus]]]

But it didn't...

Any thoughts?

Answer 1

Pick[minimus, UnitStep[min + emin - minimus[[;; , 2]]], 1]

or a pure function that does the same thing:

pF = Pick[#, UnitStep[#2 + #3 - #[[;; , 2]]], 1] &;

Examples:

min = RandomReal[{0, 0.5}, 10^6];
emin = RandomReal[{0, 0.5}, 10^6];
minimus = RandomReal[{0, 1}, {10^6, 2}];

p1 = pF[minimus, min, emin]; // AbsoluteTiming // First

0.059911

p2 = Pick[minimus, Thread[minimus[[;; , 2]] < (min + emin)]]; // 
  AbsoluteTiming // First

0.988790

p3 = First@Transpose@Select[Transpose@{minimus, min, emin}, 
     #[[1, 2]] < (#[[2]] + #[[3]]) &]; // AbsoluteTiming // First

2.497177

p1 == p2 == p3

True

Update: A variation suggested by @ciao in the comments is faster for large lists:

pFx = With[{tot = #2 + #3}, Pick[#, UnitStep[Subtract[tot, Transpose[#][[2]]]], 1]] &;

min = RandomReal[{0, 0.5}, 10^7];
emin = RandomReal[{0, 0.5}, 10^7];
minimus = RandomReal[{0, 1}, {10^7, 2}];

p1 = pF[minimus, min, emin]; // AbsoluteTiming // First

0.555083

p1x = pFx[minimus, min, emin]; // AbsoluteTiming // First

0.461842

p1x == p1

True

Answer 2

Another approach, using Pick:

min = RandomReal[{0, 0.5}, 10]
emin = RandomReal[{0, 0.5}, 10]
minimus = RandomReal[{0, 1}, {10, 2}]

Pick[minimus, Thread[minimus[[;; , 2]] < (min + emin)]]

Answer 3

Assuming that you want to select all values from minimus such as its second element is less than sum of corresponding min and emin

RandomSeed[3141592];
minimus = RandomReal[{0, 1}, {10, 2}];
min = RandomReal[{0, 1}, 10];
emin = RandomReal[{0, 1}, 10];
First@Transpose@
  Select[Transpose@{minimus, min, 
     emin}, #[[1, 2]] < (#[[2]] + #[[3]]) &]