14
$\begingroup$

I applied the spherical harmonic equation on the SphericalHarmonicY functions like this:

Simplify[(1/Sin[θ]) D[Sin[θ] D[SphericalHarmonicY[l, m, θ, ϕ], θ], θ] + 
    (1/Sin[θ]^2) D[SphericalHarmonicY[l, m, θ, ϕ], {ϕ, 2}]]

And it returns a sum of factors with $Y^{m}_{l}(\theta, \phi)$, $Y^{m+1}_{l}(\theta, \phi)$ and $Y^{m+2}_{l}(\theta, \phi)$

This is counterintuitive. I thought these were the eigenfunctions of the operator. I feel like I might be missing something basic here.

$\endgroup$
  • 1
    $\begingroup$ Even if one uses FullSimplify[], the problem seems to be in the fact that Mathematica does not seem to recognize a particular difference equation satisfied by the associated Legendre polynomial. $\endgroup$ – J. M.'s technical difficulties Dec 18 '15 at 2:14
  • $\begingroup$ Using FunctionExpand[Exp[-I m ϕ] ... ] and adding the assumption to FullSimplify that m is an integer also do not help. However, plotting the result over {θ, -Pi/2, Pi/2} certainly yields zero for any integer m. $\endgroup$ – bbgodfrey Dec 18 '15 at 2:36
  • 2
    $\begingroup$ @J.M. This seems pretty silly. Apart from expansions in spherical harmonics, it seems to me that Ylm being an eigenfunction of this particular differential operator is the defining feature of the spherical harmonics. It strikes me as a little, I don't know, unorthodox that the Mathematica programmers shouldn't include this naturally behind the scenes. Much less for the Legendre polynomials. $\endgroup$ – march Dec 18 '15 at 2:37
  • 1
    $\begingroup$ Another data point: if you use FunctionExpand[FullSimplify[(* stuff *)]] on the full eigenvalue PDE, you get True as the result. So, it can simplify that, but it cannot do the intermediate step of simplifying your expression to a single instance of SphericalHarmonicY[]. $\endgroup$ – J. M.'s technical difficulties Dec 18 '15 at 13:52
  • $\begingroup$ So is Mathematica doing something about it ? Is there a forum where I can post this problem ? Because I am doing something in AdS4 and simplification seems to depend on this fact. $\endgroup$ – Jaswin May 8 '16 at 17:25
8
+50
$\begingroup$

The operator in the question can be simplified by first applying it to an arbitrary function f:

Simplify[(1/Sin[θ]) D[Sin[θ] D[f[θ,ϕ],θ],θ]+(1/Sin[θ]^2) D[f[θ,ϕ],{ϕ,2}]]

$$f^{(2,0)}(\theta ,\phi )+\cot (\theta ) f^{(1,0)}(\theta ,\phi )+\csc ^2(\theta ) f^{(0,2)}(\theta ,\phi )$$

This can be recognized as the negative of the squared angular momentum operator, $-L^2$, see below (and see also my answer here). It doesn't seem possible to do the simplification exactly as asked for in the question, but you can put together a Mathematica based proof of the desired eigenvalue property $$L^2 Y^{m}_{\ell} = \ell (\ell +1) Y^{m}_{\ell}$$ in several steps. In doing so, the advantage is that you can see more clearly how this equation is related to the properties of the angular-momentum operator (the brute-force approach in the question would be shorter, but less illuminating, even if it were possible).

The spherical harmonics are simultaneous eigenfunctions of the squared angular momentum and its z component. Here is how you can verify this by asking Mathematica to derive the two corresponding eigenvalues:

First I define the two operators to make the notation in the following steps clearer. Then I apply these operators in the eigenvalue equation with the spherical harmonic as the assumed solution. The proof consists in the fact that Mathematica does indeed find an eigenvalue that makes each relation true.

Clear[θ, ϕ, f, m, ℓ]
lzOp = Function[f, (-I)*D[f, {ϕ}]];
l2Op = Function[f, -D[f, {θ, 2}] - Csc[θ]^2*D[f, {ϕ, 2}] - Cot[θ]*D[f, {θ}]];

Simplify[
 lzOp[SphericalHarmonicY[ℓ, m, θ, ϕ]]]

m SphericalHarmonicY[ℓ, m, θ, ϕ]

Simplify[
 l2Op[SphericalHarmonicY[ℓ, ℓ, θ, ϕ]]]

ℓ (1 + ℓ) SphericalHarmonicY[ℓ, ℓ, θ, ϕ]

So both lzOp (the z-angular momentum) and l2Op (the squared angular momentum) reproduce the spherical harmonic with a prefactor that corresponds to the correct eigenvalue.

However, the last eigenvalue equation with l2Op (which is what the question focuses on) only works for m = ℓ. For the remaining values of m, I would proceed by using the ladder operators which turn $Y^m_{\ell}$ into $Y^{m\pm 1}_{\ell}$ and also commute with l2Op. These operations will then necessarily leave the eigenvalue ℓ (1 + ℓ) unchanged for l2Op.

To execute this idea, I have to define the lowering operator, lMinus:

lMinus = Function[f, Exp[-I ϕ] (Cot[θ] D[f, ϕ] + I D[f, θ])];

First I now show that lMinus indeed has the effect of lowering the z eigenvalue of any spherical harmonic:

Simplify[
 First[Solve[
   lzOp[lMinus@SphericalHarmonicY[ℓ, m, θ, ϕ]] ==
     eigenvalue lMinus@SphericalHarmonicY[ℓ, m, θ, ϕ], 
   eigenvalue]
 ]]

{eigenvalue -> -1 + m}

Here I had to use Solve to extract the eigenvalue property by defining the unknown eigenvalue as a prefactor in front of the expected functional form lMinus@SphericalHarmonicY. Without this trick, the functions are too complicated, and FullSimplify can't bring them into the same form on both sides. Note that I have only cheated a little here, because I didn't tell Mathematica what the new eigenvalue is expected to be. It found that out by itself.

The last eigenvalue equation means that if the original spherical harmonic had index m, then the result of lMinus has index m -1. We could now apply this operator to the "maximal state" $Y^{\ell}_{\ell}$ for which I had already shown that the eigenvalue equation $L^2 Y^{\ell}_{\ell} = \ell (\ell +1) Y^{\ell}_{\ell}$ is satisfied. Then it remains to be shown that the same eigenvalue of $L^2$ is obtained with the function created by repeated application of lMinus (one writes it $L_{-}$). The crucial fact that is needed for that proof is this commutation relation:

$$L^2 L_{-} = L_{-} L^2$$

which I show here by applying both orders to an arbitrary test function $f(\theta, \phi)$:

Simplify[
 l2Op[lMinus[f[θ, ϕ]]] == lMinus[l2Op[f[θ, ϕ]]]]

True

With this, I have all the building blocks to deduce that

$$L^2 Y^{m}_{\ell} = \ell (\ell +1) Y^{m}_{\ell}$$

holds. You start by setting $m=\ell$, for which the above is known to be true from earlier. Then apply lMinus on both sides to get the same equation for $m=\ell -1$, and repeat another $2\ell$ times to span the entire angular-momentum ladder of allowed m for the given .

| improve this answer | |
$\endgroup$
  • $\begingroup$ This is a very indirect way of dealing, what if I am using these functions and want simplifications of eigenvalue equations ? $\endgroup$ – Jaswin Jun 13 '16 at 7:04
  • $\begingroup$ @Jaswin The same difficulties arise with other eigenvalue equations that involve different special functions, e.g., the Coulomb problem or the harmonic oscillator. The trick of using Solve to derive the eigenvalue works in all these cases. I need that here to show the properties of lMinus, but it's actually not needed for the other eigenvalue properties (see the edit to my answer). But this is pretty much the simplest form of a proof for the general eigenvalue property that I could come up with. $\endgroup$ – Jens Jun 14 '16 at 5:10
  • 1
    $\begingroup$ @Jaswin, that's why I was prompting you in the comments to include examples in the post. $\endgroup$ – J. M.'s technical difficulties Jun 14 '16 at 5:14
  • $\begingroup$ @J.M : Actually I was a bit busy, so couldn't update, and the days for giving away bounty points was yesterday, so closed the answer. Will put the updated question soon. $\endgroup$ – Jaswin Jun 15 '16 at 5:49
0
$\begingroup$

In this wikipedia page you will find the relationship between the spherical harmonics and the associated Legendre Polynomials. The second of the recurrence formula from this page gives you a relationship for same l different m's. That is the origin of this formula to simplify MMA's answer.

| improve this answer | |
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.