Consider the following series:
$$\sigma (\text{x$\_$})\text{:=}\sqrt{\sum _{k=0}^{x-1} \frac{(x! x!) (-1)^{x-k}}{(x-k) (k! (2 x-k)!)}+\frac{\pi ^2}{12}}$$
From the following codes, it seems that the series tends to $0$ with a very low slope as $n$ approaches $+\infty$, this is the case in the article that I'm studying

σ[x_]:=Sqrt[Pi^2/12+Sum[(x!*x!)/(k!*(2 x-k)!)*(-1)^(x-k)/(x-k),{k,0,x-1}]]

enter image description here

but when I compute this limit, there are the results:

(*Limit[Sqrt[π^2/12+(-1)^(2+2 n) (HarmonicNumber[n]-HarmonicNumber[2 n])],n->∞]*)

(*Sqrt[0.822467 -0.693147 2.71828^((0. +2. I) Interval[{-6.67522*10^-308,3.14159}])]*)

(*Sqrt[(0. -0.693147 I) Interval[{-1,1}]+Interval[{0.12932,1.51561}]]*)  

How can I obtain $0$ as the result of this limit?


Observing strictly that the domain of x as the upper limit of the summation index is the integers, the limit exists, it can be calculated easily with Mathematica and it is different from zero.

We need to consider this sum

σWH[x_] := 
 Sqrt[π^2/12 + 
   Simplify[Sum[(x!*x!)/(k!*(2 x - k)!)*(-1)^(x - k)/(x - k), {k, 0, x - 1}], 
    x ∈ Integers]]

which is evaluated to

$$\text{$\sigma $WH}(\text{x}) = \sqrt{H_{\text{x}}-H_{2 \text{x}}+\frac{\pi ^2}{12}}$$

where $H_{\text{x}}$ is the harmonic number of x.

The limit is then

Limit[σWH[x], x -> ∞]

(* Out[232]= 1/2 Sqrt[π^2/3 - 4 Log[2]] *)

% // N

(* Out[233]= 0.359611 *)

This value is in good agreement with the asymptotic behaviour of your graph.


The essence of the agument can be studied in this simpler example

Sum[(-1)^(x - k)/(x - k), {k, 0, x - 1}]

(* Out[303]= (-1)^(2 x) ((-1)^x LerchPhi[-1, 1, 1 + x] - Log[2]) *)

Simplify[%, x ∈ Integers]

(* Out[304]= (-1)^x LerchPhi[-1, 1, 1 + x] - Log[2] *)

Limit[%, x -> ∞]

(* Out[305]= -Log[2] *)

I think you will have to ask a mathematician if the limit is really 0 (or even real) since in Mathematica you can get this

s[x_] := Sqrt[
  Pi^2/12 + 
   Sum[(x!*x!)/(k!*(2 x - k)!)*(-1)^(x - k)/(x - k), {k, 0, x - 1}]]
s[x] // FullSimplify
Limit[s[x], x -> Infinity] // FullSimplify


So the limit seems to be complex, but I am not sure, I am not a mathematician. If you assume that you do the limit for integers, then you get this from Mathematica

Assuming[Element[x, Integers],Limit[s[x], x -> Infinity]] // FullSimplify
(*1/2 Sqrt[π^2/3 - 4 Log[2]]*)

which is not 0.

  • $\begingroup$ Yeah, it's pretty clear from OP's plot that the limit isn't zero $\endgroup$ – Jason B. Jan 25 '16 at 10:34
  • $\begingroup$ the owner of the post and @JasonB I've made a subtle mistake. There is $k!$ in the denominator not $x!$ $\endgroup$ – Sepideh Abadpour Jan 25 '16 at 10:44
  • 1
    $\begingroup$ I would first check, if you got the expression right, since Mathematica should be able to deal with these expressions. If you are completely sure, then try your luck in math.stackexchange.com $\endgroup$ – Mauricio Fernández Jan 25 '16 at 10:55
  • 1
    $\begingroup$ @sepideh - the question is where did the authors get that formula (eq. 6) and how does it relate to the formulas in eq. 7. before eq. 6 they say "It can be shown that the standard deviation can be evaluated in terms of n as" and then they don't include a citation so you kind of have to take their word for it. I've never seen that formula for the standard deviation. But clearly the limit is not zero. I might ask over on the math SE where the authors came up with eq. 6 and how it relates to eq. 7, including this image $\endgroup$ – Jason B. Jan 25 '16 at 11:03
  • 2
    $\begingroup$ Assuming x is intended to be an integer (so we are looking at the limit of a sequence rather than a function), it reduces in the limit to 1/2 Sqrt[\[Pi]^2/3 - 4 Log[2]]. So it should be Log[2] inside the original sum, not Pi^2/12, to make the limit work out to zero. $\endgroup$ – Daniel Lichtblau Jan 25 '16 at 16:59

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.