Incompatibility between Dynamic’s second argument and Wolfram Demonstrations

Question

A central feature of the Wolfram Demonstrations is the use of multiple instances of the Manipulate output, placed into the Thumbnail and Snapshots sections – for instance here, that are used to illustrate different control settings and corresponding displays. However that seems to preclude the use of Dynamic’s second argument for various control variables to either change the expression displayed, or to limit or constrain the choices available for other controls. To illustrate, the following shows the bare bones code for a Manipulate and two separate instances of its output with 3 three controls adjusted to give different displays:

Manipulate[
 Plot[{Cos[frq$a x], Sin[frq$b x + plt$ph]}, {x, 0, 10}, 
  ImageSize -> {250, 170}],
 Row[{Style[Text["Multiplier 1: "], 12], 
   Slider[Dynamic[frq$a], {1, 10}]}],
 Control[{{frq$b, 2, "Multiplier 2"}, 1, 4}], 
 DynamicModule[{ctrl, b}, 
  Row[{Style[Text["Phase: "], 12], 
    Slider[Dynamic[
      b, (b = #; ext$var$1 = b + 3; plt$ph = b + 3) &], {0, 10}]}]],
 LocalizeVariables -> True,
 Initialization :> (plt$ph = 3; frq$a = 5)]

In the display, changing either of the Multiplier 1 controls causes the physical position of the other one to change in lock-step, with both displays changing likewise. But changing either of the Multiplier 2 controls changes only that physical control setting (frq_b) along with the corresponding frequency (the red trace, the higher frequency sine wave in the right-most display). And, finally, in an attempt to get the unlinked features of the Multiplier 2 controls while keeping the necessary features of Dynamic associated with the Multiplier 1 control, I created a DynamicModule that incorporates another Slider control (plt_ph). However, while those two controls themselves are not physically linked – as indicated by their two different positions – when either one is changed the variable plt_ph is changed in both and both displays update accordingly.

So my question, though a bit of a wan hope, is whether there’s some way of obtaining that combination of features, i.e., the non-linked capability along with the ability to use Dynamic’s second argument to implement various other functions. Somewhat in passing, it seems suprising that the control Multiplier 2 – implemented as Control[{{frq_b, 2, "Multiplier 2"}, 1,4}] – creates a variable that seems to have separate instances, and values, between the two outputs. Consequently, it seems possible that something similar could implemented with the other control variable, plt_ph.

Answer 1

I'm still not sure what the desired functionality is in the working example. Here's my guess. If it's off, I apologize.

Manipulate[
 Plot[{Cos[frq$a x], Sin[frq$b x + plt$ph]}, {x, 0, 10}, ImageSize -> {250, 170}],

 {{frq$a, 5, Style[Text["Multiplier 1: "], 12]}, 1, 10},                 (*$*)
 {{frq$b, 2, "Multiplier 2"}, 1, 4},                                     (*$*)
 {{b, 0, Style[Text["Phase: "], 12]}, 0, 10,                             (*$*)
  Manipulator[Dynamic[b, (b = #; ext$var$1 = b + 3; plt$ph = b + 3) &], {0, 10}] &},
 {{plt$ph, 3}, ControlType -> None}]

I'm not sure what ext$var$1 is for. I took the prefix ext to indicate it should be a global (i.e. external) variable. One can watch it change like this:

Dynamic@ext$var$1

But there's no point to such variables in Demonstrations, since they run in a private context, not "Global`", I think.

Answer 2

The following provides some clarification and elaboration on what “the desired functionality” is intended to be. As the target application uses 3 or 4 sets of TogglerBars, Togglers, and Checkboxes – not all of whose combinations are valid or which make sense – the Dynamic second argument seems an ideal way of implementing the appropriate restrictions. In the following simplified example, the Dynamic function for the TogglerBar in particular ensures that valid combinations are selected, and that various other control variables are set prior to the Plot functions being displayed:

Manipulate[
 If[(MemberQ[go$optns, go$frq$a]) && (MemberQ[go$optns, go$frq$b]), 
  Plot[{Cos[frq$a3 x + plt$ph3], Sin[frq$b3 x + plt$ph3]}, {x, 0, 10},
    ImageSize -> {300, 170}], 
  If[MemberQ[go$optns, go$frq$a], 
   Plot[Cos[frq$a3 x + plt$ph3], {x, 0, 10}, ImageSize -> {300, 170}],
   Plot[Sin[frq$b3 x + plt$ph3], {x, 0, 10}, 
    ImageSize -> {300, 170}]]],
 Control[{{sel$enbl$2, True, Style[Text["Selection Enable:"], 12]}, 
   Checkbox[
     Dynamic[sel$enbl$2, (sel$enbl$2 = #; 
        optn$enbl = sel$enbl$2) &], {False, True}] &}], 
 Control[{{go$optns, {go$frq$b}, Style[Text["Graph Options:"], 12]}, 
   1, 5, TogglerBar[
     Dynamic[go$optns, (If[(Length[#] != 0) && (MemberQ[#, go$frq$a] ||
             MemberQ[#, go$frq$b]), go$optns = #]; 
        If[! MemberQ[go$optns, go$ph], (plt$ph3 = 0; ctl$ph = 0; 
          ph$enbl = False), ph$enbl = True]) &], {go$frq$a -> 
       "Frequency A", go$frq$b -> "Frequency B", 
      go$ph -> "Frequency & Phase"}, 
     Enabled -> Dynamic[optn$enbl]] &}],
 Control[{{frq$a3, 5, Style[Text["Frequency A:"], 12]}, 1, 10}],
 {{frq$b3, 2, Style[Text["Frequency B:"], 12]}, 1, 4}, 
 Control[{{ctl$ph, 0, Style[Text["Phase:"], 12]}, 0, 10, 
   Manipulator[
     Dynamic[ctl$ph, (ctl$ph = #; ext$ph$1a = ctl$ph + 3; 
        plt$ph3 = ctl$ph + 3) &], {0, 10}, 
     Enabled -> Dynamic[ph$enbl]] &}],
 {{plt$ph3, 3}, ControlType -> None}, {{optn$enbl, True}, 
  ControlType -> None},
 {{ph$enbl, False}, ControlType -> None}]

The following image shows two separate instances of the Manipulate output cell with different sets of control settings. Which is exactly what is required for the Demonstrations project:

It was particularly interesting to note the use of {{ph_enbl, False}, ControlType -> None} which I assume creates variables local to each instance of the Output cell of the Manipulate. Which is apparently what the use of Control[…] does, as does its more rudimentary form, e.g., {{frq_b3, 2, Style[Text["Frequency B:"], 12]}, 1, 4}.