How to set the relative directory so that they work both in script and in notebook and portable?

Question

Maybe the question is not clear, here I try to state it in more detail： I have a folder named project, for instance. In it I have two folders, one is named code, the other is named data. In the code folder, I have two code files: one is testCode.nb, the other is testCode.m, these two files always synchronized (have the same contents). What the code does is quite simple, it export a list to a file named test.txt, which I require it to locate in the data folder. How can I achieve this?

If in the code files I have:

lst={{1,Pi},{2,2 Pi}};
SetDirectory["../data"];
Export["test.txt",lst//N,"Table"];

The code run as script .m file in the terminal (on ubuntu linux) pass but failed in notebook. The error is:

SetDirectory::cdir: Cannot set current directory to ../data. >>

Answer 1

related: Analogue of NotebookDirectory[] for scripts (to get the directory path of my script.m)?

It's longer, so not so tempting to use what MMA provides but it is encouraged if you want to write OS/environment independent scripts:

If[$Input === "",
 FileNameJoin[{NotebookDirectory[], "data"}],
 FileNameJoin[{DirectoryName @ $InputFileName, "data"}]
 ]

"C:\\ [....] \\data" 

path = FileNameJoin[{$TemporaryDirectory, "test.m"}];

Export[path, "If[$Input === \"\",    
     FileNameJoin[{NotebookDirectory[],\"data\"}],
     FileNameJoin[{DirectoryName@$InputFileName,\"data\"}]
  , "String"]

Get@path

C:\\ [...] \\ Local \\ Temp \\ data

---

Edit Above answer has assumed data folder is in the same directory as the code files. The code going one level upper and more related to OP's question is like this:

lst={{1,Pi},{2,2 Pi}};

path = FileNameJoin[{ParentDirectory @ #,"data"}]& @ If[ $Input==="", 
    NotebookDirectory[],
	DirectoryName @ $InputFileName
];

path = FileNameJoin[{path,"test.txt"}];

Export[path, lst//N, "Table"];

Answer 2

myDir = "dataTest";
If[Length[
    FileNames[
     myDir = FileNameJoin[{$UserDocumentsDirectory, myDir}]]] == 0, 
  CreateDirectory[myDir]];
lst = {{1, Pi}, {2, 2 Pi}};
Export[FileNameJoin[{myDir, "test.txt"}], lst // N, "Table"]