0
$\begingroup$

I want to find the asymptotic form of this function

exact[t_]:=2^-t ((Binomial[t, 1/2 (-2 + t)] + Binomial[t, (2 + t)/2]) 
(2 + t + (8 (-2 + t) Hypergeometric2F1[3, 2 - t/2, 3 + t/2, -1])/(4 + t)) 
+ \[Pi] Binomial[1 + t, (1 + t)/2] Gamma[(3 + t)/2]
 HypergeometricPFQRegularized[{1, 3/2, 3/2, (1 - t)/2}, {1/2, 
  1/2, (3 + t)/2}, -1])

I tried:

Series[exact[t], {t, Infinity, 0}]

But it doesn't produce a result even after a few hours of running.

there is "strange" graphic of this function

Plot[exact[t], {t, -20, 1000}]

enter image description here

$\endgroup$
1
  • 1
    $\begingroup$ Mathematica does not know how to expand Hypergeometric2F1[3, 2 - t/2, 3 + t/2, -1] at t near Infinity, so it is not expected to find the asymptotic behavior of your exact. Also, it seems that HypergeometricPFQRegularized is what causes excessive computation time. $\endgroup$
    – QuantumDot
    Mar 27, 2016 at 13:36

2 Answers 2

5
$\begingroup$

Taking into account the remark of @vito in the comment, I suggest to take the correct formulas of the simple one-dimensional random walk and calculate the mean square deviation as a function of time.

The probability that the walker gets at the point n at time t is given by

p[n_, t_] := 1/2^t Binomial[t, (t + n)/2]

The normalization can be checked by this sum

Sum[p[n, t], {n, -t, t, 2}]

(* Out[16]= 1 *)

Notice that, the sum differs from the sum in the OP in these two aspects: the sum is over a finite number of terms from - t to + t, and it jumps in steps of two.

Higher moments are (Simplify takes care that t assumes integer values)

m[k_] := Simplify[Sum[n^k p[n, t], {n, -t, t, 2}], t \[Element] Integers]

m[1]

(* Out[39]= 0 *)

And the moment in question is

m[2]

(* Out[40]= t *)

As expected it is equal to the time t, i.e. the numer of steps taken.

EDIT

We can calculate and identify a general moment. The generating function of the moments Expectation( Exp[n x]) is

g[x_, t_] := Cosh[x]^t

Hence the moments are

m[k_] := D[g[x, t], {x, k}] /. x -> 0

The first few are

tb = Table[m[k], {k, 0, 10, 2}] // Expand

(* Out[30]= 
{1, t, -2 t + 3 t^2, 
 16 t - 30 t^2 + 15 t^3, -272 t + 588 t^2 - 420 t^3 + 105 t^4, 
 7936 t - 18960 t^2 + 16380 t^3 - 6300 t^4 + 945 t^5}
*)

These polynomials in t are related to the sequence

Flatten[List @@@ tb] /. t -> 1

(* Out[37]= {1, 1, -2, 3, 16, -30, 15, -272, 588, -420, 105, 7936, -18960, 16380, -6300, 945}
*)

which is listed in https://oeis.org/A085734

$\endgroup$
3
$\begingroup$

The exact function can be simplified

exact[t_] = 
 2^-t ((Binomial[t, 1/2 (-2 + t)] + Binomial[t, (2 + t)/2]) (2 + 
         t + (8 (-2 + t) Hypergeometric2F1[3, 2 - t/2, 3 + t/2, -1])/(4 + 
            t)) + \[Pi] Binomial[
        1 + t, (1 + t)/2] Gamma[(3 + t)/2] HypergeometricPFQRegularized[{1, 
         3/2, 3/2, (1 - t)/2}, {1/2, 1/2, (3 + t)/2}, -1]) //
   FunctionExpand // FullSimplify

(*  t + (4*Gamma[(3 + t)/2]*
        ((4 + t)*(2 + 3*t) + 
           2*(-2 + t)*t*Hypergeometric2F1[
               1, 2 - t/2, (6 + t)/2, -1]))/
     (Sqrt[Pi]*(1 + t)*(2 + t)*
        (4 + t)*Gamma[t/2])  *)

The limit of the exact function exists at t = 0

exact[0] = exact[0.] = Limit[exact[t], t -> 0]

(*  0  *)

The first term of the series expansion does not really simplify the expression and its limit does not exist at t = 0

approx[t_] = Series[exact[t], {t, Infinity, 0}] // Normal // FullSimplify

(*  (1/(32*Sqrt[Pi]))*((1/t)^(3/2)*
      ((32*Sqrt[Pi])/(1/t)^(5/2) + 
         Sqrt[2]*(291 + 
              8*t*(-19 + 12*t)) + 
         2*Sqrt[2]*(1345 + 
              8*t*(-33 + 4*t))*
           Hypergeometric2F1[1, 2 - t/2, 
             (6 + t)/2, -1]))  *)

Limit[approx[t], t -> 0]

(*  ∞  *)

To avoid loss of precision in the Plot set a WorkingPrecision to force use of arbitrary precision rather than machine precision in the calculations.

Plot[{exact[t], approx[t]}, {t, -20, 1000},
 PlotStyle -> {Directive[Blue, Thick],
   Directive[Red, AbsoluteDashing[{15, 10}]]},
 WorkingPrecision -> 20,
 PlotLegends -> "Expressions"]

enter image description here

Plot[{approx[t] - exact[t]}, {t, 200, 2000},
 WorkingPrecision -> 20]

enter image description here

$\endgroup$
4
  • $\begingroup$ But in my book, answer is $t$. $\sqrt{\sum_{n=-\infty}^{\infty} \frac{n^2}{2^t}\binom{t}{\frac{t+n}{2}}}=\sqrt{t}$. I evaluate this infinite series and I gave the function "exact[t]" $\endgroup$
    – vito
    Mar 27, 2016 at 15:30
  • $\begingroup$ "my book" - can you show this book to us, @vito? $\endgroup$ Mar 27, 2016 at 15:58
  • $\begingroup$ @vito - Or show us the Mathematica commands that you used to evaluate the series shown in your comment. $\endgroup$
    – Bob Hanlon
    Mar 27, 2016 at 16:11
  • $\begingroup$ @J.M. [Quantum Walks and Search Algorithms ](dropbox.com/s/1k4afz4v2xldl63/…) page 19. equation 3.3. thanks $\endgroup$
    – vito
    Mar 27, 2016 at 16:56

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.