fat    = ArrayPlot[RandomReal[1, {20, 10}], ColorFunction->"Rainbow"];
skinny = ArrayPlot[RandomReal[1, {20,  1}], ColorFunction->"Rainbow"];

What must one do to display fat and skinny side-by-side, so that

  • the bottom and top edges of fat line up vertically with the bottom and top edges (respectively) of skinny (IOW, both fat and skinny appear as having the same height)
  • fat appears 10x wider than skinny

(GraphicsRow[{fat, skinny}] produces a ridiculous monster featuring a tiny fat next to a gigantic skinny. Pretty much everything else I've tried produces the same nonsense.)

  • $\begingroup$ @kjo, the issue with GraphicsRow and graphics of different aspect ratios is not unique to ArrayPlot and MatrixPlot. You could write your own heatmap code from scratch, but GraphicsRow will still exhibit the same behaviour. It's not clear to me why ArrayPlot in conjunction with the various strategies given in this question doesn't meet your needs. $\endgroup$ Sep 30, 2012 at 14:41
  • $\begingroup$ kjo, I have merged the duplicate, rambling re-post of this question into this one, and reopened it. Please edit this post to include a concise summary of functionality you seek and the problems you have had in programming it. Please leave out general grumblings about Mathematica; they serve no constructive purpose. $\endgroup$
    – Mr.Wizard
    Sep 30, 2012 at 14:55
  • $\begingroup$ @kjo I get the feeling that you are uncomfortable with optional parameters. Optional parameters are a huge chunk of the functionality in Mathematica, much more so than in other languages. $\endgroup$
    – amr
    Sep 30, 2012 at 18:33
  • $\begingroup$ The answers to this question might be of assistance. I think part of the issue is that you are using GraphicsRow instead of Row. $\endgroup$
    – Verbeia
    Oct 1, 2012 at 2:09

4 Answers 4


GraphicsGrid makes too many assumptions about similarity of sizes. For this kind of case, use Grid. I'd also recommend using the PlotRangePadding option in fat so that the two are exactly the same height. I'm not sure why the one-column case skinny doesn't use plot range padding, but it seems to be the way it works. (If you turn off the frame using Frame->False, you do need to turn off PlotRangePadding for both graphics.)

fat = ArrayPlot[RandomReal[1, {20, 10}], ColorFunction -> "Rainbow", 
   PlotRangePadding -> 0];
skinny = ArrayPlot[RandomReal[1, {20, 1}], ColorFunction -> "Rainbow"];

Grid[{{fat, skinny}}, Spacings -> -0.2]

aligned perfectly

This is what it looks like without the Spacings option.

just a bit of space

As for producing the desired plot type, MatrixPlot does the job with just a few custom option values. Consider the following example. First, I create some fake data:

testdata = 
  RandomVariate[TriangularDistribution[{0, 1}, 0.2], {30, 30}];

Some custom ticks will be handy, too. Notice that I use the list-valued third position to specify that the ticks will be zero length.

xtix = Array[{#, Rotate["E" <> ToString[#], 3 Pi/2], {0, 0}} &, {30}];
ytix = Array[{#, "F" <> ToString[#], {0, 0}} &, {30}];

To get the look shown in the example plot in your question, you need an appropriate usage of Blend, together with the ColorFunctionScaling->False option (if the data are already scaled between zero and 1, or True if they aren't). Notice the form of Blend that sets particular colors to particular values. This is in the documentation but little used.

MatrixPlot[testdata, ColorFunctionScaling -> False, 
 ColorFunction -> (Blend[{{0, Red}, {0.2, Black}, {1, Green}}, #] &), 
  PlotRangePadding -> 0, 
 FrameTicks -> {{ytix, None}, {xtix, None}}]

enter image description here

It would be easy to automate this further, either by building this into a custom function, or using SetOptions to set some of those options to MatrixPlot by default. However, I can imagine that you might want to tweak the ColorFunction depending on how your data are distributed.

As for building up arrays of these graphic elements, you need to investigate the ImageSize and AspectRatio options, as well as the original question which your previous question was a duplicate of. Once that is done, it is easy to put together something that looks a lot like the Wikipedia example.

First, define a custom color Blend:

myblend = (Blend[{{-1, Red}, {0, Black}, {0.5, Black}, {1, Green}}, #] &);

Then load in the HierarchicalClustering package to access the DendrogramPlot function. We can then do something like this (I used a different sized random data set to the previous case):

Grid[{{DendrogramPlot[Transpose@testdata, AspectRatio -> 1/5, 
    ImageSize -> 240, ImagePadding -> {{15, 0}, {0, 0}}], 
   Null}, {MatrixPlot[testdata, ColorFunctionScaling -> False, 
    AspectRatio -> 1, ColorFunction -> myblend, 
    FrameStyle -> AbsoluteThickness[0], PlotRangePadding -> 0, 
    FrameTicks -> {{ytix, None}, {xtix, None}}, 
    BaseStyle -> {FontFamily -> "Helvetica Neue", FontSize -> 8}, 
    ImageSize -> 250], 
   DendrogramPlot[testdata, AspectRatio -> 5, Orientation -> Right, 
    ImageSize -> 45, ImagePadding -> {{0, 0}, {20, 0}}]}}, 
 Spacings -> {0, -0.2}]

enter image description here

To summarize, yes, I do think that Mathematica can do this, and in a relatively straightforward way, too. If it is not specifically included as a custom function in the application, it is probably because there are so many different fields in the world that use Mathematica, and they can't build it all into the main application. I agree that it would be nice if there were more user-distributed custom packages around. This has already been discussed on the site but as yet not much has come of it.


This is a start:

fat = ArrayPlot[RandomReal[1, {20, 10}], ColorFunction -> "Rainbow"];
skinny = ArrayPlot[RandomReal[1, {20, 1}], ColorFunction -> "Rainbow"];

GraphicsRow[Show[#, ImageSize -> {All, 300}] & /@ {fat, skinny}, -50]

Mathematica graphics

Alignment is not intuitive; I had to use -50 to get the items close.

This is not resizable but spacing is more precise:

Row[ Show[#, ImageSize -> {All, 300}] & /@ {fat, skinny} ]

Mathematica graphics

You can use Spacer inside Row or Grid with the Spacings option to control spacing:

Grid[{Show[#, ImageSize -> {All, 300}] & /@ {fat, skinny}}, Spacings -> 1]

Mathematica graphics


I think the GraphicsRow/Column/Grid functions are designed to rescale the contents of each cell to have similar sizes, so I wouldn't have tried them. Since these plots are images, why not use ImageAssemble:

a0 = RandomReal[1, {20, 10}]; 
a1 = RandomReal[1, {20, 1}]; 
   ArrayPlot[a0, PlotRangePadding -> 0], {{30, 0}, {0, 0}}, 
   Padding -> White], 
   ArrayPlot[a1, PlotRangePadding -> 0], {{30, 0}, {0, 0}}, 
   Padding -> White]}]

heat maps

  • $\begingroup$ It should be noted that this rasterizes the plot whereas the solutions using Row or GraphicsRow won't. $\endgroup$
    – rm -rf
    Sep 30, 2012 at 18:56
  • $\begingroup$ @rm-rf True enough. Although ArrayPlot objects are just rasters to begin with, so it couldn't be too damaging (or could it? :)) $\endgroup$
    – cormullion
    Oct 1, 2012 at 6:46

Here's a GraphicsRow-like function which might help. The arguments are a list of graphics and optional spacing and height values.

myGraphicsRow[plots_List, spacing_Integer: 15, height_Integer: 360] :=
  Module[{p, d, o},
  p = Show[#, ImageSize -> {Automatic, height}] & /@ plots;
  d = ImageDimensions /@ p;
  o = Most@FoldList[Plus[#1, {1, 0} #2 + {spacing, 0}] &, {0, 0}, d];
    Inset[#1, #2, ImageScaled[{0, 0.5}], #3] &, {plots, o, d}],
    ContentSelectable -> True, ImageSize -> {Automatic, height}]]

For example:

myGraphicsRow[{fat, skinny, skinny}, 10, 300]

enter image description here


Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.