0
$\begingroup$

Solve this equation explicitly for $\beta$:
$$T_{12}=\frac{x_{11}+x_{22}}{1+|\beta|^2}\beta$$
$x_{11}$ and $x_{22}$ are positive real numbers where $x_{11}>x_{22}$ and $T_{12}$ and $\beta$ are complex numbers. and $|\beta|<1$

Up to know I've tried this:

sol1 = Solve[
 Subscript[T, 12] == (Subscript[x, 11] + Subscript[x, 22])/(1 + Abs[β]^2) β &&
  {Subscript[x, 11], Subscript[x, 22]} ∈ Reals &&
  {Subscript[T, 12], β} ∈ Complexes,
 β
]

But it gives a complicated solution whereas the answer should be
$$\beta=\frac{T_{12}}{|T_{12}|}\sqrt{\frac{x_{22}}{x_{11}}}$$ according to the scientific article that I'm studying.

$\endgroup$
  • $\begingroup$ sol1 = Block[{$Assumptions = Subscript[x, 11] > Subscript[x, 22] > 0 && {Subscript[x, 11], Subscript[x, 22]} \[Element] Reals && Subscript[T, 12] \[Element] Complexes}, Solve[Subscript[T, 12] == ((Subscript[x, 11] + Subscript[x, 22]) \[Beta])/(1 + Abs[\[Beta]]^2), \[Beta], Complexes]] seems to work, but adding Abs[\[Beta]] < 1 in Solve takes too long. $\endgroup$ – JungHwan Min Jan 10 '16 at 22:14
  • 1
    $\begingroup$ your answer cant be correct. the x's are a sum in the original, how can they appear otherwise in the result? $\endgroup$ – george2079 Jan 11 '16 at 1:28
2
$\begingroup$

Edited to provide greater detail

eq = Subscript[T, 12] == (Subscript[x, 11] + Subscript[x, 22])/(1 + Abs[β]^2) β

First determine Abs[β]

Simplify[ComplexExpand[Abs[#] & /@ eq, {Subscript[T, 12], β}, 
    TargetFunctions -> Abs], Subscript[x, 11] + Subscript[x, 22] > 0]
(* (1 + Abs[β]^2) Abs[Subscript[T, 12]] == Abs[β] (Subscript[x, 11] + Subscript[x, 22]) *)

Simplify[Solve[%, Abs[β]]] // Flatten
(* {Abs[β] -> (Subscript[x, 11] + Subscript[x, 22] - Sqrt[-4 Abs[Subscript[T, 12]]^2 + 
    (Subscript[x, 11] + Subscript[x, 22])^2])/(2 Abs[Subscript[T, 12]]), 
    Abs[β] -> (Subscript[x, 11] + Subscript[x, 22] + Sqrt[-4 Abs[Subscript[T, 12]]^2 + 
    (Subscript[x, 11] + Subscript[x, 22])^2])/(2 Abs[Subscript[T, 12]])}

and then β itself

Simplify[Solve[eq /. #, β] & /@ %] // Flatten
(* {β -> (Subscript[T, 12] (Subscript[x, 11] + Subscript[x, 22] - 
    Sqrt[-4 Abs[Subscript[T, 12]]^2 + (Subscript[x, 11] + Subscript[x, 22])^2]))
    /(2 Abs[Subscript[T, 12]]^2), 
    β -> (Subscript[T, 12] (Subscript[x, 11] + Subscript[x, 22] + 
    Sqrt[-4 Abs[Subscript[T, 12]]^2 + (Subscript[x, 11] + Subscript[x, 22])^2]))
    /(2 Abs[Subscript[T, 12]]^2)} *)
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.