6
$\begingroup$

The process of ListContourPlot[] or ListDensityPlot[] is extremely slow comparing to Matlab's contour(). Why? Is it possible to speed it up? I prefer ListDensityPlot[] but plotting of an array of 512x512 elements takes about 5 min (several seconds with contour() in Matlab).

EDIT

To be more specific: I have a regular square grid of (x,y) coordinates, x = y = -5*^-7 ... 5*^-7, and a square grid of function values in range [0,0.05]. To plot these data I tried ListDensityPlot[{{x1,y1,f1},{x2,y2,f2},...,{xn,yn,fn}}] but it's very slow (several minutes, rescaling doesn't help). DensityPlot[Interpolate[...]] is much faster but the image quality deteriorates by interpolation. I like ArrayPlot[], it's fast and image looks nice, but I loose any information about coordinates. I need to simply visualize points without any changes but keep (x,y) coordinates.

$\endgroup$
  • 2
    $\begingroup$ It shouldn't take that long, can you post the code that generates the data, or is it too long? Is the data in the form of an $n \times n$ array, or in the form of {{x1, y1, z1}, {x2, y2, z2},.......{xn, yn, zn}}? $\endgroup$ – Jason B. Mar 10 '16 at 14:07
  • $\begingroup$ It really does. The generation is a bit long but data are stored, so I actually use ListDensityPlot[{{x1, y1, z1}, {x2, y2, z2},.......{x262144, y262144, z262144}}]. $\endgroup$ – T. Rihacek Mar 10 '16 at 14:22
  • 1
    $\begingroup$ Are the data points in a regular grid? Or are they randomly spaced throughout the grid? If they are regular, then you are much better off reshaping it so that you have an $n \times n$ array of z values only. For some reason that plots much better. $\endgroup$ – Jason B. Mar 10 '16 at 14:24
  • $\begingroup$ Another option that is probably faster is to do this, intfunc=Interpolation[data]; DensityPlot[ intfunc[x, y], {x, xmin, xmax}, {y, ymin, ymax}, options] where data is your data and options are all the options you use with ListDensityPlot $\endgroup$ – Jason B. Mar 10 '16 at 14:26
  • 1
    $\begingroup$ Further issues, possibly relevant: ListContourPlot and ListContourPlot3D use better interpolation for arrays of values than for lists of tuples, and depending on your version, you may be running into a bug that existed up to version 10.3: Terrifying performance decrease for contour/density plots in v10.1 -> 10.3. $\endgroup$ – MarcoB Mar 10 '16 at 17:26
15
$\begingroup$

This comes up quite often here - Mathematica simply does a much better job of making 2D plots when the data is an $n\times n$ array of z-values than it does when the data is an $n^2 \times 3$ list of {x, y, z} tuples. I think it uses different interpolation algorithms.

If the data is on a regular grid, then there is absolutely no reason to use the tuples form, since you can specify the x and y ranges using DataRange. Here is an example, with a larger list of data than in the OP,

testdata1 = 
  Flatten[Table[{x, y, 
     Sin[x - 2 y] Cos[
       2 x + y]}, {x, -π, π, .01}, {y, -π, π, .01}], 
   1];

Dimensions@testdata1
(* {395641, 3} *)

If I use ListDensityPlot on the data in this format, it takes 81 seconds on my machine (ListContourPlot takes a bit longer),

ListDensityPlot[testdata1, ImageSize -> 400] // AbsoluteTiming

enter image description here

If, however, I restructure the data using Partition (and Transpose to keep the x and y axes in the same spot), then it only takes about 4 seconds,

testdata2 = Transpose[Partition[testdata1[[All, 3]], 629]];
ListDensityPlot[testdata2, ImageSize -> 400, 
  DataRange -> {{-π, π}, {-π, π}}] // AbsoluteTiming

enter image description here

Exact same output, in much less time.

You can get a similar plot with ArrayPlot, although it doesn't make the tick marks look very nice. You have to reverse the data to account for the reversal that automatically happens with ArrayPlot,

ArrayPlot[Reverse@testdata2, 
  ColorFunction -> "M10DefaultDensityGradient", 
  DataRange -> {{-π, π}, {-π, π}}, AspectRatio -> 1, 
  FrameTicks -> All, ImageSize -> 500(*,DataReversed\[Rule]{True,
  False}*)] // AbsoluteTiming

enter image description here

This is the fastest non-interpolating option. You can get away from the ugly tick labels if you use the CustomTicks package, part of the SciDraw package. If you do the above plot using FrameTicks -> {{LinTicks, StripTickLabels@LinTicks}, {LinTicks, StripTickLabels@LinTicks}} then it comes out looking decent.

Another workaround is to use Interpolation, and it is faster, but it's usually better to work with the data itself. And to get the same quality, you often have to use a high value for PlotPoints,

func = Interpolation[testdata1];
DensityPlot[func[x, y], {x, -π, π}, {y, -π, π}, 
  ImageSize -> 400, PlotPoints -> 100] // AbsoluteTiming

enter image description here

$\endgroup$
  • $\begingroup$ So the middle method is the one I'm advocating (ListDenistyPlot[testdata2,DataRange->....], not the last one. But you can get there with ArrayPlot as well, but I think the tickmarks are uglier. $\endgroup$ – Jason B. Mar 11 '16 at 12:40
  • 2
    $\begingroup$ As to the ticks issue, you can also draw a blank density plot and then show it with the array plot: Show[DensityPlot[False, {x, -\[Pi], \[Pi]}, {y, -\[Pi], \[Pi]}, ImageSize -> 400], (*ArrayPlot[...]*)] $\endgroup$ – xzczd Mar 11 '16 at 19:14
  • $\begingroup$ @JasonB. How would you do this if the data is not n^2 x 3 but n x m x 3? I tried doing this by using the largest of two, let's say n: Transpose[Partition[testdata1[[All, 3]], 629]] but the resulting image is not identical to the original. I have a mirror symmetry along the 0. Edit: It's because my data range runs from 5 to -5. So I probably need to sort that. $\endgroup$ – Karim Dec 3 '18 at 22:42

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.