Issue with NSolve for solving six equation and six unkown [closed]

Question

I am trying to solve the following six equations and six unknown but It takes me one hour then the program stops. Would you please give some help. I am a beginner.

$eqe1=0.000466667 \left(A_2 \cosh (0.249888 d)+C_2\right)=C_3$

$eqe2=0.3=\frac{1}{4} A_3 (12.7\, -d)^2+\frac{1}{2} B_3 (12.7\, -d)+C_3$

$eqe3=0.000233229 A_2 \sinh (0.249888 d)=B_3$

$eqe4=0.000116563 A_2 \cosh (0.249888 d)=2 A_3$

$eqe5=A_3 (12.7\, -d)+B_3=0.00225946$

$eqe6=\frac{9}{2} (12.7\, -d)+2.00089 A_2 \sinh (0.249888 d)+\frac{C_2 d}{2}=19.685$

This is what I wrote:

equ1 = 0.0004666666666666666 (Cosh[0.24988836793370642 d] Subscript[A,
       2] + Subscript[C, 2]) == Subscript[C, 3]
equ2 = 0.30000000000000004 == 
   1/4 (12.7` - d)^2 Subscript[A, 3] + 
    1/2 (12.7 - d) Subscript[B, 3] + Subscript[C, 3];
equ3 = 0.00023322914340479262 Sinh[0.24988836793370642 d] Subscript[A,
     2] == Subscript[B, 3];
equ4 = 0.0001165625 Cosh[0.24988836793370642 d] Subscript[A, 2] == 
   2 Subscript[A, 3];
equ5 = (12.7 - d) Subscript[A, 3] + Subscript[B, 3] == 
   0.002259463490122021;
equ6 = 9/2 (12.7 - d) + 
    2.000893455483476` Sinh[0.24988836793370642 d] Subscript[A, 2] + (
    d Subscript[C, 2])/2 == 19.68503937007874;

qq = NSolve[{equ1 && equ2 && equ3 && equ4 && equ5 && 
    equ6}, {Subscript[A, 2], Subscript[C, 2], Subscript[A, 3], 
   Subscript[B, 3], Subscript[C, 3], d}]

By considering that $d>0$ and all variables are Real, I wrote this which never work??

    qq = NSolve[{equ1 && equ2 && equ3 && equ4 && equ5 && 
    equ6, d>0}, {Subscript[A, 2], Subscript[C, 2], Subscript[A, 3], 
   Subscript[B, 3], Subscript[C, 3], d}, Reals]

Answer 1

Avoid subscripts and user-defined names starting with capitals.

Format[a[n_]] := Subscript[a, n]
Format[b[n_]] := Subscript[b, n]
Format[c[n_]] := Subscript[c, n]

equ1 = 0.0004666666666666666 (Cosh[0.24988836793370642 d] a[2] + 
      c[2]) == c[3];
equ2 = 0.30000000000000004 == 
   1/4 (12.7` - d)^2 a[3] + 1/2 (12.7 - d) b[3] + c[3];
equ3 = 0.00023322914340479262 Sinh[0.24988836793370642 d] a[2] == b[3];
equ4 = 0.0001165625 Cosh[0.24988836793370642 d] a[2] == 2 a[3];
equ5 = (12.7 - d) a[3] + b[3] == 0.002259463490122021;
equ6 = 9/2 (12.7 - d) + 
    2.000893455483476` Sinh[0.24988836793370642 d] a[2] + (d c[2])/
     2 == 19.68503937007874;

eqns = {equ1 && equ2 && equ3 && equ4 && equ5 && equ6 && d > 0} // 
    Rationalize[#, 0] & // Simplify;

qq = NSolve[eqns, {a[2], c[2], a[3], b[3], c[3], d}, Reals, 
   WorkingPrecision -> 20][[1]]

eqns /. qq

(*  {True}  *)