How to replace a space by a comma

Question

in this expression = "{1 2 3 4 5 6 7 8}", I want to replace each space by a comma , to get {1,2,3,4,5,6,7,8}.

Answer 1

expression = "{1 2 3 4 5 6 7 8}";

A few alternatives to PlatoManiac's approach:

ToExpression[
    expression, 
    StandardForm, 
    Function[e, Sequence @@@ Unevaluated[e], HoldAll]
]

or

ToExpression @ StringReplace[expression, " " -> ","]

{1, 2, 3, 4, 5, 6, 7, 8} 

or

 StringCases[expression, n : NumberString :> ToExpression[n]]

 ToExpression @ StringCases[expression, NumberString]

Answer 2

A possibility with WhitespaceCharacter

ToExpression@
     StringReplace[expression, WhitespaceCharacter -> ","]

(* {1, 2, 3, 4, 5, 6, 7, 8} *)

Another using Interpreter

Interpreter[
   DelimitedSequence["Integer", {"{", " ", "}"}]][expression]

Answer 3

My thought was to drop the brackets using StringTake and then import it using ImportString

"{1 2 3 4 5 6 7 8}"~StringTake~{2, -2}~ImportString~"Table" // First
(* {1, 2, 3, 4, 5, 6, 7, 8} *)

edit I just realized this is very similar to what J.M. suggested in his comment (although I'm playing around with infix notation here).

Answer 4

Since space is implicit Times similar methods to Convert head Times to List can be applied:

Block[{Times = List}, ToExpression @ "{1 2 3 4 5 6 7 8}"] // First

{1, 2, 3, 4, 5, 6, 7, 8}

Though in this case a much shorter method works too:

ToHeldExpression[expression] ~Level~ {3}

{1, 2, 3, 4, 5, 6, 7, 8}

Answer 5

Another solution, inspired by Kuba's first one:

Sequence @@@ ToExpression[expression, StandardForm, Inactivate] 

Answer 6

A similar case to "{1 2 3 4 5 6 7 8}", that also appears when you extract data from txt, is {"1 2 3 4 5 6 7 8"}

In that case, one can use

ToExpression@ StringSplit@ {"1 2 3 4 5 6"}

Answer 7

Another way is to use StringRiffle:

ToExpression[StringRiffle[StringSplit["{1 2 3 4 5 6 7 8}"], ","]]

{1, 2, 3, 4, 5, 6, 7, 8}

Note that StringRiffle can also perform the inverse operation too:

StringRiffle[{1, 2, 3, 4, 5, 6, 7, 8}, {"{", ", ", "}"}]

"{1, 2, 3, 4, 5, 6, 7, 8}"

Answer 8

Using Composition :

strToList = Composition[
  ToExpression,
  StringSplit,
  StringReplace[#,
    PunctuationCharacter :> ""] &
  ];

alist = strToList@expression

{1, 2, 3, 4, 5, 6, 7, 8}

---

Alternate notation:

ToExpression @*
  StringSplit@*(StringReplace[#, 
     PunctuationCharacter :> ""] &)@expression