1
$\begingroup$

I have two equations from a analisys of the following situation. A ball starts to move from the center of a turntable (rotating disk).

enter image description here

I tried to solve these equations in Mathematica but the solution is too long and complex.

I want to make a ball following the solution of these equations.

eqx = DSolve[{(x''[t] == w^2 x[t] + 2 w Derivative[1][y][t] + w'[t] (y[t])}, x[t], t]
eqy = DSolve[{(y''[t] ==  w^2 y[t] - 2 w Derivative[1][x][t] - w'[t] (x[t])}, y[t], t]
Equacao = Thread[eqx == eqy]
CondIni = {x[0] == 0, x'[0] == 0, y[0] == 0, C[1] == 1, C[2] == 1, 
  K[1] == 1, K[2] == 0}
Exemplo = Join[Equacao, CondIni]

If someone could help with these solutions, or the manipulation of a ball following these equations I'd be grateful..

$\endgroup$
7
$\begingroup$
w[t_] := Cos@t
nd = NDSolveValue[{
    x''[t] == w[t]^2 x[t] + 2 w[t] y'[t] + w'[t] y[t],
    y''[t] == w[t]^2 y[t] - 2 w[t] x'[t] - w'[t] x[t],
    y[0] == 0, y'[0] == 1,
    x[0] == 0, x'[0] == 0}, {x, y}, {t, 0, 10}];

ParametricPlot[Through[nd[t]], {t, 0, 10}]

Mathematica graphics

Or shorter in vector form:

w[t_] := Cos@t
s = RotationMatrix[-Pi/2];

nd = NDSolveValue[{r''[t] == {r[t], s.r'[t], s.r[t]}.{w[t]^2, 2 w[t], w'[t]}, 
                   r[0] == {0, 0}, r'[0] == {0, 1}}, {r}, {t, 0, 10}];

ParametricPlot[Through[nd[t]], {t, 0, 10}]
$\endgroup$
  • $\begingroup$ It works... I´ll try to make a manipulate follow this path, theres is a way to make an object, like a ball, follow the path? $\endgroup$ – dcvilela Feb 23 '16 at 18:46
  • $\begingroup$ @dcvilela Your previous question was about that! $\endgroup$ – Dr. belisarius Feb 23 '16 at 18:58
  • $\begingroup$ Yeah... thats what i´m trying!! $\endgroup$ – dcvilela Feb 23 '16 at 19:01

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.