I'm trying to show that an E field satisfies the two Maxwell equations: $\mathsf{Curl}[E]=-dB/dt$ and $\mathsf{Curl}[B]=(w/k)^2 dE/dt$

I define

$\qquad e_o(\text{t$\_$})\;\mathsf{:=}\;\left\{0,0,\frac{(A \sin (\theta )) \left(\cos (k r-t \omega )-\frac{\sin (k r-t \omega )}{k r}\right)}{r}\right\}$


$\qquad B(\text{t$\_$})\;\mathsf{:=}\;\int_0^t \mathsf{Curl}\left[e_o(t)\right] \, dt$

Now I want to show that

$\qquad e_1(\text{t$\_$})\;\mathsf{:=}\;\int_0^t \left(\frac{\omega }{k}\right)^2 \mathsf{Curl}[B(t)] \, dt$

is equivalent to $e_o$

but the terms don't actually seem to be equivalent and FullSimplify doesn't seem to work right. I'm not sure if/how I am supposed to put constraints the constants k and w.

Here is my actual input text:

Subscript[E, o][r_, θ_, ϕ_] := 
  {0, 0, (A Sin[θ])/r (Cos[k r - ω t] - Sin[k r - ω t]/(k r))}

Div[Subscript[E, o][r, θ, ϕ], {r, θ, ϕ}, "Spherical"]


Curl[Subscript[E, o][r, θ, ϕ], {r, θ, ϕ}, "Spherical"]
{(2 A Cos[θ] (Cos[k r - t ω] - Sin[k r - t ω]/(k r)))/r^2, 
  -((A Sin[θ] (-(Cos[k r - t ω]/r) - k Sin[k r - t ω] + Sin[k r - t ω]/(k r^2)))/r), 
B[r_, θ_, ϕ_] := 
  -Integrate[Curl[Subscript[E, o][r, θ, ϕ], {r, θ, ϕ}, "Spherical"], {t, 0, t}]

FullSimplify[B[r, θ, ϕ]]
{(4 A Cos[θ] Sin[(t ω)/2] (-k r Cos[k r - (t ω)/2] + Sin[k r - (t ω)/2]))/(k r^3 ω), 
 -((2 A Sin[θ] Sin[(t ω)/2] (k r Cos[k r - (t ω)/2] + (-1 + k^2 r^2) Sin[k r - (t ω)/2]))/(k r^3 ω)), 
Simplify[Div[B[r, θ, ϕ], {r, θ, ϕ}, "Spherical"]]
Subscript[E, 1] := 
  Integrate[(ω/k)^2 Curl[B[r, θ, ϕ], {r, θ, ϕ}, "Spherical"], {t, 0, t}]

FullSimplify[Part[Subscript[E, 1], 3] == Part[Subscript[E, o][r, θ, ϕ], 3]]
(A ((k r + t ω) Cos[k r] + (-1 + k r t ω) Sin[k r]) Sin[θ])/(k r) == 0
  • 2
    $\begingroup$ Please post the actual Mathematica code that you are using (e.g. you're probably not using $e_1(t_)$ but rather e1[t]), properly formatted in code blocks: edit your post and click on the grey question mark at the right of the editing toolbar for help. As for Ttheta, although it's impossible to diagnose the problem without your actual code, probably what's going on is you need to put a space or a * between T and theta. $\endgroup$
    – march
    Mar 4, 2016 at 22:45
  • $\begingroup$ A couple of questions. The theta that appears in the definition of Eo: is it supposed to be the spherical coordinate $\theta$? In that case, I'm guessing you need to use Ttheta instead, since it seems that by using SetCoordinates, it assumes that the names of the spherical coordinates are Rr, Ttheta, Pphi. That would explain where the Csc[Ttheta]^2 comes from: it shows up probably because of the form of the curl in spherical coordinates. Anyway, I'm not familiar with this (outdated as of V9) functionality, so I can't say much else. $\endgroup$
    – march
    Mar 4, 2016 at 23:09
  • $\begingroup$ @march what would I use instead for the most recent version of Mathematica? $\endgroup$
    – Logan
    Mar 4, 2016 at 23:22
  • 2
    $\begingroup$ @Logan take a look at this tutorial on the built-in vector analysis capabilities in newer versions of MMA: Vector Analysis Tutorial $\endgroup$
    – MarcoB
    Mar 4, 2016 at 23:24
  • 1
    $\begingroup$ Following @MarcoB's suggestion, you will see nice things like Curl[Subscript[E, o][t], {r, θ, ϕ}, "Spherical"]. $\endgroup$
    – march
    Mar 4, 2016 at 23:32

1 Answer 1


There was nothing wrong with Mathematica's result. You just made a mistake in the time integration by enforcing a condition of vanishing magnetic field at the lower integration limit $t=0$ which is not correct. Instead, you should just do the indefinite integral, as follows:

Clear[ω, k, t, A, r, θ, ϕ]
E0 = {0, 0, (A Sin[θ])/r (Cos[k r - ω t] - Sin[k r - ω t]/(k r))};

curlE0 = Curl[E0, {r, θ, ϕ}, "Spherical"]
==> {(
 2 A Cos[θ] (Cos[k r - t ω] - Sin[k r - t ω]/(k r)))/r^2, -
  ((A Sin[θ] (-(Cos[k r - t ω]/r) - 
     k Sin[k r - t ω] + Sin[k r - t ω]/(k r^2)))/r), 0}

dtE0 = D[E0, t]
==> {0, 0, (A Sin[θ] ((ω Cos[k r - t ω])/
  (k r) + ω Sin[k r - t ω]))/r}

b = Integrate[curlE0, t] // Simplify
==> {-((
  2 A Cos[θ] (Cos[k r - t ω] + 
     k r Sin[k r - t ω]))/(k r^3 ω)), (
 A Sin[θ] ((-1 + k^2 r^2) Cos[k r - t ω] - 
    k r Sin[k r - t ω]))/(k r^3 ω), 0}

curlB = Simplify[Curl[b, {r, θ, ϕ}, "Spherical"]]
==> {0, 0, -((
  A k Sin[θ] (Cos[k r - t ω] + 
     k r Sin[k r - t ω]))/(r^2 ω))}

Simplify[dtE0 == -(ω/k)^2 curlB]

(* ==> True *)

I made several other modifications. First, get rid of the Subscript, then don't use E as a name.

Also, I avoided the second time integral by instead comparing the curl of the magnetic field to the time derivative of the given electric field. You also had a missing minus sign in the last comparison.


Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.