1
$\begingroup$

Given the variables

q1 = Root[(48 a^2 + 16 b) #^4 - (40 a^3 + 168 a b)#^3 + (-45 a^4 + 225 a^2 b + 72 b^2) #^2 + (27a^3 b - 162 a b^2) #+ 27 b^3 &,1]
q2 = Root[(48 a^2 + 16 b) #^4 - (40 a^3 + 168 a b)#^3 + (-45 a^4 + 225 a^2 b + 72 b^2) #^2 + (27a^3 b - 162 a b^2) #+ 27 b^3 &,2]
r1 = Root[375 a^8 - 3600 a^6 # + 8088 a^4 #^2 - 6912 a^2 #^3 + 2048 #^4 &,1]
r2 = Root[375 a^8 - 3600 a^6 # + 8088 a^4 #^2 - 6912 a^2 #^3 + 2048 #^4 &,2]

My intention is to solve the inequality $q_2 < c$ for a real number $c<0$ under the conditions $0<b<a^2$ and $a<0$. I first tried

Reduce[q2 < c && b > 0 && b < a^2 && a <0 && c <0,b,Reals]

which gives me a fairly nice solution to work with. However, if I split the domain of $b$ in two parts, namely $0<b<r_1$ and $r_1<b<a^2$

Reduce[q2 < c && b > 0 && b < r1 && c <0 && a <0,b,Reals]

and

Reduce[q2 < c && b > r1 && b < a^2 && c <0 && a <0,b,Reals]

then the outcomes are more complex involving an annoying root expression that bounds $a$. Where doest this come from? I assume it has something to do with the nature of the roots of the polynomial occurring in $q_2$? When I split the domain it looks like it threats $q_2$ differently then when I don't split the domain.

$\endgroup$
  • $\begingroup$ is it guaranteed 0<r1<a^2 ? Even if so Reduce might not recognise that from the root expression. $\endgroup$ – george2079 Apr 1 '16 at 3:42
  • $\begingroup$ Yes, that is indeed guaranteed. This is due the fact that $r_1 \approx 0.14 a^2$. $\endgroup$ – Cavents Apr 1 '16 at 8:31
3
$\begingroup$

I guess I'm unsure why you would expect adding a root expression as an additional constraint would not increase the complexity of the result. Heres how I'd look at it:

For simplicity define some root expressions that end up in the Reduce results:

root1 = Root[-45 a^4 c^2 - 40 a^3 c^3 + 
     48 a^2 c^4 + (27 a^3 c + 225 a^2 c^2 - 168 a c^3 + 16 c^4) #1 +
     (-162 a c + 72 c^2) #1^2 + 27 #1^3 &, 1];
root2 = Root[
   544210944 c^8 - 3439853568 c^7 #1 + 9279799296 c^6 #1^2 - 
     13912793088 c^5 #1^3 +
     12599076608 c^4 #1^4 - 6972768000 c^3 #1^5 + 
     2248633440 c^2 #1^6 - 365310000 c #1^7 + 18984375 #1^8 &, 1];

your original result is this:

Reduce[q2 < c < 0 && 0 < b < a^2 && a < 0, b, Reals] /. 
 root1 -> HoldForm[root1]

c < 0 && a < (4 c)/3 && root1< b < a^2

now adding the additional constraint we get:

Reduce[q2 < c < 0 && 0 < b < r1 < a^2 && a < 0, b,  Reals] /. 
  {root1 -> HoldForm[root1], root2 -> HoldForm[root2], 
     r1 -> HoldForm[r1]}

c < 0 && a < root2 && root1 < b < r1

note indeed Reduce recognized that r1<a^2. Now it turns out that root2 is linear in c:

Plot[ {(4 c)/3, root2 }, {c, -10, 0}]

enter image description here

so your condition is :

c < 0 && a < 11.1282 c && root1 < b < r1

where that approximate number comes from: root2/c /. c -> -1 // N You can verify you get the same numerical result for any c<0, and see that must be since every term in the expression is of the form c^(8-i)#1^i or c^8 (#1/c)^i. I was not successful at finding an exact form simpler than the RootExpression.

Incidentally you might find this useful:

 Simplify[  root1 // ToRadicals ,  Assumptions -> {  c < 0 , a < root2  } ]
$\endgroup$
  • $\begingroup$ Thank you for the great explanation! Could you perhaps tell me what exact meaning of root2/c /. c -> -1 // N is? I guess it's the computation of the slope. However, I'm not familiar with this notation. $\endgroup$ – Cavents Apr 2 '16 at 9:00
  • $\begingroup$ I was recently looking back at this post. It appears that Root2 = 11.1282c, however when I compute the second root of the 8th degree polynomial, I obtain 0.7c. It seems that Mathematica switch the orders? $\endgroup$ – Cavents Apr 14 '16 at 13:51
  • $\begingroup$ the convention is to order the roots real first in increasing order. Remember c is negative so 11c < .7 c $\endgroup$ – george2079 Apr 14 '16 at 17:56
  • $\begingroup$ Of course! I was forgotten that c<0. Thanks again! $\endgroup$ – Cavents Apr 14 '16 at 18:50

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.