0
$\begingroup$

I have a function of two positive variables $t$ and $C$ with $t$ and $C$ in a specific range as below. $0 < C < 10^{-5}$ and $0< t <4.54 \times 10^{-6}$. I want to see which variable of $C$ where the value of the function doesn't depend much on the variable $t$. So I used Plot3D[] function. However, from the plot I can vaguely see the trend. Is there a way to see it more clearly in Mathematica?

Function:

(0.0002607680962081059*(-1 + E^((63.9137490706142*Sqrt[6.799999999999999*^-6 - 144*C]*t)/C)))/(E^((12254.901960784315*(6.799999999999999*^-6 + 0.002607680962081059*Sqrt[6.799999999999999*^-6 - 144*C])*t)/C)*Sqrt[6.799999999999999*^-6 - 144*C])

Plot:

Plot3D[(0.0002607680962081059` E^(-((12254.901960784315` (6.799999999999999`*^-6+0.002607680962081059` Sqrt[6.799999999999999`*^-6-144 C]) t)/C)) (-1+E^((63.9137490706142` Sqrt[6.799999999999999`*^-6-144 C] t)/C)))/Sqrt[6.799999999999999`*^-6-144 C],{C,0,10^-5},{t,0,4.54 10^-6},AxesLabel->{C,t,VL}, PlotRange-> All,Mesh-> None,Background->Black,AxesStyle->White,Boxed->False]
$\endgroup$
  • 1
    $\begingroup$ I'd suggest reducing the C range to {C, 0, 10^-6} to zoom in on a more interesting region of your plot; I would also suggest using DensityPlot or ContourPlot instead of Plot3D to capture some features of your 3D graph as a 2D projection, which may be more readable. $\endgroup$ – MarcoB Mar 1 '16 at 8:00
4
$\begingroup$

I want to see which variable of C where the value of the function doesn't depend much on the variable t

For this, I would plot the derivative of the function with respect to t, in those regions where it is close to 0, then the dependence on t is weakest.

f[C_, t_] := (0.0002607680962081059` E^(-((12254.901960784315` \
(6.799999999999999`*^-6 + 
              0.002607680962081059` Sqrt[
                6.799999999999999`*^-6 - 144 C]) t)/C)) (-1 + 
       E^((63.9137490706142` Sqrt[6.799999999999999`*^-6 - 144 C] t)/
          C)))/Sqrt[6.799999999999999`*^-6 - 144 C];
With[
 {dfdt = D[f[C, t], t]},
 Plot3D[{dfdt, 0}, {C, 0, 10^-5}, {t, 0, 4.54 10^-6}, 
  PlotRange -> {-10^4, 10^4}, AxesLabel -> {C, t, VL}, 
  BoxRatios -> {1, 1, 1}]
 ]

enter image description here

As you can see, nowhere in this range is the derivative with respect to t equal to zero, so the function always has some dependence on t. But that dependence is strongest between C=0 and C=5*10^(-6).

You can view the derivative using a regular Plot as well,

With[
 {dfdt = D[f[C, t], t], cvalues = Range[2 10^-6, 10^-5, 2.0 10^-6]},
 Plot[Evaluate[
   dfdt /. C -> # & /@ cvalues
   ], {t, 0, 4.54 10^-6}, 
  PlotLegends -> (Row[{"C = ", #}] & /@ cvalues)]]

enter image description here

$\endgroup$
  • $\begingroup$ Well, extremely impressive! Thank you very much. $\endgroup$ – anhnha Mar 1 '16 at 10:05

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.