How to solve this integration? [closed]

Question

I need to find the integration of the following expression

$$H(k)=\frac{\tau_0}{\pi}\int_0^{\infty}\exp\left(-u^{\delta}\cos\left(\frac{\delta\pi}{2}\right)\right)\cos\left(u^{\delta}\sin\left(\frac{\delta\pi}{2}\right)-k\tau_0u\right)du$$

But I am getting some syntax error.

If $\delta=1/2$ and $\delta=2/3$, how to solve these symbolically or numerically?

Answer 1

We calculate the symbolic result of the integral for the two values of the parameter δ.

Considering, as I did before in a related problem (Strange result of parameter-dependent definite integral), the exponential form instead of the cosine I obtain after expanding the exponential function containig δ and integrating term by term the following result (where t = τ0)

H[δ_] = 
  1/(π k I )
    Sum[(-1)^n/n! Gamma[n δ + 1]/(-k t )^(n*δ), {n, 
     0, ∞}];

Interestingly Mathematica can calculate the sum explicity for the two values of δ requested:

H[1/2]

$$-\frac{i e^{-\frac{1}{4 k t}} \left(-\sqrt{\pi } \sqrt{-k t} \text{erfi}\left(\frac{1}{2} \sqrt{\frac{1}{k t}}\right)+\sqrt{\pi } (-k) t \sqrt{\frac{1}{k t}}+2 k t e^{\frac{1}{4 k t}} \sqrt{-k t} \sqrt{\frac{1}{k t}}\right)}{2 \pi k^2 t \sqrt{\frac{1}{k t}} \sqrt{-k t}}$$

FullSimplify[%, {t > 0, k > 0}]

$$\text{h12}=\frac{\frac{2 i F\left(\frac{1}{2 \sqrt{k t}}\right)}{\sqrt{k t}}+\frac{\sqrt{\pi } e^{-\frac{1}{4 k t}}}{\sqrt{k t}}-2 i}{2 \pi k}$$

Here F() is the function DawsonF[].

The real part is

$$\text{h12r}=\frac{e^{-\frac{1}{4 k t}}}{2 \sqrt{\pi } k \sqrt{k t}};$$

And with the next parameter value we find

h23 = FullSimplify[H[2/3], {t > 0, k > 0}]

$$-\frac{i t \left(-9 (-k t)^{4/3} \, _2F_2\left(\frac{1}{2},1;\frac{1}{3},\frac{2}{3};-\frac{4}{27 k^2 t^2}\right)+6 \Gamma \left(\frac{2}{3}\right) (-k t)^{2/3} \, _1F_1\left(\frac{5}{6};\frac{2}{3};-\frac{4}{27 k^2 t^2}\right)-2 \Gamma \left(\frac{1}{3}\right) \, _1F_1\left(\frac{7}{6};\frac{4}{3};-\frac{4}{27 k^2 t^2}\right)\right)}{9 \pi (-k t)^{7/3}}$$

The real part can be simplified to

h23r = (t/(π Sqrt[3]) ) ((
     Gamma[2/3] Hypergeometric1F1[5/6, 2/
       3, -(4/(27 k^2 t^2))])/(k t)^(5/3) + (
     Gamma[4/3] Hypergeometric1F1[7/6, 4/
       3, -(4/(27 k^2 t^2))])/(k t)^(7/3));

In Latex

$$\text{h23r}=\frac{t \left(\frac{\Gamma \left(\frac{2}{3}\right) \, _1F_1\left(\frac{5}{6};\frac{2}{3};-\frac{4}{27 k^2 t^2}\right)}{(k t)^{5/3}}+\frac{\Gamma \left(\frac{4}{3}\right) \, _1F_1\left(\frac{7}{6};\frac{4}{3};-\frac{4}{27 k^2 t^2}\right)}{(k t)^{7/3}}\right)}{\pi \sqrt{3}};$$

The graphs are

Plot[{h12r /. k -> 1/2, Re[h23 /. k -> 1/2]}, {t, 0, 5}, 
 PlotLabel -> 
  "Two integrals for k = 1/2\nblue curve -> δ = 1/2, yellow curve -> \
δ = 2/3", AxesLabel -> {"t", "H"}]

Answer 2

Honestly speaking, this kind of question does not have a definite answer. Whenever you are trying to do such integration, first thing you should check is whether your function is convergent or not. Considering your function, it will not converge for any parameter values.

So I have to give a generic answer. If you don't know the properties of your function, evaluate it on the parameter space and then plot it. You might get an idea of the parameter dependence of the integral.

For your example

f[d_, k_, t0_, u_] := t0/Pi Exp[-u^d Cos[d Pi/2]] Cos[u^d Sin[d Pi/2] - k t0 u]

Does not converge for d=1

NIntegrate[ f[1, 1, 1, u], {u, 0, Infinity}]

$2.731938882417951*10^{27949}$

So choose smaller d and evaluate it

dat1 = Table[{k, t0,
 NIntegrate[ 
  f[.1, k, t0, u], {u, 0, Infinity}]}
 ,{k, -0.5, .5, .1}, {t0, 0.,1., .1}];
dat2 = Table[{k, t0,
 NIntegrate[ 
  f[.5, k, t0, u], {u, 0, Infinity}]}
 ,{k, -0.5, .5, .1}, {t0, 0.,1., .1}];

dat1 = Flatten[dat1, 1];
dat2 = Flatten[dat2, 1];

ListPlot3D[dat1, PlotLabel -> "d=0.1"]
ListPlot3D[dat2, PlotLabel -> "d=0.5"]

For advanced integration techniques you might be interested in this.

Now let say you want the functional relationship. So you can use Interpolation.

g = Interpolation[dat2]
Plot3D[g[x, y], {x, -0.5, 0.5}, {y, 0, 1}]

g[k,t0] is your approximate solution for d=0.5.

Answer 3

You have no assumptions made for tau and k.

f = t/Pi Exp[-u^d Cos[d Pi/2]] Cos[u^d Sin[d Pi/2] - k t u];
d = 1/2;

1.) solution:

int1 = Integrate[f, {u, 0, \[Infinity]}, Assumptions -> k*t != 0 && k*t \[Element] Reals]

2.) solution:

f1 = f // TrigToExp

int2 = Integrate[f1, {u, 0, \[Infinity]}, Assumptions -> k*t != 0 && k*t \[Element] Reals]
(* 0 *)

We may believe what is right! The plots point to 0.

{Plot3D[int1, {k, -5, -0.1}, {t, -5, -0.1}, PlotRange -> All, PlotPoints -> 100], 
 Plot3D[int1, {k, 0.1, 5}, {t, 0.1, 5}, PlotRange -> All, PlotPoints -> 100]}

{Plot3D[int1, {k, -5, -0.1}, {t, 0.1, 5}, PlotRange -> All, PlotPoints -> 100], 
 Plot3D[int1, {k, 0.1, 5}, {t, -5, -0.1}, PlotRange -> All, PlotPoints -> 100]}