Panning with Mouse + Moving A Curve

Question

I would like to be able to move any curve (for example f(x)=x, or g(x)=x^2) by mouse dragging the particular curve.

I would like to keep the functionality I have for panning across the screen in the code below. This uses Manipulate, (provided by @Karsten 7) but other solutions using Dynamic can be found here

Manipulate[

 Plot[{x, x^2}, {x, -3, 3}, Axes -> True, AxesOrigin -> {0, 0}, 
  PlotRange -> pr, GridLines -> Range @@@ Round@pr, 
  GridLinesStyle -> LightGray],


 {{p, {0, 0}}, Locator, 
  TrackingFunction -> {p = 
       MousePosition[{"Graphics", Graphics}, {0, 0}]; &, 
    If[MousePosition["GraphicsScaled"] \[Element] Rectangle[], 
       pr += p - MousePosition[{"Graphics", Graphics}, {0, 0}]]; &, 
    None}, Appearance -> None},
 {{pr, {{-5, 5}, {-5, 5}}},
  None}]

I'm guessing I would like to put a locator on each curve and then move the curve as long as I am close enough to the locator. What do you think?

Below is a video of what I want to emulate from desmos.com.

Answer 1

This isn't a very elegant implementation, but since nobody else has answered so far, I've decided to post it. It is an extension of what I posted in this previous question.

f1[x_] := x^2
f2[x_] := x + 1

With[{span = 10., δ = .1, f1DragPt = {0., f1[0.]}, f2DragPt = {0., f2[0.]}},
  Framed @
    DynamicModule[{mXY, action, xmin, xmax, ymin, ymax, p1, p2},
      {xmin, xmax} = {ymin, ymax} = span {-1., 1.}/2.;
      p1 = p2 = {0., 0.};
    EventHandler[
      Dynamic @
        Plot[
          {f1[t - p1[[1]]] + p1[[2]], f2[t - p2[[1]]] + p2[[2]]}, 
          {t, xmin, xmax}, 
          AspectRatio -> Automatic, 
          PlotRange -> {{xmin, xmax}, {ymin, ymax}},
          GridLines ->
            {Floor /@ Range[xmin, xmax], Floor /@ Range[ymin, ymax]}],
      {"MouseDown" :>
        (mXY = MousePosition["Graphics"];
         Which[
           Abs[f1[mXY[[1]] - p1[[1]]] + p1[[2]] - mXY[[2]]] < δ, action = "moveF1",
           Abs[f2[mXY[[1]] - p2[[1]]] + p2[[2]] - mXY[[2]]] < δ, action = "moveF2",
           True, action = "pan"])},
      {"MouseDragged" :>
        Module[{xy, dx, dy},
          xy = MousePosition["Graphics"];
          Switch[action,
            "pan", 
              {dx, dy} = xy - mXY; xmin -= dx; xmax -= dx; ymin -= dy; ymax -= dy,
            "moveF1", p1 = xy - f1DragPt,
            "moveF2", p2 = xy - f2DragPt]]}]]]

Initial plot

Plot after some panning and curve dragging.

To select a curve for moving, click anywhere along the curve. However, dragging will always be with the mouse cursor at the designated drag point. Having to designate drag points for each curve is one of the inelegant features of this solution.

Update

Here is a version that doesn't require designating drag points in advance. Any point of a curve can serve as a drag point.

With[{span = 10., δ = .1},
  Framed @
    DynamicModule[
        {mXY, action, f1DragPt, f2DragPt, xmin, xmax, ymin, ymax, p1, p2},
      {xmin, xmax} = {ymin, ymax} = span {-1., 1.}/2.;
      p1 = p2 = {0., 0.};
      EventHandler[
        Dynamic @
          Plot[
            {f1[t - p1[[1]]] + p1[[2]], f2[t - p2[[1]]] + p2[[2]]}, 
            {t, xmin, xmax}, 
            AspectRatio -> Automatic, 
            PlotRange -> {{xmin, xmax}, {ymin, ymax}},
            GridLines ->
              {Floor /@ Range[xmin, xmax], Floor /@ Range[ymin, ymax]}],
        {"MouseDown" :>
          (mXY = MousePosition["Graphics"];
           Which[
             Abs[f1[mXY[[1]] - p1[[1]]] + p1[[2]] - mXY[[2]]] < δ, 
               f1DragPt = mXY - p1; action = "moveF1",
             Abs[f2[mXY[[1]] - p2[[1]]] + p2[[2]] - mXY[[2]]] < δ,
               f2DragPt = mXY - p2; action = "moveF2",
             True, action = "pan"])},
        {"MouseDragged" :>
          Module[{xy, dx, dy},
            xy = MousePosition["Graphics"];
            Switch[action,
              "pan", 
                 {dx, dy} = xy - mXY; xmin -= dx; xmax -= dx; ymin -= dy; ymax -= dy,
              "moveF1", p1 = xy - f1DragPt,
              "moveF2", p2 = xy - f2DragPt]]}]]]

Answer 2

Here's a solution using Manipulate.

xmin = -5;
ymin = -5;
xmax = 5;
ymax = 5;
Manipulate[EventHandler[Dynamic@Show[
    Plot[{t - qt[[1]] + qt[[2]], (t - pt[[1]])^2 + pt[[2]]}, {t, xmin,
       xmax}],
    PlotRange -> {{xmin, xmax}, {ymin, ymax}},
    Axes -> True,
    GridLines -> {Floor /@ Range[xmin, xmax], 
      Floor /@ Range[ymin, ymax]},
    AspectRatio -> Automatic,
    Ticks -> False],
  If[Norm[MousePosition["Graphics"] - pt] > .3 && 
    Norm[MousePosition["Graphics"] - qt] > .3,
   {
    {"MouseDown" :> (mouseXY = MousePosition["Graphics"])},
    {"MouseDragged" :> Module[{dx, dy},
       {dx, dy} = (MousePosition["Graphics"] - mouseXY);
       xmin -= dx;
       xmax -= dx;
       ymin -= dy;
       ymax -= dy]}}]],
 {{pt, {-1, 1}}, Locator}, {{qt, {3, 3}}, Locator}]

If anyone sees any bad programming practice in my code or how it can be made better, let me know. I would appreciate it. Thank you!