How to combine Tabview with Dynamic Graphic to change the colour of a polygon

Question

1. How does one get TabView to specify the colour of the Polygon?

2. How does one put a label on the slider: label => "number of sides = {}".

   DynamicModule[{p, colour},
    {
     Dynamic[Graphics[{colour, Polygon[CirclePoints[p]]}]],
   
     Slider[Dynamic[p], {3, 17, 1}, Appearance -> "Labeled"],
   
     Dynamic[TabView[{colour -> Green, colour -> Orange}]]
   
   }]
   

Note: Detailed Explanations welcome. Im a determined beginner. Does it have something to do with the way TabView interacts with Set?

Answer 1

TabView is for viewing. You can associate color changes with the second argument of TabView but it will be easier to just use what is designed for that, like SetterBar.

Moreover, the less inside Dynamic the better so instead of creating whole Graphics you can just tell the FrontEnd to take care of that colour and Polygon.

DynamicModule[{p = 3, colour = Green}
 ,
 Column @ {
   Graphics[{
     Dynamic@colour,
     Dynamic@Polygon[CirclePoints[p]]
     }, PlotRange -> 1
   ],
   Row[{
     Slider[Dynamic[p], {3, 17, 1}],
     "number of sides = {", Dynamic@p, "}"
     }, Spacer[5]
   ],
   SetterBar[Dynamic@colour, {Red, Green, Orange}]
}]

Answer 2

I believe this is the natural and idiomatic way to do it:

Manipulate[Graphics[{colour, Polygon[CirclePoints[sides]]}], 
           {sides, 3, 17, 1},
           {{colour, Orange}, {Green -> "Green", Orange -> "Orange"}} ]

Answer 3

This is more or less directly cribbed from the help:

Manipulate[Graphics[{color, Polygon[CirclePoints[sides]]}],
{{sides, 3,"Number of Sides"}, 3, 17, 1}, {color, Green}]