2
$\begingroup$

Can Mathematica 10 confirm a nice closed form for

Integrate[ (-2 a Cos[π/24] Gamma[11/12] 
    HypergeometricPFQ[{11/24, 23/24}, {2/3, 4/3}, (4 a^3)/27] + 
    8 Gamma[5/4] HypergeometricPFQ[{1/8, 5/8}, {1/3, 2/3}, (4 a^3)/27] Sin[π/8] + 
    a^2 Gamma[19/12] HypergeometricPFQ[{19/24, 31/24}, {4/3, 5/3}, (4 a^3)/27]
    Sin[(5 π)/24]), {a, 0, ∞}]

?

Mathematica 8 returns no result.

$\endgroup$
9
  • $\begingroup$ @BobHanlon thank you for the helping hand $\endgroup$ Jan 13, 2016 at 15:16
  • $\begingroup$ 10.1 gives -(Sqrt[2 - Sqrt[3/2] + 1/Sqrt[2]]*Gamma[-5/12]) along with a warning that some big expression has been assumed to be zero. $\endgroup$
    – george2079
    Jan 13, 2016 at 15:25
  • $\begingroup$ @george2079 yeah, that should be $\frac{2}{15} \sin \left(\frac{5 \pi }{24}\right) \Gamma \left(\frac{7}{12}\right)$. My calculations suggest the same thing. You can post that as an answer. $\endgroup$ Jan 13, 2016 at 15:27
  • $\begingroup$ the 10.1 result (~4.47) is consistent with NIntegrate (which itself has precision issues for large a ) $\endgroup$
    – george2079
    Jan 13, 2016 at 15:36
  • $\begingroup$ I'm getting 72/35 Sqrt[2 (4 + Sqrt[2] - Sqrt[6])] Gamma[19/12] which is I think the same as george2079's 10.1 result, but not the same as 2/15 Sin[5 Pi/24]Gamma[7/12] (one is about 4.47, the other 0.16). $\endgroup$ Jan 13, 2016 at 15:44

2 Answers 2

4
$\begingroup$

This was done in V10.3.1.

Integrate[(-2 a Cos[π/24] Gamma[11/12] 
  HypergeometricPFQ[{11/24, 23/24}, {2/3, 4/3}, (4 a^3)/27] + 
    8 Gamma[5/4] HypergeometricPFQ[{1/8, 5/8}, {1/3, 2/3}, (4 a^3)/27] Sin[π/8] + 
    a^2 Gamma[19/12] HypergeometricPFQ[{19/24, 31/24}, {4/3, 5/3}, (4 a^3)/27] 
      Sin[(5 π)/24]), 
  {a, 0, ∞}]

msg

(864/665) Sqrt[2 (4 + Sqrt[2] - Sqrt[6])] Gamma[31/12]
FullSimplify[
  (864/665) Sqrt[2 (4 + Sqrt[2] - Sqrt[6])] Gamma[31/12] == 
    (24/5) Sin[5 (Pi/24)] Gamma[7/12]]

True

Closed form appears to be confirmed.

$\endgroup$
1
  • $\begingroup$ Good job there! $\endgroup$ Jan 14, 2016 at 0:08
2
$\begingroup$

A "nice" result is confirmed, but it is not the one hoped for in the OP but that of george2079 and others here.

An analysis is made on the basis of the fundamental theorem of calculus. Here no error messages appear but the slight uncertainty is now shifted to the hypothesis of continuity of the antiderivative. This in turn seems pretty obvious from plotting it for a typical interval.

Here we go.

First of all the antiderivative is given by

$Version

(* Out[7]= "10.1.0  for Microsoft Windows (64-bit) (March 24, 2015)" *)

ad = Integrate[(-2 a Cos[\[Pi]/24] Gamma[
      11/12] HypergeometricPFQ[{11/24, 23/24}, {2/3, 4/3}, (4 a^3)/27] + 
    8 Gamma[5/4] HypergeometricPFQ[{1/8, 5/8}, {1/3, 2/3}, (4 a^3)/
       27] Sin[\[Pi]/8] + 
    a^2 Gamma[
      19/12] HypergeometricPFQ[{19/24, 31/24}, {4/3, 5/3}, (4 a^3)/
       27] Sin[(5 \[Pi])/24]), a]


(* Out[1]= -((2 a^2 Cos[\[Pi]/24] Gamma[2/3] Gamma[11/
    12] HypergeometricPFQ[{11/24, 23/24}, {4/3, 5/3}, (4 a^3)/27])/(
  3 Gamma[5/3])) + (
 8 a Gamma[1/3] Gamma[5/4] HypergeometricPFQ[{1/8, 5/8}, {2/3, 4/3}, (4 a^3)/
   27] Sin[\[Pi]/8])/(3 Gamma[4/3]) - 
 288/35 Gamma[19/
   12] (-1 + HypergeometricPFQ[{-(5/24), 7/24}, {1/3, 2/3}, (4 a^3)/27]) Sin[(
   5 \[Pi])/24] *)

We make a plot to study continuity, which - although, unfortunately, the plot cannot be extended beyond a = 6 - we assume in the following to hold

Plot[ad, {a, 0, 10}]

enter image description here

Because ad/.a->0 = 0 the value of the integral is given by the limit of ad for a -> [Infinity].

In order to tackle this we expand ad in a series about a = [Infinity] and, for ease of refenrence, bring the result into the form of a list:

 sad = List @@ Series[ad, {a, \[Infinity], 0}] // Normal

(* Out[370]= {-((3 (3/2)^(1/4) (1/a)^(11/4) E^((4 a^3)/27) Sqrt[\[Pi]]
    Cos[\[Pi]/24] Gamma[2/3])/Gamma[5/3]), (
 3 2^(3/4) 3^(1/4) (1/a)^(11/4) E^((4 a^3)/27) Sqrt[\[Pi]]
   Gamma[1/3] Gamma[5/4] Sin[\[Pi]/8])/(
 Gamma[1/4] Gamma[4/3]), -((
  324 2^(3/4) 3^(1/4) (1/a)^(11/4) E^((4 a^3)/27) Sqrt[\[Pi]]
    Gamma[19/12] Sin[(5 \[Pi])/24])/(35 Gamma[-(5/12)])), 
 288/35 Gamma[19/12] Sin[(5 \[Pi])/24] + (1/a)^(
   7/8) (-((4 (-1)^(1/24) \[Pi] Cos[\[Pi]/24] Gamma[2/3] Gamma[23/24])/(
      3^(5/8) Gamma[3/8] Gamma[17/24] Gamma[5/3])) + (
     8 (-1)^(3/8) \[Pi] Gamma[1/3] Gamma[5/8] Gamma[5/4] Sin[\[Pi]/8])/(
     3^(5/8) Gamma[1/24] Gamma[1/4] Gamma[17/24] Gamma[4/3]) - (
     288 (-1)^(17/24) 3^(
      3/8) \[Pi] Gamma[7/24] Gamma[19/12] Sin[(5 \[Pi])/24])/(
     35 Gamma[-(5/12)] Gamma[1/24] Gamma[3/8]))} *)

Close inspection shows that the first three elements becomes very big for a->[Infinity] because of the exponential factor. But it turns out - and that is the advantage of this approach - that the sum of the terms after extraction of the common factor is exactly zero:

FullSimplify[sad[[1]] + sad[[2]] + sad[[3]]]

(* Out[372]= 0 *)

This is the announced harmless version of the cancellation of big terms.

In the fourth element we are lucky as the complicated part goes to zero with (1/a)^(7/8) leaving only the nice final result:

lim = Limit[sad[[4]], a -> \[Infinity]]

(* Out[404]= 288/35 Gamma[19/12] Sin[(5 \[Pi])/24] *)

This can be simpified

FullSimplify[lim == 24/5 Gamma[7/12] Sin[(5 \[Pi])/24]]

(* Out[405]= True *)

Hence the integral becomes finally

f = 24/5 Gamma[7/12] Sin[(5 \[Pi])/24];
% // N

(* Out[12]= 4.46697 *)

This is a nice result, and it conincides with the one of george2079 but not with the one of the OP.

Observation

Choosing the "black-box" approach, i.e. letting Mathematica do the Job quietly, we have on the one hand

Limit[ad, a -> \[Infinity]] // Quiet

(* Out[3]= -(72/35) (Sqrt[2 - Sqrt[2]] - Sqrt[3 (2 + Sqrt[2])]) Gamma[19/12] *)

on the other hand the original integral becomes

Timing[Integrate[(-2 a Cos[\[Pi]/24] Gamma[
       11/12] HypergeometricPFQ[{11/24, 23/24}, {2/3, 4/3}, (4 a^3)/27] + 
     8 Gamma[5/4] HypergeometricPFQ[{1/8, 5/8}, {1/3, 2/3}, (4 a^3)/
        27] Sin[\[Pi]/8] + 
     a^2 Gamma[
       19/12] HypergeometricPFQ[{19/24, 31/24}, {4/3, 5/3}, (4 a^3)/
        27] Sin[(5 \[Pi])/24]), {a, 0, \[Infinity]}] // Quiet]

(* Out[5]= {124.894, -Sqrt[2 - Sqrt[3/2] + 1/Sqrt[2]] Gamma[-(5/12)]} *)

% // N

(* Out[6]= {124.894, 4.46697} *)

Which provides the same values in algebraic terms instead of the sine.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.