I want to solve the following integral:

Integrate[( E^(-ω/Λ) Sin[((ω + Ω) t)/2] Sin[(ω t)/ 2])/((ω + Ω)/4) , {ω, 0, ∞}]

But unfortunately Mathematica cannot solve it. Is there any way to solve this integral analytically? If not, what is the most innocent approximation to solve it?


Assuming a little about domains lets it find the integral

Assuming[Λ > 0 && Ω > 0 && t > 0, 
  Integrate[(E^(-ω/Λ) Sin[((ω+Ω) t)/2] Sin[(ω t)/2])/((ω+Ω)/4), {ω, 0, ∞}]]

Λ being positive is required for the integral to converge. If t==0 the integral is simply zero. Assuming t>0 gives the same result as t<0, but assuming t!=0 doesn't seem to be quite enough. If you assume Ω<0 you get a very different result.

  • $\begingroup$ The assumptions are physically reasonable: Λ and Ω are frequencies and t is time, so they are positive. Thanks man. $\endgroup$ – Farhad Jan 11 '16 at 19:00

You can get a simpler form by converting the trig functions to exponentials (TrigToExp), expanding, integrating each term separately, and simplifying.

expr = (E^(-ω/Λ) Sin[((ω + Ω) t)/
         2] Sin[(ω t)/2])/((ω + Ω)/4) // 
    TrigToExp // Expand;

Assuming[{Λ > 0, Element[t, Reals], Ω > 0},
 Simplify[Integrate[#, {ω, 0, ∞}] & /@ expr]]

(*  E^(-(1/2) I t Ω + Ω/Λ) (-(1 + E^(
       I t Ω)) \
ExpIntegralEi[-(Ω/Λ)] - 
   Gamma[0, (-I t + 1/Λ) Ω] - 
   E^(I t Ω)
     Gamma[0, (I t + 1/Λ) Ω])  *)

Note that you need only assume that t is real.

For the case t == 0

FullSimplify[%, {Λ > 0, t == 0, Ω > 0}]

(*  0  *)
  • $\begingroup$ Interesting that the initial solution has some discontinuities when it is plotted, but the second solution does not. I don't know whether this is due to the simpler function or the assumption that t is a real number. $\endgroup$ – Jack LaVigne Mar 7 '16 at 17:02

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.