Rendering a shape rather than a point in Graphics

Question

Here is some sample data

m = {{0.658254, 1.04273, 0.15, 0.613587, 2}, {0.157981, 4.03653, 1.25, 
        0.437706, 1}, {0.149204, 1.65371, 2.72, 0.571777, 1}, {0.495885, 
        3.62412, 1.67, 0.00119993, 3}, {-0.149204, 2.23414, 200., 0.260858, 
        0}, {-0.50905, 2.98259, 200., 0.146681, 0}, {-0.662643, 1.60788, 
        21.77, 0.0305032, 1}, {0.539769, 0.385922, 0.33, 0.450807, 
        2}, {0.157981, 3.77687, 1.04, 0.584416, 1}, {-0.623147, 4.32675, 
        200., 0.173352, 0}};

A color code

getColor[m_List, i_Integer] := Module[{s = m[[i, 5]]}, 
Which[s == -1, White, s == 0, Blue, s == 1, Red, s == 2, Darker[Green],
      s == 3, Cyan]];

data = Table[{PointSize[0.004], getColor[m, i], Point[{m[[i, 1]], 
       m[[i, 2]]}]}, {i, 1, Length[m]}];

And finally we plot them

S0 = Graphics[data]

Graphics renders the data using dots with the predefined point size. How can I change the plot markers to small squares instead of dots? Of course, I should be able to control the size of the new plot markers.

EDIT

If I use @Andrew S method in a Show like

P0 = Show[S0, Axes -> False, Frame -> True, FrameLabel -> {"x", "y"}, 
     RotateLabel -> False, LabelStyle -> Directive[FontFamily -> "Helvetica", 20], 
     PlotRange -> All, AspectRatio -> 1, PlotRangeClipping -> True,
     PlotRangePadding -> 0, ImageSize -> 500]

then the squares become rectangles.

The output of the Graphics

And then the output of the Show

EDIT 2

@m_goldberg:

Test.nb

The final plot markers are much bigger than in Graphics, while some of them are cut in half at the borders.

Answer 1

If you need Graphics (even though for this ListPlot will be better), then you can use

rectSize = 0.05;
data = Table[
   {
    getColor[m, i],
    Rectangle[{m[[i, 1]] - rectSize, 
      m[[i, 2]] - rectSize}, {m[[i, 1]] + rectSize, 
      m[[i, 2]] + rectSize}]
    },
   {i, 1, Length[m]}
   ];

To draw rectangles instead of points:

Or with ListPlot

markSize = 0.05;
ListPlot[
 Table[{{m[[i, 1]], m[[i, 2]]}}, {i, 1, Length[m]}],
 PlotMarkers -> Table[
   {Graphics[{getColor[m, i], Rectangle[{-1, -1}, {1, 1}]}], markSize},
   {i, 1, Length[m]}
   ]
 ]

For this:

EDIT:

To fix the ratio problem after "post-rationing" the whole graphics object

yR = Max[m[[All, 2]]] - Min[m[[All, 2]]];
xR = Max[m[[All, 1]]] - Min[m[[All, 1]]];
rectSize = 0.05;
data = Table[
   {getColor[m, i], 
    Rectangle[{m[[i, 1]] - rectSize*xR/yR, 
      m[[i, 2]] - rectSize}, {m[[i, 1]] + rectSize*xR/yR, 
      m[[i, 2]] + rectSize}]},
   {i, 1, Length[m]}
   ];

Answer 2

First let's simplify your code so it will be easier to make the adjustment you are asking for.

m = {{0.658254, 1.04273, 0.15, 0.613587, 2}, {0.157981, 4.03653, 1.25,
     0.437706, 1}, {0.149204, 1.65371, 2.72, 0.571777, 1}, {0.495885, 
     3.62412, 1.67, 0.00119993, 3}, {-0.149204, 2.23414, 200., 
     0.260858, 0}, {-0.50905, 2.98259, 200., 0.146681, 0}, {-0.662643, 
     1.60788, 21.77, 0.0305032, 1}, {0.539769, 0.385922, 0.33, 
     0.450807, 2}, {0.157981, 3.77687, 1.04, 0.584416, 1}, {-0.623147, 
     4.32675, 200., 0.173352, 0}};

colors = <|-1 -> White, 0 -> Blue, 1 -> Red, 2 -> Darker[Green], 3 -> Cyan|>;
pts = {colors[#[[5]]], AbsolutePointSize[8], Point[#[[1 ;; 2]]]} & /@ m;

Now, let's replace pts with a marker generating function that will accept any graphics object and make markers scaled to a specified fraction of the graphics viewport.

markers[graphic_, scale_, data_] := 
  Inset[
    Graphics[{colors[#[[5]]], graphic}], 
    #[[1 ;; 2]], {.5, .5}, Scaled[scale]]& 
  /@ data

Now we can reproduce your point image with

Graphics[markers[Disk[], .07, m]]

and also produce square markers this way

Graphics[markers[Rectangle[], .08, m]]

or this way

Graphics[markers[RegularPolygon[4], .08, m]]

and even have pentagon markers.

Graphics[markers[RegularPolygon[5], .1, m]]

Update

Versions of Mathematica too old to have associations can use a list of rules to set the colors.

colorRules = {-1 -> White, 0 -> Blue, 1 -> Red, 2 -> Darker[Green], 3 -> Cyan};
markers[graphic_, scale_, data_] :=
  Inset[
    Graphics[{#[[5]] /. colorRules, graphic}], 
    #[[1 ;; 2]], {.5, .5}, Scaled[scale]]& 
  /@ data

Update 2

You only need to make some minor adjustments. Reduce the marker scale factor, add PlotRangePadding and remove PlotRangeClipping.

Show[Graphics[markers[RegularPolygon[4], .025, m]], 
  Axes -> False, 
  Frame -> True, 
  FrameLabel -> {"x", "y"}, 
  RotateLabel -> False, 
  LabelStyle -> Directive[FontFamily -> "Helvetica", 20], 
  PlotRange -> All, 
  AspectRatio -> 1, 
  PlotRangePadding -> .15, 
  ImageSize -> 500]