3
$\begingroup$

I have this output:

Conjugate[Subscript[a, 0][x] + t^β Subscript[a, 1][x]]

I want to distribute Conjugate:

Conjugate[Subscript[a, 0][x]] + t^β Conjugate[Subscript[a, 1][x]]

I tried using Thread[U, Plus], for U set to:

Conjugate[
 E^(I x) + (t^α Subscript[a, 0][x])/Gamma[1 + α] + (
  4^-α Sqrt[π] t^(2 α) Subscript[a, 1][x])/
  Gamma[1/2 + α]]

However, this doesn't appear to work. Any suggestion?

$\endgroup$
3
  • 2
    $\begingroup$ The result you're looking for requires the assumption that t^\[Beta] is real. Apart from pulling that out, a start might be Thread[expr, Plus]. $\endgroup$ – Martin Ender Mar 11 '16 at 12:34
  • $\begingroup$ Many thanks. I want introduce t^[Beta] is real in global, but I don not know. Please help abut this problem. $\endgroup$ – Bahram Agheli Mar 11 '16 at 13:06
  • $\begingroup$ About 3 term, I think 'Plus' is not correct. $\endgroup$ – Bahram Agheli Mar 11 '16 at 13:18
2
$\begingroup$

I don't know if there's a better option, but you can do it manually. To distribute Conjugate over addition, you can use Thread as I mentioned in the question. The reason why it doesn't work with more complicated expressions as your first example is that it's only applied at the top level. This can be fixed with replacement rule:

expr = Conjugate[
     E^(I x) + (t^α Subscript[a, 0][x])/Gamma[1 + α] + (
      4^-α Sqrt[π] t^(2 α) Subscript[a, 1][x])/
      Gamma[1/2 + α]]

expr /. e : Conjugate[Plus[__]] :> Thread[e, Plus]

(* E^(-I Conjugate[x]) + (
 4^-Conjugate[α] Sqrt[π]
   Conjugate[t^(2 α) Subscript[a, 1][x]])/
 Gamma[1/2 + Conjugate[α]] + 
 Conjugate[t^α Subscript[a, 0][x]]/
 Gamma[1 + Conjugate[α]] *)

This already gets you a good part of the way. But it doesn't pull out your prefactors yet, and neither will Simplify. The reason for that is the Mathematica doesn't know they are real. You can convince it that they are by giving it a suitable list of assumptions. The simplest case would be Element[x, Reals] for every single prefactor you have, but that could be annoying because you seem to have various combinations of t and α. It might be better to give it a handful of more basic assumptions that guarantee that all of your prefactors will still be real, for instance:

Assuming[{Element[α, Reals], t > 0},
 Simplify[expr /. e : Conjugate[Plus[__]] :> Thread[e, Plus]]
]

(* E^(-I Conjugate[x]) + (
 4^-α Sqrt[π] t^(2 α)
   Conjugate[Subscript[a, 1][x]])/Gamma[1/2 + α] + (
 t^α Conjugate[Subscript[a, 0][x]])/Gamma[1 + α] *)

Here's a screenshot of all three expressions for better readability:

enter image description here

It is a bit odd that Mathematica distributes Conjugate over the exponential summand automatically, but not over the other two. If someone could shed some additional light on why that happens, I'd also be very interested.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.