4
$\begingroup$

I would like to show the controls as in the image, but after I try ControlPlacement->Right and some combinations of Row[] and Column[], I can´t get the solution.

Could you help me?

Manipulate[
 ListPlot[{a, b, c, d}],

 Style["a and b in a column on the right", Orange, Bold],
 {{a, 1, "a->"}, 0, 5, Appearance -> "Open"},
 {{b, 1, "b->"}, 0, 5, Appearance -> "Open"},
 Delimiter,

 Style["c and d in a column on the more right", Blue, Bold],
 {{c, 1, "c->"}, 0, 5, Appearance -> "Open"},
 {{d, 1, "d->"}, 0, 5, Appearance -> "Open"}
 ]

enter image description here

$\endgroup$
3
  • $\begingroup$ I am not aware how to achieve a setting like you do but perhaps you could look into ControlPlacement->Right ? This does move controls to the right but they are placed vertically one after another. $\endgroup$ Dec 23, 2015 at 12:35
  • $\begingroup$ @E.Doroskevic yes, I tried but all the controls go to the Right in a ONLY column. I would like to obtain 2 cols. $\endgroup$
    – Mika Ike
    Dec 23, 2015 at 12:40
  • 1
    $\begingroup$ You can use e.g. Grid together with Control to achieve complex layouts. I would recommend that you browse the Demonstrations website, which features many different types of control layouts together with the used code. This one took me quite a while, layout-wise. It may be wise to consider the pareto rule in terms of effort invested... $\endgroup$
    – Yves Klett
    Dec 23, 2015 at 12:57

1 Answer 1

7
$\begingroup$
Manipulate[None,

 Grid[{
   {Dynamic@ListPlot[{a, b, c, d}],
    Grid[{
      {Style["a and b in a column on the right", Orange, Bold]},
      {Control[{{a, 1, "a->"}, 0, 5, Appearance -> "Open"}]},
      {Control[{{b, 1, "b->"}, 0, 5, Appearance -> "Open"}]}
      }],
    Grid[{
      {Style["c and d in a column on the more right", Blue, Bold]},
      {Control[{{c, 1, "c->"}, 0, 5, Appearance -> "Open"}]},
      {Control[{{d, 1, "d->"}, 0, 5, Appearance -> "Open"}]}
      }]
    }
   }, Frame -> All, Alignment -> Center]

 ]

Mathematica graphics

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.