3
$\begingroup$

I'm looking for a parametrization for $\frac{\sin(x)}{x}$ as a revolution surface arround the $y$ axis.

I have tried $X(x,y)=\Big(\frac{\sin(y)\sin(x)}{x},x,\frac{\cos(y)\sin(x)}{x}\Big)$.

ParametricPlot3D[
  {Sin[y] Sin[x]/x,x ,Cos[y] Sin[x]/x}, 
  {x, 0, 6*Pi}, {y, 0, 2*Pi}, 
  PlotRange -> All
]

But it does not make the surface it should be

Plot3D[Sin[Sqrt[x*x + y*y]]/Sqrt[x*x + y*y], {x, -10, 10}, {y, -10, 10}, PlotRange -> All]

Is my parametrization right? Can you give me some advice? Any help thanks!

$\endgroup$
8
$\begingroup$

Perhaps something like this. Just rotate the original function about the z-axis directly:

RotationMatrix[θ, {0, 0, 1}].{x, 0, Sin[x]/x}
(* {x Cos[θ], x Sin[θ], Sin[x]/x} *)

and so:

ParametricPlot3D[RotationMatrix[θ, {0, 0, 1}].{x, 0, Sin[x]/x}
 , {x, 0, 20}, {θ, 0, 2 π}
 , RegionFunction -> (-10 <= #1 <= 10 && -10 <= #2 <= 10 &)
 , PlotRange -> All
 , BoxRatios -> {1, 1, 1/2}]

enter image description here

Your original code seems to rotate around the x-axis:

ParametricPlot3D[RotationMatrix[θ, {1, 0, 0}].{x, 0, Sin[x]/x}
 , {x, 0, 10}, {θ, 0, 2 π}
 , PlotRange -> All
 , BoxRatios -> {2, 1, 1}]

enter image description here

and rotating it about the y-axis is uninteresting. (Note that I have taken z to be "vertical".)

| improve this answer | |
$\endgroup$
3
$\begingroup$

Try this:

RevolutionPlot3D[Sin[x]/x, {x, 0, 6 \[Pi]}]

enter image description here

Have fun!

| improve this answer | |
$\endgroup$
  • 1
    $\begingroup$ Or to rotate around the x-axis: evolutionPlot3D[Sin[x]/x, {x, 0, 6 Pi}, RevolutionAxis -> "X", BoxRatios -> {1, 0.25, 0.25}] $\endgroup$ – murray Feb 26 '16 at 15:19

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.