# How can draw the inner region of the one -parameter function?

fig1 = ParametricPlot[{(1 + r -12 r^2 + 4 r^3)/(2 r - 2 ),
Sqrt[(4 r^2)/(r - 1)^2 (r - r^2 (r - 3)^2)]}, {r, 2, 4},
Axes -> True, Frame -> False,
PlotStyle -> {Directive[Yellow, Thick]}]

fig2 = ParametricPlot[{(1 + r - 12  r^2 + 4 r^3)/(
2 r - 2 ), -Sqrt[(4 r^2)/(r - 1)^2 (r - r^2 (r - 3)^2)]}, {r, 2,
4}, Axes -> True, Frame -> False,
PlotStyle -> {Directive[Yellow, Thick]},
PlotRange -> {{-12, 12}, {-8, 8}}, AspectRatio -> Automatic]

Show[fig1,fig2]


• I think you just need Show[fig1, fig2, PlotRange -> All] Commented Mar 22, 2016 at 17:36
• Hi, thank you your answer but this isnt satisfy. ı need like a regionplot. Commented Mar 22, 2016 at 17:47
• This function doesnt transform to the cartesian format!! Commented Mar 22, 2016 at 17:53
• Welcome to Mathematica.SE! I suggest the following: 0) Browse the common pitfalls question 1) As you receive help, try to give it too, by answering questions in your area of expertise. 2) Read the faq! 3) When you see good questions and answers, vote them up by clicking the gray triangles, because the credibility of the system is based on the reputation gained by users sharing their knowledge. Also, please remember to accept the answer, if any, that solves your problem, by clicking the checkmark sign! Commented Mar 22, 2016 at 17:53
• i found the answer of my question mathematica.stackexchange.com/questions/10811/… thenk you. Commented Mar 24, 2016 at 18:41

We "invent" the second parameter:

f[r_, n_] := {(1 + r - 12 r^2 + 4 r^3)/(2 r - 2),
n Sqrt[(4 r^2)/(r - 1)^2 (r - r^2 (r - 3)^2)]}

ParametricPlot[u f[r, 1] + (1 - u) f[r, -1], {r, 2, 4}, {u, 0, 1},
Axes -> True, Frame -> False, PlotRange -> All, PlotPoints -> 50]


• How shall one beat 26 minutes. ;-(
– gwr
Commented Mar 22, 2016 at 17:55
• @gwr That poses an interesting question! What is the statistic for the elapsed time until the first answer on this site? Commented Mar 22, 2016 at 17:58
• Inventing second parameter is cheating! :) Commented Mar 22, 2016 at 18:07
• Commented Mar 22, 2016 at 18:20
• @gwr Query here data.stackexchange.com/mathematica/query/454758/… Commented Mar 22, 2016 at 18:33

using RegionPlot ( this is awful slow.. )

region = ParametricRegion[{
{ (1 + r - 12 r^2 + 4 r^3)/(2 r - 2),
z Sqrt[(4 r^2)/(r - 1)^2 (r - r^2 (r - 3)^2)]},
2 < r < 4 && -1 < z < 1} , {r, z}];
RegionPlot[region, PlotRange -> {{-7, 7}, {-7, 7}}]


oddly if we supply the exact bounds on r:

 2 (1 + Sin[\[Pi]/18]) < r < 2 (1 + Cos[(2 \[Pi])/9])


its even slower..

• Does anybody else get something like this from above code on Windows 10 (64 Bit) using Mathematica 10.4 or am I unique?
– gwr
Commented Mar 22, 2016 at 18:32
• Maybe that ugly result also explains why it is not slow at all on my machine? ;-)
– gwr
Commented Mar 22, 2016 at 18:33
• I checked it again, v10.1 takes a minute and a half. Commented Mar 22, 2016 at 18:40
• Do you have an explanation for the result I am getting using your solution? (If you are on 10.1 then we might have an explanation for me getting a result in a blink -- which is wrong?)
– gwr
Commented Mar 22, 2016 at 18:41
• @gwr, I get the same result as you, 10.4 Commented Mar 22, 2016 at 19:10